configure

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   7 #   Copyright (C) 2009-2010 Daniel De Graaf <danieldg@inspircd.org>
   8 #   Copyright (C) 2007, 2009 Dennis Friis <peavey@inspircd.org>
   9 #   Copyright (C) 2003, 2006-2008 Craig Edwards <craigedwards@brainbox.cc>
  10 #   Copyright (C) 2006-2008 Robin Burchell <robin+git@viroteck.net>
  11 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
  12 #   Copyright (C) 2007 John Brooks <john.brooks@dereferenced.net>
  13 #   Copyright (C) 2006 Oliver Lupton <oliverlupton@gmail.com>
  14 #   Copyright (C) 2003-2006 Craig McLure <craig@chatspike.net>
  15 #
  16 # This file is part of InspIRCd.  InspIRCd is free software: you can
  17 # redistribute it and/or modify it under the terms of the GNU General Public
  18 # License as published by the Free Software Foundation, version 2.
  19 #
  20 # This program is distributed in the hope that it will be useful, but WITHOUT
  21 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  22 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  23 # details.
  24 #
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  27 #
  28
  29
  30 BEGIN {
  31         require 5.10.0;
  32 }
  33
  34 use feature ':5.10';
  35 use strict;
  36 use warnings FATAL => qw(all);
  37
  38 use File::Basename        qw(basename);
  39 use File::Copy            ();
  40 use File::Spec::Functions qw(rel2abs);
  41 use FindBin               qw($RealDir);
  42 use Getopt::Long          qw(GetOptions);
  43 use POSIX                 qw(getgid getuid);
  44
  45 use lib $RealDir;
  46 use make::common;
  47 use make::configure;
  48 use make::console;
  49 use make::directive;
  50
  51 my ($opt_binary_dir,
  52     $opt_config_dir,
  53     $opt_data_dir,
  54     $opt_development,
  55     $opt_disable_interactive,
  56     $opt_distribution_label,
  57     $opt_gid,
  58     $opt_log_dir,
  59     $opt_manual_dir,
  60     $opt_module_dir,
  61     $opt_prefix,
  62     $opt_script_dir,
  63     $opt_socketengine,
  64     $opt_system,
  65     $opt_uid);
  66
  67 sub list_extras ();
  68
  69 sub enable_extras (@);
  70
  71 sub disable_extras (@);
  72
  73 my @opt_enableextras;
  74 my @opt_disableextras;
  75
  76 GetOptions(
  77         'clean'  => \&cmd_clean,
  78         'help'   => \&cmd_help,
  79         'update' => \&cmd_update,
  80
  81         'development'          => \$opt_development,
  82         'disable-interactive'  => \$opt_disable_interactive,
  83         'distribution-label=s' => \$opt_distribution_label,
  84         'binary-dir=s'         => \$opt_binary_dir,
  85         'config-dir=s'         => \$opt_config_dir,
  86         'data-dir=s'           => \$opt_data_dir,
  87         'gid=s'                => \$opt_gid,
  88         'log-dir=s'            => \$opt_log_dir,
  89         'manual-dir=s'         => \$opt_manual_dir,
  90         'module-dir=s'         => \$opt_module_dir,
  91         'prefix=s'             => \$opt_prefix,
  92         'script-dir=s'         => \$opt_script_dir,
  93         'socketengine=s'       => \$opt_socketengine,
  94         'system'               => \$opt_system,
  95         'uid=s'                => \$opt_uid,
  96
  97         # TODO: when the modulemanager rewrite is done these should be removed.
  98         'disable-extras=s@' => \@opt_disableextras,
  99         'enable-extras=s@'  => \@opt_enableextras,
 100         'list-extras'       => sub { list_extras; exit 0; },
 101 );
 102
 103 if (scalar(@opt_enableextras) + scalar(@opt_disableextras) > 0) {
 104         @opt_enableextras = split /,/, join(',', @opt_enableextras);
 105         @opt_disableextras = split /,/, join(',', @opt_disableextras);
 106         enable_extras(@opt_enableextras);
 107         disable_extras(@opt_disableextras);
 108         list_extras;
 109         print "Remember: YOU are responsible for making sure any libraries needed have been installed!\n";
 110         exit 0;
 111 }
 112
 113 our $interactive = !(
 114         !-t STDIN ||
 115         !-t STDOUT ||
 116         defined $opt_binary_dir ||
 117         defined $opt_config_dir ||
 118         defined $opt_data_dir ||
 119         defined $opt_development ||
 120         defined $opt_disable_interactive ||
 121         defined $opt_distribution_label ||
 122         defined $opt_gid ||
 123         defined $opt_log_dir ||
 124         defined $opt_manual_dir ||
 125         defined $opt_module_dir ||
 126         defined $opt_prefix ||
 127         defined $opt_script_dir ||
 128         defined $opt_socketengine ||
 129         defined $opt_system ||
 130         defined $opt_uid
 131 );
 132
 133 my %version = get_version $opt_distribution_label;
 134 print_format "<|BOLD Configuring InspIRCd $version{FULL} on $^O.|>\n";
 135
 136 my %config;
 137 if ($interactive) {
 138         %config = read_config_file(CONFIGURE_CACHE_FILE);
 139         run_test CONFIGURE_CACHE_FILE, %config;
 140         if (!defined $config{VERSION}) {
 141                 $config{VERSION} = CONFIGURE_CACHE_VERSION;
 142         } elsif ($config{VERSION} != CONFIGURE_CACHE_VERSION) {
 143                 print_warning "ignoring contents of ${\CONFIGURE_CACHE_FILE} as it was generated by an incompatible version of $0!";
 144                 %config = ('VERSION', CONFIGURE_CACHE_VERSION);
 145         }
 146 }
 147
 148 $config{CXX} = find_compiler($config{CXX} // $ENV{CXX});
 149 unless ($config{CXX}) {
 150         say 'A suitable C++ compiler could not be detected on your system!';
 151         unless ($interactive) {
 152                 say 'Set the CXX environment variable to the path to a C++ compiler binary if this is incorrect.';
 153                 exit 1;
 154         }
 155         until ($config{CXX}) {
 156                 my $compiler_path = prompt_string 1, 'Please enter the path to a C++ compiler binary:', 'c++';
 157                 $config{CXX} = find_compiler $compiler_path;
 158         }
 159 }
 160 my %compiler = get_compiler_info($config{CXX});
 161
 162 $config{HAS_ARC4RANDOM_BUF} = run_test 'arc4random_buf()', test_file($config{CXX}, 'arc4random_buf.cpp');
 163 $config{HAS_CLOCK_GETTIME} = run_test 'clock_gettime()', test_file($config{CXX}, 'clock_gettime.cpp', $^O eq 'darwin' ? undef : '-lrt');
 164 $config{HAS_EVENTFD} = run_test 'eventfd()', test_file($config{CXX}, 'eventfd.cpp');
 165
 166 my @socketengines;
 167 push @socketengines, 'epoll'  if run_test 'epoll', test_header $config{CXX}, 'sys/epoll.h';
 168 push @socketengines, 'kqueue' if run_test 'kqueue', test_file $config{CXX}, 'kqueue.cpp';
 169 push @socketengines, 'poll'   if run_test 'poll', test_header $config{CXX}, 'poll.h';
 170 push @socketengines, 'select';
 171
 172 if (defined $opt_socketengine) {
 173         unless (grep { $_ eq $opt_socketengine } @socketengines) {
 174                 my $reason = -f "src/socketengines/socketengine_$opt_socketengine.cpp" ? 'is not available on this platform' : 'does not exist';
 175                 print_error "The socket engine you requested ($opt_socketengine) $reason!",
 176                         'Available socket engines are:',
 177                         map { "  * $_" } @socketengines;
 178         }
 179 }
 180 $config{SOCKETENGINE} = $opt_socketengine // $socketengines[0];
 181
 182 if (defined $opt_system) {
 183         $config{BASE_DIR}   = $opt_prefix     // '/var/lib/inspircd';
 184         $config{BINARY_DIR} = $opt_binary_dir // '/usr/sbin';
 185         $config{CONFIG_DIR} = $opt_config_dir // '/etc/inspircd';
 186         $config{DATA_DIR}   = $opt_data_dir   // '/var/inspircd';
 187         $config{LOG_DIR}    = $opt_module_dir // '/var/log/inspircd';
 188         $config{MANUAL_DIR} = $opt_manual_dir // '/usr/share/man/man1';
 189         $config{MODULE_DIR} = $opt_module_dir // '/usr/lib/inspircd';
 190         $config{SCRIPT_DIR} = $opt_script_dir // '/usr/share/inspircd'
 191 } else {
 192         $config{BASE_DIR}   = $opt_prefix     // $config{BASE_DIR}   // rel2abs 'run';
 193         $config{BINARY_DIR} = $opt_binary_dir // $config{BINARY_DIR} // rel2abs $config{BASE_DIR} . '/bin';
 194         $config{CONFIG_DIR} = $opt_config_dir // $config{CONFIG_DIR} // rel2abs $config{BASE_DIR} . '/conf';
 195         $config{DATA_DIR}   = $opt_data_dir   // $config{DATA_DIR}   // rel2abs $config{BASE_DIR} . '/data';
 196         $config{LOG_DIR}    = $opt_log_dir    // $config{LOG_DIR}    // rel2abs $config{BASE_DIR} . '/logs';
 197         $config{MANUAL_DIR} = $opt_manual_dir // $config{MANUAL_DIR} // rel2abs $config{BASE_DIR} . '/manuals';
 198         $config{MODULE_DIR} = $opt_module_dir // $config{MODULE_DIR} // rel2abs $config{BASE_DIR} . '/modules';
 199         $config{SCRIPT_DIR} = $opt_script_dir // $config{SCRIPT_DIR} // $config{BASE_DIR};
 200 }
 201
 202 # Parse --gid=123 or --gid=foo and extract the group id.
 203 my @group;
 204 if (defined $opt_gid) {
 205         @group = $opt_gid =~ /^\d+$/ ? getgrgid($opt_gid) : getgrnam($opt_gid);
 206         print_error "there is no '$opt_gid' group on this system!" unless @group;
 207 } else {
 208         @group = $opt_system ? getgrnam('irc') : getgrgid($config{GID} // getgid());
 209         print_error "you need to specify a group to run as using '--gid [id|name]'!" unless @group;
 210 }
 211 $config{GROUP} = $group[0];
 212 $config{GID}   = $group[2];
 213
 214 # Parse --uid=123 or --uid=foo and extract the user id.
 215 my @user;
 216 if (defined $opt_uid) {
 217         @user = $opt_uid =~ /^\d+$/ ? getpwuid($opt_uid) : getpwnam($opt_uid);
 218         print_error "there is no '$opt_uid' user on this system!" unless @user;
 219 } else {
 220         @user = $opt_system ? getpwnam('irc') : getpwuid($config{UID} // getuid());
 221         print_error "you need to specify a user to run as using '--uid [id|name]'!" unless @user;
 222 }
 223 $config{USER} = $user[0];
 224 $config{UID}  = $user[2];
 225
 226 # Clear the screen.
 227 system 'tput', 'clear' if $interactive;
 228
 229 # Warn the user about clock drifting when running on OpenVZ.
 230 if (-e '/proc/user_beancounters' || -e '/proc/vz/vzaquota') {
 231         print_warning <<'EOW';
 232 You are building InspIRCd inside of an an OpenVZ container. If you
 233 plan to use InspIRCd in this container then you should make sure that NTP is
 234 configured on the Hardware Node. Failure to do so may result in clock drifting!
 235 EOW
 236 }
 237
 238 # Check that the user actually wants this version.
 239 if ($version{LABEL} ne 'release') {
 240         print_warning <<'EOW';
 241 You are building a development version. This contains code which has
 242 not been tested as heavily and may contain various faults which could seriously
 243 affect the running of your server. It is recommended that you use a stable
 244 version instead.
 245
 246 You can obtain the latest stable version from http://www.inspircd.org/ or by
 247 running `<|GREEN git checkout $(git describe --abbrev=0 --tags insp20)|>` if you are
 248 installing from Git.
 249 EOW
 250         if (!prompt_bool $interactive, 'I understand this warning and want to continue anyway.', $opt_development // 0) {
 251                 say STDERR 'If you understand this warning and still want to continue pass the --development flag.' unless $interactive;
 252                 exit 1;
 253         }
 254 }
 255
 256 # Configure directory settings.
 257 my $question = <<"EOQ";
 258 Currently, InspIRCd is configured with the following paths:
 259
 260 <|BOLD Base:|>   $config{BASE_DIR}
 261 <|BOLD Binary:|> $config{BINARY_DIR}
 262 <|BOLD Config:|> $config{CONFIG_DIR}
 263 <|BOLD Data:|>   $config{DATA_DIR}
 264 <|BOLD Log:|>    $config{LOG_DIR}
 265 <|BOLD Manual:|> $config{MANUAL_DIR}
 266 <|BOLD Module:|> $config{MODULE_DIR}
 267 <|BOLD Script:|> $config{SCRIPT_DIR}
 268
 269 Do you want to change these settings?
 270 EOQ
 271 if (prompt_bool $interactive, $question, 0) {
 272         my $original_base_dir = $config{BASE_DIR};
 273         $config{BASE_DIR} = prompt_dir $interactive, 'In what directory do you wish to install the InspIRCd base?', $config{BASE_DIR};
 274         foreach my $key (qw(BINARY_DIR CONFIG_DIR DATA_DIR LOG_DIR MANUAL_DIR MODULE_DIR SCRIPT_DIR)) {
 275                 $config{$key} =~ s/^\Q$original_base_dir\E/$config{BASE_DIR}/;
 276         }
 277         $config{BINARY_DIR} = prompt_dir $interactive, 'In what directory should the InspIRCd binary be placed?', $config{BINARY_DIR};
 278         $config{CONFIG_DIR} = prompt_dir $interactive, 'In what directory are configuration files to be stored?', $config{CONFIG_DIR};
 279         $config{DATA_DIR}   = prompt_dir $interactive, 'In what directory are variable data files to be stored?', $config{DATA_DIR};
 280         $config{LOG_DIR}    = prompt_dir $interactive, 'In what directory are log files to be stored?',           $config{LOG_DIR};
 281         $config{MANUAL_DIR} = prompt_dir $interactive, 'In what directory are manual pages to be placed?',        $config{MANUAL_DIR};
 282         $config{MODULE_DIR} = prompt_dir $interactive, 'In what directory are modules to be placed?',             $config{MODULE_DIR};
 283         $config{SCRIPT_DIR} = prompt_dir $interactive, 'In what directory are scripts to be placed?',             $config{SCRIPT_DIR};
 284 }
 285
 286 # Configure module settings.
 287 $question = <<'EOQ';
 288 Currently, InspIRCd is configured to automatically enable all available extra modules.
 289
 290 Would you like to enable extra modules manually?
 291 EOQ
 292 if (prompt_bool $interactive, $question, 0) {
 293         foreach my $extra (<src/modules/extra/m_*.cpp>) {
 294                 my $module_name = basename $extra, '.cpp';
 295                 if (prompt_bool $interactive, "Would you like to enable $module_name?", 0) {
 296                         enable_extras "$module_name.cpp";
 297                 }
 298         }
 299 } else {
 300         # TODO: finish modulemanager rewrite and replace this code with:
 301         # system './modulemanager', 'enable', '--auto';
 302         enable_extras 'm_ssl_gnutls.cpp' unless system 'pkg-config --exists gnutls >/dev/null 2>&1';
 303         enable_extras 'm_ssl_mbedtls.cpp' if -e '/usr/include/mbedtls/ssl.h';
 304         enable_extras 'm_ssl_openssl.cpp' unless system 'pkg-config --exists openssl >/dev/null 2>&1';
 305 }
 306
 307 # Generate SSL certificates.
 308 $question = <<EOQ;
 309 Would you like to generate a self-signed SSL certificate now? This certificate
 310 can be used for testing but <|BOLD should not|> be used on a production network.
 311
 312 Note: you can get a <|BOLD free|> CA-signed certificate from Let's Encrypt. See
 313 https://letsencrypt.org/getting-started/ for more details.
 314 EOQ
 315
 316 if (<src/modules/m_ssl_*.cpp> && prompt_bool $interactive, $question, $interactive) {
 317         system './tools/genssl', 'auto';
 318 }
 319
 320 # Cache the distribution label so that its not lost when --update is run.
 321 $config{DISTRIBUTION} = $opt_distribution_label if $opt_distribution_label;
 322
 323 write_configure_cache %config;
 324 parse_templates \%config, \%compiler, \%version;
 325
 326 print_format <<"EOM";
 327
 328 Configuration is complete! You have chosen to build with the following settings:
 329
 330 <|GREEN Compiler:|>
 331   <|GREEN Binary:|>  $config{CXX}
 332   <|GREEN Name:|>    $compiler{NAME}
 333   <|GREEN Version:|> $compiler{VERSION}
 334
 335 <|GREEN Extra Modules:|>
 336 EOM
 337
 338 for my $file (<src/modules/m_*>) {
 339         my $module = basename $file, '.cpp';
 340         say "  * $module" if -l $file;
 341 }
 342
 343 print_format <<"EOM";
 344
 345 <|GREEN Paths:|>
 346   <|GREEN Base:|>   $config{BASE_DIR}
 347   <|GREEN Binary:|> $config{BINARY_DIR}
 348   <|GREEN Config:|> $config{CONFIG_DIR}
 349   <|GREEN Data:|>   $config{DATA_DIR}
 350   <|GREEN Log:|>    $config{LOG_DIR}
 351   <|GREEN Manual:|> $config{MANUAL_DIR}
 352   <|GREEN Module:|> $config{MODULE_DIR}
 353   <|GREEN Script:|> $config{SCRIPT_DIR}
 354
 355 <|GREEN Execution Group:|> $config{GROUP} ($config{GID})
 356 <|GREEN Execution User:|>  $config{USER} ($config{UID})
 357 <|GREEN Socket Engine:|>   $config{SOCKETENGINE}
 358
 359 To build with these settings run '<|GREEN make -j${\get_cpu_count}|>' now.
 360
 361 EOM
 362
 363 # Routine to list out the extra/ modules that have been enabled.
 364 # Note: when getting any filenames out and comparing, it's important to lc it if the
 365 # file system is not case-sensitive (== Epoc, MacOS, OS/2 (incl DOS/DJGPP), VMS, Win32
 366 # (incl NetWare, Symbian)). Cygwin may or may not be case-sensitive, depending on
 367 # configuration, however, File::Spec does not currently tell us (it assumes Unix behavior).
 368 sub list_extras () {
 369         use File::Spec;
 370         # @_ not used
 371         my $srcdir = File::Spec->catdir("src", "modules");
 372         my $abs_srcdir = File::Spec->rel2abs($srcdir);
 373         local $_;
 374         my $dd;
 375         opendir $dd, File::Spec->catdir($abs_srcdir, "extra") or die (File::Spec->catdir($abs_srcdir, "extra") . ": $!\n");
 376         my @extras = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 377         closedir $dd;
 378         undef $dd;
 379         opendir $dd, $abs_srcdir or die "$abs_srcdir: $!\n";
 380         my @sources = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 381         closedir $dd;
 382         undef $dd;
 383         my $maxlen = (sort { $b <=> $a } (map {length($_)} (@extras)))[0];
 384         my %extras = ();
 385 EXTRA:  for my $extra (@extras) {
 386                 next if (File::Spec->curdir() eq $extra || File::Spec->updir() eq $extra);
 387                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 388                 my $abs_source = File::Spec->catfile($abs_srcdir, $extra);
 389                 next unless ($extra =~ m/\.(cpp|h)$/ || (-d $abs_extra)); # C++ Source/Header, or directory
 390                 if (-l $abs_source) {
 391                         # Symlink, is it in the right place?
 392                         my $targ = readlink($abs_source);
 393                         my $abs_targ = File::Spec->rel2abs($targ, $abs_srcdir);
 394                         if ($abs_targ eq $abs_extra) {
 395                                 $extras{$extra} = "\e[32;1menabled\e[0m";
 396                         } else {
 397                                 $extras{$extra} = sprintf("\e[31;1mwrong symlink target (%s)\e[0m", $abs_targ);
 398                         }
 399                 } elsif (-e $abs_source) {
 400                         my ($devext, $inoext) = stat($abs_extra);
 401                         my ($devsrc, $inosrc, undef, $lnksrc) = stat($abs_source);
 402                         if ($lnksrc > 1) {
 403                                 if ($devsrc == $devext && $inosrc == $inoext) {
 404                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 405                                 } else {
 406                                         $extras{$extra} = sprintf("\e[31;1mwrong hardlink target (%d:%d)\e[0m", $devsrc, $inosrc);
 407                                 }
 408                         } else {
 409                                 open my $extfd, "<", $abs_extra;
 410                                 open my $srcfd, "<", $abs_source;
 411                                 local $/ = undef;
 412                                 if (scalar(<$extfd>) eq scalar(<$srcfd>)) {
 413                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 414                                 } else {
 415                                         $extras{$extra} = sprintf("\e[31;1mout of synch (re-copy)\e[0m");
 416                                 }
 417                         }
 418                 } else {
 419                         $extras{$extra} = "\e[33;1mdisabled\e[0m";
 420                 }
 421         }
 422         # Now let's add dependency info
 423         for my $extra (keys(%extras)) {
 424                 next unless $extras{$extra} =~ m/enabled/; # only process enabled extras.
 425                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 426                 my @deps = split /\s+/, get_directive($abs_extra, 'ModDep', '');
 427                 for my $dep (@deps) {
 428                         if (exists($extras{$dep})) {
 429                                 my $ref = \$extras{$dep}; # Take reference.
 430                                 if ($$ref !~ m/needed by/) {
 431                                         # First dependency found.
 432                                         if ($$ref =~ m/enabled/) {
 433                                                 $$ref .= " (needed by \e[32;1m$extra\e[0m";
 434                                         } else {
 435                                                 $$ref =~ s/\e\[.*?m//g; # Strip out previous coloring. Will be set in bold+red+blink later.
 436                                                 $$ref .= " (needed by \e[0;32;1;5m$extra\e[0;31;1;5m";
 437                                         }
 438                                 } else {
 439                                         if ($$ref =~ m/enabled/) {
 440                                                 $$ref .= ", \e[32;1m$extra\e[0m";
 441                                         } else {
 442                                                 $$ref .= ", \e[0;32;1;5m$extra\e[0;31;1;5m";
 443                                         }
 444                                 }
 445                         }
 446                 }
 447         }
 448         for my $extra (sort {$a cmp $b} keys(%extras)) {
 449                 my $text = $extras{$extra};
 450                 if ($text =~ m/needed by/ && $text !~ m/enabled/) {
 451                         printf "\e[31;1;5m%-*s = %s%s\e[0m\n", $maxlen, $extra, $text, ($text =~ m/needed by/ ? ")" : "");
 452                 } else {
 453                         printf "%-*s = %s%s\n", $maxlen, $extra, $text, ($text =~ m/needed by/ ? "\e[0m)" : "");
 454                 }
 455         }
 456         return keys(%extras) if wantarray; # Can be used by manage_extras.
 457 }
 458
 459 sub enable_extras (@) {
 460         my (@extras) = @_;
 461         for my $extra (@extras) {
 462                 my $extrapath = "src/modules/extra/$extra";
 463                 if (!-e $extrapath) {
 464                         print STDERR "Cannot enable \e[32;1m$extra\e[0m : No such file or directory in src/modules/extra\n";
 465                         next;
 466                 }
 467                 my $source = "src/modules/$extra";
 468                 if (-e $source) {
 469                         print STDERR "Cannot enable \e[32;1m$extra\e[0m : destination in src/modules exists (might already be enabled?)\n";
 470                         next;
 471                 }
 472                 # Get dependencies, and add them to be processed.
 473                 my @deps = split /\s+/, get_directive($extrapath, 'ModDep', '');
 474                 for my $dep (@deps) {
 475                         next if scalar(grep { $_ eq $dep } (@extras)) > 0; # Skip if we're going to be enabling it anyway.
 476                         if (!-e "src/modules/$dep" && !-e "include/$dep") {
 477                                 if (-e "src/modules/extra/$dep") {
 478                                         print STDERR "Will also enable extra \e[32;1m$dep\e[0m (needed by \e[32;1m$extra\e[0m)\n";
 479                                         push @extras, $dep;
 480                                 } else {
 481                                         print STDERR "\e[33;1mWARNING:\e[0m module \e[32;1m$extra\e[0m might be missing dependency \e[32;1m$dep\e[0m - YOU are responsible for satisfying it!\n";
 482                                 }
 483                         }
 484                 }
 485                 print "Enabling $extra ... \n";
 486                 symlink "extra/$extra", $source or print STDERR "$source: Cannot link to 'extra/$extra': $!\n";
 487         }
 488 }
 489
 490 sub disable_extras (@)
 491 {
 492         opendir my $dd, "src/modules/extra/";
 493         my @files = readdir($dd);
 494         closedir $dd;
 495         my (@extras) = @_;
 496 EXTRA:  for my $extra (@extras) {
 497                 my $extrapath = "src/modules/extra/$extra";
 498                 my $source = "src/modules/$extra";
 499                 if (!-e $extrapath) {
 500                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : Is not an extra\n";
 501                         next;
 502                 }
 503                 if ((! -l $source) || readlink($source) ne "extra/$extra") {
 504                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : Source is not a link or doesn't refer to the right file. Remove manually if this is in error.\n";
 505                         next;
 506                 }
 507                 # Check if anything needs this.
 508                 for my $file (@files) {
 509                         my @deps = split /\s+/, get_directive("src/modules/extra/$file", 'ModDep', '');
 510                         # File depends on this extra...
 511                         if (scalar(grep { $_ eq $extra } @deps) > 0) {
 512                                 # And is both enabled and not about to be disabled.
 513                                 if (-e "src/modules/$file" && scalar(grep { $_ eq $file } @extras) < 1) {
 514                                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : is needed by \e[32;1m$file\e[0m\n";
 515                                         next EXTRA;
 516                                 }
 517                         }
 518                 }
 519                 # Now remove.
 520                 print "Disabling $extra ... \n";
 521                 unlink "src/modules/$extra" or print STDERR "Cannot disable \e[32;1m$extra\e[0m : $!\n";
 522         }
 523 }