configure

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   7 #   Copyright (C) 2009-2010 Daniel De Graaf <danieldg@inspircd.org>
   8 #   Copyright (C) 2007, 2009 Dennis Friis <peavey@inspircd.org>
   9 #   Copyright (C) 2003, 2006-2008 Craig Edwards <craigedwards@brainbox.cc>
  10 #   Copyright (C) 2006-2008 Robin Burchell <robin+git@viroteck.net>
  11 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
  12 #   Copyright (C) 2007 John Brooks <john.brooks@dereferenced.net>
  13 #   Copyright (C) 2006 Oliver Lupton <oliverlupton@gmail.com>
  14 #   Copyright (C) 2003-2006 Craig McLure <craig@chatspike.net>
  15 #
  16 # This file is part of InspIRCd.  InspIRCd is free software: you can
  17 # redistribute it and/or modify it under the terms of the GNU General Public
  18 # License as published by the Free Software Foundation, version 2.
  19 #
  20 # This program is distributed in the hope that it will be useful, but WITHOUT
  21 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  22 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  23 # details.
  24 #
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  27 #
  28
  29
  30 BEGIN {
  31         require 5.10.0;
  32 }
  33
  34 use feature ':5.10';
  35 use strict;
  36 use warnings FATAL => qw(all);
  37
  38 use File::Basename        qw(basename);
  39 use File::Copy            ();
  40 use File::Spec::Functions qw(rel2abs);
  41 use FindBin               qw($RealDir);
  42 use Getopt::Long          qw(GetOptions);
  43 use POSIX                 qw(getgid getuid);
  44
  45 use lib $RealDir;
  46 use make::common;
  47 use make::configure;
  48 use make::console;
  49 use make::directive;
  50
  51 my ($opt_binary_dir,
  52     $opt_config_dir,
  53     $opt_data_dir,
  54     $opt_development,
  55     $opt_disable_interactive,
  56     $opt_distribution_label,
  57     $opt_gid,
  58     $opt_log_dir,
  59     $opt_manual_dir,
  60     $opt_module_dir,
  61     $opt_prefix,
  62     $opt_socketengine,
  63     $opt_system,
  64     $opt_uid);
  65
  66 sub list_extras ();
  67
  68 sub enable_extras (@);
  69
  70 sub disable_extras (@);
  71
  72 my @opt_enableextras;
  73 my @opt_disableextras;
  74
  75 GetOptions(
  76         'clean'  => \&cmd_clean,
  77         'help'   => \&cmd_help,
  78         'update' => \&cmd_update,
  79
  80         'development'          => \$opt_development,
  81         'disable-interactive'  => \$opt_disable_interactive,
  82         'distribution-label=s' => \$opt_distribution_label,
  83         'binary-dir=s'         => \$opt_binary_dir,
  84         'config-dir=s'         => \$opt_config_dir,
  85         'data-dir=s'           => \$opt_data_dir,
  86         'gid=s'                => \$opt_gid,
  87         'log-dir=s'            => \$opt_log_dir,
  88         'manual-dir=s'         => \$opt_manual_dir,
  89         'module-dir=s'         => \$opt_module_dir,
  90         'prefix=s'             => \$opt_prefix,
  91         'socketengine=s'       => \$opt_socketengine,
  92         'system'               => \$opt_system,
  93         'uid=s'                => \$opt_uid,
  94
  95         # TODO: when the modulemanager rewrite is done these should be removed.
  96         'disable-extras=s@' => \@opt_disableextras,
  97         'enable-extras=s@'  => \@opt_enableextras,
  98         'list-extras'       => sub { list_extras; exit 0; },
  99 );
 100
 101 if (scalar(@opt_enableextras) + scalar(@opt_disableextras) > 0) {
 102         @opt_enableextras = split /,/, join(',', @opt_enableextras);
 103         @opt_disableextras = split /,/, join(',', @opt_disableextras);
 104         enable_extras(@opt_enableextras);
 105         disable_extras(@opt_disableextras);
 106         list_extras;
 107         print "Remember: YOU are responsible for making sure any libraries needed have been installed!\n";
 108         exit 0;
 109 }
 110
 111 our $interactive = !(
 112         !-t STDIN ||
 113         !-t STDOUT ||
 114         defined $opt_binary_dir ||
 115         defined $opt_config_dir ||
 116         defined $opt_data_dir ||
 117         defined $opt_development ||
 118         defined $opt_disable_interactive ||
 119         defined $opt_distribution_label ||
 120         defined $opt_gid ||
 121         defined $opt_log_dir ||
 122         defined $opt_manual_dir ||
 123         defined $opt_module_dir ||
 124         defined $opt_prefix ||
 125         defined $opt_socketengine ||
 126         defined $opt_system ||
 127         defined $opt_uid
 128 );
 129
 130 my %version = get_version $opt_distribution_label;
 131 print_format "<|BOLD Configuring InspIRCd $version{FULL} on $^O.|>\n";
 132
 133 my %config;
 134 if ($interactive) {
 135         %config = read_config_file(CONFIGURE_CACHE_FILE);
 136         run_test CONFIGURE_CACHE_FILE, %config;
 137         if (!defined $config{VERSION}) {
 138                 $config{VERSION} = CONFIGURE_CACHE_VERSION;
 139         } elsif ($config{VERSION} != CONFIGURE_CACHE_VERSION) {
 140                 print_warning "ignoring contents of ${\CONFIGURE_CACHE_FILE} as it was generated by an incompatible version of $0!";
 141                 %config = ('VERSION', CONFIGURE_CACHE_VERSION);
 142         }
 143 }
 144
 145 $config{CXX} = find_compiler($config{CXX} // $ENV{CXX});
 146 unless ($config{CXX}) {
 147         say 'A suitable C++ compiler could not be detected on your system!';
 148         unless ($interactive) {
 149                 say 'Set the CXX environment variable to the path to a C++ compiler binary if this is incorrect.';
 150                 exit 1;
 151         }
 152         until ($config{CXX}) {
 153                 my $compiler_path = prompt_string 1, 'Please enter the path to a C++ compiler binary:', 'c++';
 154                 $config{CXX} = find_compiler $compiler_path;
 155         }
 156 }
 157 my %compiler = get_compiler_info($config{CXX});
 158
 159 $config{HAS_CLOCK_GETTIME} = run_test 'clock_gettime()', test_file($config{CXX}, 'clock_gettime.cpp', $^O eq 'darwin' ? undef : '-lrt');
 160 $config{HAS_EVENTFD} = run_test 'eventfd()', test_file($config{CXX}, 'eventfd.cpp');
 161
 162 my @socketengines;
 163 push @socketengines, 'epoll'  if run_test 'epoll', test_header $config{CXX}, 'sys/epoll.h';
 164 push @socketengines, 'kqueue' if run_test 'kqueue', test_file $config{CXX}, 'kqueue.cpp';
 165 push @socketengines, 'ports'  if run_test 'Solaris IOCP', test_header $config{CXX}, 'port.h';
 166 push @socketengines, 'poll'   if run_test 'poll', test_header $config{CXX}, 'poll.h';
 167 push @socketengines, 'select';
 168
 169 if (defined $opt_socketengine) {
 170         unless (grep { $_ eq $opt_socketengine } @socketengines) {
 171                 my $reason = -f "src/socketengines/socketengine_$opt_socketengine.cpp" ? 'is not available on this platform' : 'does not exist';
 172                 print_error "The socket engine you requested ($opt_socketengine) $reason!",
 173                         'Available socket engines are:',
 174                         map { "  * $_" } @socketengines;
 175         }
 176 }
 177 $config{SOCKETENGINE} = $opt_socketengine // $socketengines[0];
 178
 179 if (defined $opt_system) {
 180         $config{BASE_DIR}   = $opt_prefix     // '/var/lib/inspircd';
 181         $config{BINARY_DIR} = $opt_binary_dir // '/usr/sbin';
 182         $config{CONFIG_DIR} = $opt_config_dir // '/etc/inspircd';
 183         $config{DATA_DIR}   = $opt_data_dir   // '/var/inspircd';
 184         $config{LOG_DIR}    = $opt_module_dir // '/var/log/inspircd';
 185         $config{MANUAL_DIR} = $opt_manual_dir // '/usr/share/man/man1';
 186         $config{MODULE_DIR} = $opt_module_dir // '/usr/lib/inspircd';
 187 } else {
 188         $config{BASE_DIR}   = $opt_prefix     // $config{BASE_DIR}   // rel2abs 'run';
 189         $config{BINARY_DIR} = $opt_binary_dir // $config{BINARY_DIR} // rel2abs $config{BASE_DIR} . '/bin';
 190         $config{CONFIG_DIR} = $opt_config_dir // $config{CONFIG_DIR} // rel2abs $config{BASE_DIR} . '/conf';
 191         $config{DATA_DIR}   = $opt_data_dir   // $config{DATA_DIR}   // rel2abs $config{BASE_DIR} . '/data';
 192         $config{LOG_DIR}    = $opt_log_dir    // $config{LOG_DIR}    // rel2abs $config{BASE_DIR} . '/logs';
 193         $config{MANUAL_DIR} = $opt_manual_dir // $config{MANUAL_DIR} // rel2abs $config{BASE_DIR} . '/manuals';
 194         $config{MODULE_DIR} = $opt_module_dir // $config{MODULE_DIR} // rel2abs $config{BASE_DIR} . '/modules';
 195 }
 196
 197 # Parse --gid=123 or --gid=foo and extract the group id.
 198 my @group;
 199 if (defined $opt_gid) {
 200         @group = $opt_gid =~ /^\d+$/ ? getgrgid($opt_gid) : getgrnam($opt_gid);
 201         print_error "there is no '$opt_gid' group on this system!" unless @group;
 202 } else {
 203         @group = $opt_system ? getgrnam('irc') : getgrgid($config{GID} // getgid());
 204         print_error "you need to specify a group to run as using '--gid [id|name]'!" unless @group;
 205 }
 206 $config{GROUP} = $group[0];
 207 $config{GID}   = $group[2];
 208
 209 # Parse --uid=123 or --uid=foo and extract the user id.
 210 my @user;
 211 if (defined $opt_uid) {
 212         @user = $opt_uid =~ /^\d+$/ ? getpwuid($opt_uid) : getpwnam($opt_uid);
 213         print_error "there is no '$opt_uid' user on this system!" unless @user;
 214 } else {
 215         @user = $opt_system ? getpwnam('irc') : getpwuid($config{UID} // getuid());
 216         print_error "you need to specify a user to run as using '--uid [id|name]'!" unless @user;
 217 }
 218 $config{USER} = $user[0];
 219 $config{UID}  = $user[2];
 220
 221 # Clear the screen.
 222 system 'tput', 'clear' if $interactive;
 223
 224 # Check that the user actually wants this version.
 225 if ($version{LABEL} ne 'release') {
 226         print_warning <<'EOW';
 227 You are building a development version. This contains code which has
 228 not been tested as heavily and may contain various faults which could seriously
 229 affect the running of your server. It is recommended that you use a stable
 230 version instead.
 231
 232 You can obtain the latest stable version from http://www.inspircd.org/ or by
 233 running `git checkout insp20` if you are installing from Git.
 234 EOW
 235         if (!prompt_bool $interactive, 'I understand this warning and want to continue anyway.', $opt_development // 0) {
 236                 say STDERR 'If you understand this warning and still want to continue pass the --development flag.' unless $interactive;
 237                 exit 1;
 238         }
 239 }
 240
 241 # Configure directory settings.
 242 my $question = <<"EOQ";
 243 Currently, InspIRCd is configured with the following paths:
 244
 245 <|BOLD Base:|>   $config{BASE_DIR}
 246 <|BOLD Binary:|> $config{BINARY_DIR}
 247 <|BOLD Config:|> $config{CONFIG_DIR}
 248 <|BOLD Data:|>   $config{DATA_DIR}
 249 <|BOLD Log:|>    $config{LOG_DIR}
 250 <|BOLD Manual:|> $config{MANUAL_DIR}
 251 <|BOLD Module:|> $config{MODULE_DIR}
 252
 253 Do you want to change these settings?
 254 EOQ
 255 if (prompt_bool $interactive, $question, 0) {
 256         my $original_base_dir = $config{BASE_DIR};
 257         $config{BASE_DIR} = prompt_dir $interactive, 'In what directory do you wish to install the InspIRCd base?', $config{BASE_DIR};
 258         foreach my $key (qw(BINARY_DIR CONFIG_DIR DATA_DIR LOG_DIR MANUAL_DIR MODULE_DIR)) {
 259                 $config{$key} =~ s/^\Q$original_base_dir\E/$config{BASE_DIR}/;
 260         }
 261         $config{BINARY_DIR} = prompt_dir $interactive, 'In what directory should the InspIRCd binary be placed?', $config{BINARY_DIR};
 262         $config{CONFIG_DIR} = prompt_dir $interactive, 'In what directory are configuration files to be stored?', $config{CONFIG_DIR};
 263         $config{DATA_DIR}   = prompt_dir $interactive, 'In what directory are variable data files to be stored?', $config{DATA_DIR};
 264         $config{LOG_DIR}    = prompt_dir $interactive, 'In what directory are log files to be stored?',           $config{LOG_DIR};
 265         $config{MANUAL_DIR} = prompt_dir $interactive, 'In what directory are manual pages to be placed?',        $config{MANUAL_DIR};
 266         $config{MODULE_DIR} = prompt_dir $interactive, 'In what directory are modules to be placed?',             $config{MODULE_DIR};
 267 }
 268
 269 # Configure module settings.
 270 $question = <<'EOQ';
 271 Currently, InspIRCd is configured to automatically enable all available extra modules.
 272
 273 Would you like to enable extra modules manually?
 274 EOQ
 275 if (prompt_bool $interactive, $question, 0) {
 276         foreach my $extra (<src/modules/extra/m_*.cpp>) {
 277                 my $module_name = basename $extra, '.cpp';
 278                 if (prompt_bool $interactive, "Would you like to enable $module_name?", 0) {
 279                         enable_extras "$module_name.cpp";
 280                 }
 281         }
 282 } else {
 283         # TODO: finish modulemanager rewrite and replace this code with:
 284         # system './modulemanager', 'enable', '--auto';
 285         enable_extras 'm_ssl_gnutls.cpp' unless system 'pkg-config --exists gnutls >/dev/null 2>&1';
 286         enable_extras 'm_ssl_mbedtls.cpp' if -e '/usr/include/mbedtls/ssl.h';
 287         enable_extras 'm_ssl_openssl.cpp' unless system 'pkg-config --exists openssl >/dev/null 2>&1';
 288 }
 289
 290 # Generate SSL certificates.
 291 if (<src/modules/m_ssl_*.cpp> && prompt_bool $interactive, 'Would you like to generate SSL certificates now?', $interactive) {
 292         system './tools/genssl', 'auto';
 293 }
 294
 295 # Cache the distribution label so that its not lost when --update is run.
 296 $config{DISTRIBUTION} = $opt_distribution_label if $opt_distribution_label;
 297
 298 write_configure_cache %config;
 299 parse_templates \%config, \%compiler, \%version;
 300
 301 print_format <<"EOM";
 302
 303 Configuration is complete! You have chosen to build with the following settings:
 304
 305 <|GREEN Compiler:|>
 306   <|GREEN Binary:|>  $config{CXX}
 307   <|GREEN Name:|>    $compiler{NAME}
 308   <|GREEN Version:|> $compiler{VERSION}
 309
 310 <|GREEN Extra Modules:|>
 311 EOM
 312
 313 for my $file (<src/modules/m_*>) {
 314         my $module = basename $file, '.cpp';
 315         say "  * $module" if -l $file;
 316 }
 317
 318 print_format <<"EOM";
 319
 320 <|GREEN Paths:|>
 321   <|GREEN Base:|>   $config{BASE_DIR}
 322   <|GREEN Binary:|> $config{BINARY_DIR}
 323   <|GREEN Config:|> $config{CONFIG_DIR}
 324   <|GREEN Data:|>   $config{DATA_DIR}
 325   <|GREEN Log:|>    $config{LOG_DIR}
 326   <|GREEN Manual:|> $config{MANUAL_DIR}
 327   <|GREEN Module:|> $config{MODULE_DIR}
 328
 329 <|GREEN Execution Group:|> $config{GROUP} ($config{GID})
 330 <|GREEN Execution User:|>  $config{USER} ($config{UID})
 331 <|GREEN Socket Engine:|>   $config{SOCKETENGINE}
 332
 333 To build with these settings run '<|GREEN make -j${\get_cpu_count}|>' now.
 334
 335 EOM
 336
 337 # Routine to list out the extra/ modules that have been enabled.
 338 # Note: when getting any filenames out and comparing, it's important to lc it if the
 339 # file system is not case-sensitive (== Epoc, MacOS, OS/2 (incl DOS/DJGPP), VMS, Win32
 340 # (incl NetWare, Symbian)). Cygwin may or may not be case-sensitive, depending on
 341 # configuration, however, File::Spec does not currently tell us (it assumes Unix behavior).
 342 sub list_extras () {
 343         use File::Spec;
 344         # @_ not used
 345         my $srcdir = File::Spec->catdir("src", "modules");
 346         my $abs_srcdir = File::Spec->rel2abs($srcdir);
 347         local $_;
 348         my $dd;
 349         opendir $dd, File::Spec->catdir($abs_srcdir, "extra") or die (File::Spec->catdir($abs_srcdir, "extra") . ": $!\n");
 350         my @extras = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 351         closedir $dd;
 352         undef $dd;
 353         opendir $dd, $abs_srcdir or die "$abs_srcdir: $!\n";
 354         my @sources = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 355         closedir $dd;
 356         undef $dd;
 357         my $maxlen = (sort { $b <=> $a } (map {length($_)} (@extras)))[0];
 358         my %extras = ();
 359 EXTRA:  for my $extra (@extras) {
 360                 next if (File::Spec->curdir() eq $extra || File::Spec->updir() eq $extra);
 361                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 362                 my $abs_source = File::Spec->catfile($abs_srcdir, $extra);
 363                 next unless ($extra =~ m/\.(cpp|h)$/ || (-d $abs_extra)); # C++ Source/Header, or directory
 364                 if (-l $abs_source) {
 365                         # Symlink, is it in the right place?
 366                         my $targ = readlink($abs_source);
 367                         my $abs_targ = File::Spec->rel2abs($targ, $abs_srcdir);
 368                         if ($abs_targ eq $abs_extra) {
 369                                 $extras{$extra} = "\e[32;1menabled\e[0m";
 370                         } else {
 371                                 $extras{$extra} = sprintf("\e[31;1mwrong symlink target (%s)\e[0m", $abs_targ);
 372                         }
 373                 } elsif (-e $abs_source) {
 374                         my ($devext, $inoext) = stat($abs_extra);
 375                         my ($devsrc, $inosrc, undef, $lnksrc) = stat($abs_source);
 376                         if ($lnksrc > 1) {
 377                                 if ($devsrc == $devext && $inosrc == $inoext) {
 378                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 379                                 } else {
 380                                         $extras{$extra} = sprintf("\e[31;1mwrong hardlink target (%d:%d)\e[0m", $devsrc, $inosrc);
 381                                 }
 382                         } else {
 383                                 open my $extfd, "<", $abs_extra;
 384                                 open my $srcfd, "<", $abs_source;
 385                                 local $/ = undef;
 386                                 if (scalar(<$extfd>) eq scalar(<$srcfd>)) {
 387                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 388                                 } else {
 389                                         $extras{$extra} = sprintf("\e[31;1mout of synch (re-copy)\e[0m");
 390                                 }
 391                         }
 392                 } else {
 393                         $extras{$extra} = "\e[33;1mdisabled\e[0m";
 394                 }
 395         }
 396         # Now let's add dependency info
 397         for my $extra (keys(%extras)) {
 398                 next unless $extras{$extra} =~ m/enabled/; # only process enabled extras.
 399                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 400                 my @deps = split /\s+/, get_directive($abs_extra, 'ModDep', '');
 401                 for my $dep (@deps) {
 402                         if (exists($extras{$dep})) {
 403                                 my $ref = \$extras{$dep}; # Take reference.
 404                                 if ($$ref !~ m/needed by/) {
 405                                         # First dependency found.
 406                                         if ($$ref =~ m/enabled/) {
 407                                                 $$ref .= " (needed by \e[32;1m$extra\e[0m";
 408                                         } else {
 409                                                 $$ref =~ s/\e\[.*?m//g; # Strip out previous coloring. Will be set in bold+red+blink later.
 410                                                 $$ref .= " (needed by \e[0;32;1;5m$extra\e[0;31;1;5m";
 411                                         }
 412                                 } else {
 413                                         if ($$ref =~ m/enabled/) {
 414                                                 $$ref .= ", \e[32;1m$extra\e[0m";
 415                                         } else {
 416                                                 $$ref .= ", \e[0;32;1;5m$extra\e[0;31;1;5m";
 417                                         }
 418                                 }
 419                         }
 420                 }
 421         }
 422         for my $extra (sort {$a cmp $b} keys(%extras)) {
 423                 my $text = $extras{$extra};
 424                 if ($text =~ m/needed by/ && $text !~ m/enabled/) {
 425                         printf "\e[31;1;5m%-*s = %s%s\e[0m\n", $maxlen, $extra, $text, ($text =~ m/needed by/ ? ")" : "");
 426                 } else {
 427                         printf "%-*s = %s%s\n", $maxlen, $extra, $text, ($text =~ m/needed by/ ? "\e[0m)" : "");
 428                 }
 429         }
 430         return keys(%extras) if wantarray; # Can be used by manage_extras.
 431 }
 432
 433 sub enable_extras (@) {
 434         my (@extras) = @_;
 435         for my $extra (@extras) {
 436                 my $extrapath = "src/modules/extra/$extra";
 437                 if (!-e $extrapath) {
 438                         print STDERR "Cannot enable \e[32;1m$extra\e[0m : No such file or directory in src/modules/extra\n";
 439                         next;
 440                 }
 441                 my $source = "src/modules/$extra";
 442                 if (-e $source) {
 443                         print STDERR "Cannot enable \e[32;1m$extra\e[0m : destination in src/modules exists (might already be enabled?)\n";
 444                         next;
 445                 }
 446                 # Get dependencies, and add them to be processed.
 447                 my @deps = split /\s+/, get_directive($extrapath, 'ModDep', '');
 448                 for my $dep (@deps) {
 449                         next if scalar(grep { $_ eq $dep } (@extras)) > 0; # Skip if we're going to be enabling it anyway.
 450                         if (!-e "src/modules/$dep" && !-e "include/$dep") {
 451                                 if (-e "src/modules/extra/$dep") {
 452                                         print STDERR "Will also enable extra \e[32;1m$dep\e[0m (needed by \e[32;1m$extra\e[0m)\n";
 453                                         push @extras, $dep;
 454                                 } else {
 455                                         print STDERR "\e[33;1mWARNING:\e[0m module \e[32;1m$extra\e[0m might be missing dependency \e[32;1m$dep\e[0m - YOU are responsible for satisfying it!\n";
 456                                 }
 457                         }
 458                 }
 459                 print "Enabling $extra ... \n";
 460                 symlink "extra/$extra", $source or print STDERR "$source: Cannot link to 'extra/$extra': $!\n";
 461         }
 462 }
 463
 464 sub disable_extras (@)
 465 {
 466         opendir my $dd, "src/modules/extra/";
 467         my @files = readdir($dd);
 468         closedir $dd;
 469         my (@extras) = @_;
 470 EXTRA:  for my $extra (@extras) {
 471                 my $extrapath = "src/modules/extra/$extra";
 472                 my $source = "src/modules/$extra";
 473                 if (!-e $extrapath) {
 474                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : Is not an extra\n";
 475                         next;
 476                 }
 477                 if ((! -l $source) || readlink($source) ne "extra/$extra") {
 478                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : Source is not a link or doesn't refer to the right file. Remove manually if this is in error.\n";
 479                         next;
 480                 }
 481                 # Check if anything needs this.
 482                 for my $file (@files) {
 483                         my @deps = split /\s+/, get_directive("src/modules/extra/$file", 'ModDep', '');
 484                         # File depends on this extra...
 485                         if (scalar(grep { $_ eq $extra } @deps) > 0) {
 486                                 # And is both enabled and not about to be disabled.
 487                                 if (-e "src/modules/$file" && scalar(grep { $_ eq $file } @extras) < 1) {
 488                                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : is needed by \e[32;1m$file\e[0m\n";
 489                                         next EXTRA;
 490                                 }
 491                         }
 492                 }
 493                 # Now remove.
 494                 print "Disabling $extra ... \n";
 495                 unlink "src/modules/$extra" or print STDERR "Cannot disable \e[32;1m$extra\e[0m : $!\n";
 496         }
 497 }