configure

   1 #!/usr/bin/env perl
   2 #
   3 # InspIRCd -- Internet Relay Chat Daemon
   4 #
   5 #   Copyright (C) 2020 Nicole Kleinhoff <ilbelkyr@shalture.org>
   6 #   Copyright (C) 2020 Daniel Vassdal <shutter@canternet.org>
   7 #   Copyright (C) 2019 Matt Schatz <genius3000@g3k.solutions>
   8 #   Copyright (C) 2019 Anatole Denis <natolumin@rezel.net>
   9 #   Copyright (C) 2017 emerson <github@emersonveenstra.net>
  10 #   Copyright (C) 2013-2020 Sadie Powell <sadie@witchery.services>
  11 #   Copyright (C) 2012, 2019 Robby <robby@chatbelgie.be>
  12 #   Copyright (C) 2012 ChrisTX <xpipe@hotmail.de>
  13 #   Copyright (C) 2010 Daniel De Graaf <danieldg@inspircd.org>
  14 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
  15 #   Copyright (C) 2008 Robin Burchell <robin+git@viroteck.net>
  16 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
  17 #   Copyright (C) 2006-2008 Craig Edwards <brain@inspircd.org>
  18 #
  19 # This file is part of InspIRCd.  InspIRCd is free software: you can
  20 # redistribute it and/or modify it under the terms of the GNU General Public
  21 # License as published by the Free Software Foundation, version 2.
  22 #
  23 # This program is distributed in the hope that it will be useful, but WITHOUT
  24 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  25 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  26 # details.
  27 #
  28 # You should have received a copy of the GNU General Public License
  29 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  30 #
  31
  32
  33 use v5.10.0;
  34 use strict;
  35 use warnings FATAL => qw(all);
  36
  37 use Cwd                   qw(getcwd);
  38 use File::Basename        qw(basename);
  39 use File::Copy            ();
  40 use File::Spec::Functions qw(abs2rel catfile catdir rel2abs);
  41 use FindBin               qw($RealDir);
  42 use Getopt::Long          qw(GetOptions);
  43 use POSIX                 qw(getgid getuid);
  44
  45 use lib $RealDir;
  46 use make::common;
  47 use make::configure;
  48 use make::console;
  49 use make::directive;
  50
  51 my ($opt_binary_dir,
  52     $opt_config_dir,
  53     $opt_data_dir,
  54     $opt_development,
  55     $opt_disable_auto_extras,
  56     $opt_disable_interactive,
  57     $opt_distribution_label,
  58     $opt_example_dir,
  59     $opt_gid,
  60     $opt_log_dir,
  61     $opt_manual_dir,
  62     $opt_module_dir,
  63     $opt_portable,
  64     $opt_prefix,
  65     $opt_runtime_dir,
  66     $opt_script_dir,
  67     $opt_socketengine,
  68     $opt_system,
  69     $opt_uid);
  70
  71 sub list_extras ();
  72
  73 sub enable_extras (@);
  74
  75 sub disable_extras (@);
  76
  77 my @opt_enableextras;
  78 my @opt_disableextras;
  79
  80 exit 1 unless GetOptions(
  81         'clean'  => \&cmd_clean,
  82         'help'   => \&cmd_help,
  83         'update' => \&cmd_update,
  84
  85         'binary-dir=s'         => \$opt_binary_dir,
  86         'config-dir=s'         => \$opt_config_dir,
  87         'data-dir=s'           => \$opt_data_dir,
  88         'development'          => \$opt_development,
  89         'disable-auto-extras'  => \$opt_disable_auto_extras,
  90         'disable-interactive'  => \$opt_disable_interactive,
  91         'distribution-label=s' => \$opt_distribution_label,
  92         'example-dir=s'        => \$opt_example_dir,
  93         'gid=s'                => \$opt_gid,
  94         'log-dir=s'            => \$opt_log_dir,
  95         'manual-dir=s'         => \$opt_manual_dir,
  96         'module-dir=s'         => \$opt_module_dir,
  97         'portable'             => \$opt_portable,
  98         'prefix=s'             => \$opt_prefix,
  99         'runtime-dir=s'        => \$opt_runtime_dir,
 100         'script-dir=s'         => \$opt_script_dir,
 101         'socketengine=s'       => \$opt_socketengine,
 102         'system'               => \$opt_system,
 103         'uid=s'                => \$opt_uid,
 104
 105         # TODO: when the modulemanager rewrite is done these should be removed.
 106         'disable-extras=s@' => \@opt_disableextras,
 107         'enable-extras=s@'  => \@opt_enableextras,
 108         'list-extras'       => sub { list_extras; exit 0; },
 109 );
 110
 111 if (scalar(@opt_enableextras) + scalar(@opt_disableextras) > 0) {
 112         @opt_enableextras = grep { /\S/ } split /[, ]+/, join(',', @opt_enableextras);
 113         @opt_disableextras = grep { /\S/ } split /[, ]+/, join(',', @opt_disableextras);
 114         enable_extras(@opt_enableextras);
 115         disable_extras(@opt_disableextras);
 116         list_extras;
 117         print "Remember: YOU are responsible for making sure any libraries needed have been installed!\n";
 118         exit 0;
 119 }
 120
 121 our $interactive = !(
 122         !-t STDIN ||
 123         !-t STDOUT ||
 124         defined $opt_binary_dir ||
 125         defined $opt_config_dir ||
 126         defined $opt_data_dir ||
 127         defined $opt_development ||
 128         defined $opt_disable_auto_extras ||
 129         defined $opt_disable_interactive ||
 130         defined $opt_distribution_label ||
 131         defined $opt_example_dir ||
 132         defined $opt_gid ||
 133         defined $opt_log_dir ||
 134         defined $opt_manual_dir ||
 135         defined $opt_module_dir ||
 136         defined $opt_portable ||
 137         defined $opt_prefix ||
 138         defined $opt_runtime_dir ||
 139         defined $opt_script_dir ||
 140         defined $opt_socketengine ||
 141         defined $opt_system ||
 142         defined $opt_uid
 143 );
 144
 145 my %version = get_version $opt_distribution_label;
 146 say console_format "<|BOLD Configuring InspIRCd $version{FULL} on $^O.|>";
 147
 148 my %config;
 149 if ($interactive) {
 150         %config = read_config_file(CONFIGURE_CACHE_FILE);
 151         run_test abs2rel(CONFIGURE_CACHE_FILE, $RealDir), %config;
 152         if (!defined $config{VERSION}) {
 153                 $config{VERSION} = CONFIGURE_CACHE_VERSION;
 154         } elsif ($config{VERSION} != CONFIGURE_CACHE_VERSION) {
 155                 print_warning "ignoring contents of ${\CONFIGURE_CACHE_FILE} as it was generated by an incompatible version of $0!";
 156                 %config = ('VERSION', CONFIGURE_CACHE_VERSION);
 157         }
 158 }
 159
 160 $config{CXX} = find_compiler($config{CXX} // $ENV{CXX});
 161 unless ($config{CXX}) {
 162         say 'A suitable C++ compiler could not be detected on your system!';
 163         unless ($interactive) {
 164                 say 'Set the CXX environment variable to the path to a C++ compiler binary if this is incorrect.';
 165                 exit 1;
 166         }
 167         until ($config{CXX}) {
 168                 my $compiler_path = prompt_string 1, 'Please enter the path to a C++ compiler binary:', 'c++';
 169                 $config{CXX} = find_compiler $compiler_path;
 170         }
 171 }
 172 my %compiler = get_compiler_info($config{CXX});
 173
 174 $config{HAS_ARC4RANDOM_BUF} = run_test 'arc4random_buf()', test_file($config{CXX}, 'arc4random_buf.cpp');
 175 $config{HAS_CLOCK_GETTIME} = run_test 'clock_gettime()', test_file($config{CXX}, 'clock_gettime.cpp', $^O eq 'darwin' ? undef : '-lrt');
 176 $config{HAS_EVENTFD} = run_test 'eventfd()', test_file($config{CXX}, 'eventfd.cpp');
 177
 178 my @socketengines;
 179 push @socketengines, 'epoll'  if run_test 'epoll', test_header $config{CXX}, 'sys/epoll.h';
 180 push @socketengines, 'kqueue' if run_test 'kqueue', test_file $config{CXX}, 'kqueue.cpp';
 181 push @socketengines, 'poll'   if run_test 'poll', test_header $config{CXX}, 'poll.h';
 182 push @socketengines, 'select';
 183
 184 if (defined $opt_socketengine) {
 185         unless (grep { $_ eq $opt_socketengine } @socketengines) {
 186                 my $reason = -f "src/socketengines/socketengine_$opt_socketengine.cpp" ? 'is not available on this platform' : 'does not exist';
 187                 print_error "The socket engine you requested ($opt_socketengine) $reason!",
 188                         'Available socket engines are:',
 189                         map { "  * $_" } @socketengines;
 190         }
 191 }
 192 $config{SOCKETENGINE} = $opt_socketengine // $socketengines[0];
 193
 194 if (defined $opt_portable) {
 195         print_error '--portable and --system can not be used together!' if defined $opt_system;
 196         $config{DESTDIR}     = catfile $RealDir, 'run', '';
 197         $config{BASE_DIR}    = $opt_prefix      // '';
 198         $config{BINARY_DIR}  = $opt_binary_dir  // 'bin';
 199         $config{CONFIG_DIR}  = $opt_config_dir  // 'conf';
 200         $config{DATA_DIR}    = $opt_data_dir    // 'data';
 201         $config{EXAMPLE_DIR} = $opt_example_dir // catdir $config{CONFIG_DIR}, 'examples';
 202         $config{LOG_DIR}     = $opt_log_dir     // 'logs';
 203         $config{MANUAL_DIR}  = $opt_manual_dir  // 'manuals';
 204         $config{MODULE_DIR}  = $opt_module_dir  // 'modules';
 205         $config{RUNTIME_DIR} = $opt_runtime_dir // $config{DATA_DIR};
 206         $config{SCRIPT_DIR}  = $opt_script_dir  // $config{BASE_DIR};
 207 } elsif (defined $opt_system) {
 208         $config{BASE_DIR}    = $opt_prefix      // '/var/lib/inspircd';
 209         $config{BINARY_DIR}  = $opt_binary_dir  // '/usr/sbin';
 210         $config{CONFIG_DIR}  = $opt_config_dir  // '/etc/inspircd';
 211         $config{DATA_DIR}    = $opt_data_dir    // '/var/inspircd';
 212         $config{EXAMPLE_DIR} = $opt_example_dir // '/usr/share/doc/inspircd';
 213         $config{LOG_DIR}     = $opt_log_dir     // '/var/log/inspircd';
 214         $config{MANUAL_DIR}  = $opt_manual_dir  // '/usr/share/man/man1';
 215         $config{MODULE_DIR}  = $opt_module_dir  // '/usr/lib/inspircd';
 216         $config{RUNTIME_DIR} = $opt_runtime_dir // '/var/run';
 217         $config{SCRIPT_DIR}  = $opt_script_dir  // '/usr/share/inspircd';
 218 } else {
 219         $config{BASE_DIR}    = rel2abs $opt_prefix // $config{BASE_DIR}    // catdir $RealDir,            'run';
 220         $config{BINARY_DIR}  = $opt_binary_dir     // $config{BINARY_DIR}  // catdir $config{BASE_DIR},   'bin';
 221         $config{CONFIG_DIR}  = $opt_config_dir     // $config{CONFIG_DIR}  // catdir $config{BASE_DIR},   'conf';
 222         $config{DATA_DIR}    = $opt_data_dir       // $config{DATA_DIR}    // catdir $config{BASE_DIR},   'data';
 223         $config{EXAMPLE_DIR} = $opt_example_dir    // $config{EXAMPLE_DIR} // catdir $config{CONFIG_DIR}, 'examples';
 224         $config{LOG_DIR}     = $opt_log_dir        // $config{LOG_DIR}     // catdir $config{BASE_DIR},   'logs';
 225         $config{MANUAL_DIR}  = $opt_manual_dir     // $config{MANUAL_DIR}  // catdir $config{BASE_DIR},   'manuals';
 226         $config{MODULE_DIR}  = $opt_module_dir     // $config{MODULE_DIR}  // catdir $config{BASE_DIR},   'modules';
 227         $config{RUNTIME_DIR} = $opt_runtime_dir    // $config{RUNTIME_DIR} // $config{DATA_DIR};
 228         $config{SCRIPT_DIR}  = $opt_script_dir     // $config{SCRIPT_DIR}  // $config{BASE_DIR};
 229 }
 230
 231 # Parse --gid=123 or --gid=foo and extract the group id.
 232 my @group;
 233 if (defined $opt_gid) {
 234         @group = $opt_gid =~ /^\d+$/ ? getgrgid($opt_gid) : getgrnam($opt_gid);
 235         print_error "there is no '$opt_gid' group on this system!" unless @group;
 236 } else {
 237         @group = $opt_system ? getgrnam('irc') : getgrgid($config{GID} // getgid());
 238         print_error "you need to specify a group to run as using '--gid [id|name]'!" unless @group;
 239         unless ($group[2]) {
 240                 print_warning <<"EOW";
 241 You are building as the privileged $group[0] group and have not specified
 242 an unprivileged group to run InspIRCd as.
 243
 244 This is almost never what you should do. You should probably either create a new
 245 unprivileged user/group to build and run as or pass the '--gid [id|name]' flag
 246 to specify an unprivileged group to run as.
 247 EOW
 248                 if (!prompt_bool $interactive, "Are you sure you want to build as the $group[0] group?", 0) {
 249                         # PACKAGERS: You do not need to delete this check. Use `--gid $(id -g)` or `--gid 0` instead.
 250                         say STDERR "If you are sure you want to build as the $group[0] group pass the --gid $group[2] flag." unless $interactive;
 251                         exit 1;
 252                 }
 253         }
 254 }
 255 $config{GROUP} = $group[0];
 256 $config{GID}   = $group[2];
 257
 258 # Parse --uid=123 or --uid=foo and extract the user id.
 259 my @user;
 260 if (defined $opt_uid) {
 261         @user = $opt_uid =~ /^\d+$/ ? getpwuid($opt_uid) : getpwnam($opt_uid);
 262         print_error "there is no '$opt_uid' user on this system!" unless @user;
 263 } else {
 264         @user = $opt_system ? getpwnam('irc') : getpwuid($config{UID} // getuid());
 265         print_error "you need to specify a user to run as using '--uid [id|name]'!" unless @user;
 266         unless ($user[2]) {
 267                 print_warning <<"EOW";
 268 You are building as the privileged $user[0] user and have not specified
 269 an unprivileged user to run InspIRCd as.
 270
 271 This is almost never what you should do. You should probably either create a new
 272 unprivileged user/group to build and run as or pass the '--uid [id|name]' flag
 273 to specify an unprivileged user to run as.
 274 EOW
 275                 if (!prompt_bool $interactive, "Are you sure you want to build as the $user[0] user?", 0) {
 276                         # PACKAGERS: You do not need to delete this check. Use `--uid $(id -u)` or `--uid 0` instead.
 277                         say STDERR "If you are sure you want to build as the $user[0] user pass the --uid $user[2] flag." unless $interactive;
 278                         exit 1;
 279                 }
 280         }
 281 }
 282 $config{USER} = $user[0];
 283 $config{UID}  = $user[2];
 284
 285 # Warn the user about clock drifting when running on OpenVZ.
 286 if (-e '/proc/user_beancounters' || -e '/proc/vz/vzaquota') {
 287         print_warning <<'EOW';
 288 You are building InspIRCd inside of an OpenVZ container. If you
 289 plan to use InspIRCd in this container then you should make sure that NTP is
 290 configured on the Hardware Node. Failure to do so may result in clock drifting!
 291 EOW
 292 }
 293
 294 # Warn the user about OpenBSD shipping incredibly broken compilers/linkers.
 295 if ($^O eq 'openbsd') {
 296         print_warning <<'EOW';
 297 You are building InspIRCd on OpenBSD. The C++ compilers and linkers
 298 that OpenBSD ship are incredibly broken. You may have strange linker errors
 299 and crashes. Please consider using a different OS like FreeBSD/NetBSD instead.
 300 EOW
 301 }
 302
 303 # Check that the user actually wants this version.
 304 if (defined $version{REAL_LABEL}) {
 305         print_warning <<'EOW';
 306 You are building a development version. This contains code which has
 307 not been tested as heavily and may contain various faults which could seriously
 308 affect the running of your server. It is recommended that you use a stable
 309 version instead.
 310
 311 You can obtain the latest stable version from https://www.inspircd.org or by
 312 running `<|GREEN git checkout $(git describe --abbrev=0 --tags insp3)|>` if you are
 313 installing from Git.
 314 EOW
 315         if (!prompt_bool $interactive, 'I understand this warning and want to continue anyway.', $opt_development // 0) {
 316                 say STDERR 'If you understand this warning and still want to continue pass the --development flag.' unless $interactive;
 317                 exit 1;
 318         }
 319 }
 320
 321 # Configure directory settings.
 322 my $question = <<"EOQ";
 323 Currently, InspIRCd is configured with the following paths:
 324
 325 <|BOLD Binary:|> $config{BINARY_DIR}
 326 <|BOLD Config:|> $config{CONFIG_DIR}
 327 <|BOLD Data:|>   $config{DATA_DIR}
 328 <|BOLD Log:|>    $config{LOG_DIR}
 329 <|BOLD Manual:|> $config{MANUAL_DIR}
 330 <|BOLD Module:|> $config{MODULE_DIR}
 331 <|BOLD Script:|> $config{SCRIPT_DIR}
 332
 333 Do you want to change these settings?
 334 EOQ
 335 if (prompt_bool $interactive, $question, 0) {
 336         my $original_base_dir = $config{BASE_DIR};
 337         $config{BASE_DIR} = prompt_dir $interactive, 'In what directory do you wish to install the InspIRCd base?', $config{BASE_DIR};
 338         for my $key (qw(BINARY_DIR CONFIG_DIR DATA_DIR LOG_DIR MANUAL_DIR MODULE_DIR SCRIPT_DIR)) {
 339                 $config{$key} =~ s/^\Q$original_base_dir\E/$config{BASE_DIR}/;
 340         }
 341         $config{BINARY_DIR} = prompt_dir $interactive, 'In what directory should the InspIRCd binary be placed?', $config{BINARY_DIR};
 342         $config{CONFIG_DIR} = prompt_dir $interactive, 'In what directory are configuration files to be stored?', $config{CONFIG_DIR};
 343         $config{DATA_DIR}   = prompt_dir $interactive, 'In what directory are variable data files to be stored?', $config{DATA_DIR};
 344         $config{LOG_DIR}    = prompt_dir $interactive, 'In what directory are log files to be stored?',           $config{LOG_DIR};
 345         $config{MANUAL_DIR} = prompt_dir $interactive, 'In what directory are manual pages to be placed?',        $config{MANUAL_DIR};
 346         $config{MODULE_DIR} = prompt_dir $interactive, 'In what directory are modules to be placed?',             $config{MODULE_DIR};
 347         $config{SCRIPT_DIR} = prompt_dir $interactive, 'In what directory are scripts to be placed?',             $config{SCRIPT_DIR};
 348         $config{EXAMPLE_DIR} = $config{CONFIG_DIR} . '/examples';
 349         $config{RUNTIME_DIR} = $config{DATA_DIR};
 350 }
 351
 352 # Configure module settings.
 353 $question = <<'EOQ';
 354 Currently, InspIRCd is configured to automatically enable all available extra modules.
 355
 356 Would you like to enable extra modules manually?
 357 EOQ
 358 if (prompt_bool $interactive, $question, 0) {
 359         for my $extra (<$RealDir/src/modules/extra/m_*.cpp>) {
 360                 my $module_name = module_shrink $extra;
 361                 if (prompt_bool $interactive, "Would you like to enable the <|BOLD $module_name|> module?", 0) {
 362                         enable_extras $module_name;
 363                 }
 364         }
 365 } elsif (!defined $opt_disable_auto_extras) {
 366         # TODO: finish modulemanager rewrite and replace this code with:
 367         # system './modulemanager', 'enable', '--auto';
 368         my %modules = (
 369                 # Missing: m_ldap, m_regex_stdlib, m_ssl_mbedtls
 370                 'm_argon2.cpp'          => 'pkg-config --exists libargon2',
 371                 'm_geo_maxmind.cpp'     => 'pkg-config --exists libmaxminddb',
 372                 'm_mysql.cpp'           => 'mysql_config --version',
 373                 'm_pgsql.cpp'           => 'pg_config --version',
 374                 'm_regex_pcre.cpp'      => 'pcre-config --version',
 375                 'm_regex_posix.cpp'     => undef,
 376                 'm_regex_re2.cpp'       => 'pkg-config --exists re2',
 377                 'm_regex_tre.cpp'       => 'pkg-config --exists tre',
 378                 'm_sqlite3.cpp'         => 'pkg-config --exists sqlite3',
 379                 'm_ssl_gnutls.cpp'      => 'pkg-config --exists gnutls',
 380                 'm_ssl_openssl.cpp'     => 'pkg-config --exists openssl',
 381                 'm_sslrehashsignal.cpp' => undef,
 382         );
 383         while (my ($module, $command) = each %modules) {
 384                 unless (defined $command && system "$command 1>/dev/null 2>/dev/null") {
 385                         enable_extras $module;
 386                 }
 387         }
 388 }
 389
 390 # Generate SSL certificates.
 391 $question = <<EOQ;
 392 Would you like to generate a self-signed SSL certificate now? This certificate
 393 can be used for testing but <|BOLD should not|> be used on a production network.
 394
 395 Note: you can get a <|BOLD free|> CA-signed certificate from Let's Encrypt. See
 396 https://letsencrypt.org/getting-started/ for more details.
 397 EOQ
 398
 399 if (<$RealDir/src/modules/m_ssl_*.cpp>) {
 400         if (prompt_bool $interactive, $question, $interactive) {
 401                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 402                 system './tools/genssl', 'auto', CONFIGURE_DIRECTORY;
 403         } else {
 404                 my @pems = <${\CONFIGURE_DIRECTORY}/{cert,csr,dhparams,key}.pem>;
 405                 $question = <<EOQ;
 406 The following self-signed files were previously generated and will be installed
 407 when you run Make. Do you want to delete them?
 408
 409   * ${\join "\n  * ", @pems}
 410 EOQ
 411                 if (@pems && prompt_bool $interactive, $question, 0) {
 412                         unlink @pems;
 413                 }
 414         }
 415 } elsif (!defined $opt_disable_auto_extras) {
 416         print_warning <<"EOM";
 417 You are building without enabling any SSL modules. This is not
 418 recommended as SSL greatly enhances the security and privacy of your IRC server
 419 and in a future version will be <|BOLD required|> for linking servers.
 420
 421 Please read the following documentation pages on how to enable SSL support:
 422
 423 GnuTLS (recommended): https://docs.inspircd.org/3/modules/ssl_gnutls
 424 mbedTLS:              https://docs.inspircd.org/3/modules/ssl_mbedtls
 425 OpenSSL:              https://docs.inspircd.org/3/modules/ssl_openssl
 426 EOM
 427 }
 428
 429 # Cache the distribution label so that its not lost when --update is run.
 430 $config{DISTRIBUTION} = $opt_distribution_label if $opt_distribution_label;
 431
 432 write_configure_cache %config;
 433 parse_templates \%config, \%compiler, \%version;
 434
 435 print console_format <<"EOM";
 436
 437 Configuration is complete! You have chosen to build with the following settings:
 438
 439 <|GREEN Compiler:|>
 440   <|GREEN Binary:|>  $config{CXX}
 441   <|GREEN Name:|>    $compiler{NAME}
 442   <|GREEN Version:|> $compiler{VERSION}
 443
 444 <|GREEN Extra Modules:|>
 445 EOM
 446
 447 for my $file (<$RealDir/src/modules/m_*>) {
 448         say "  * ${\module_shrink $file}" if -l $file;
 449 }
 450
 451 my @makeargs;
 452 push @makeargs, "-C${\abs2rel $RealDir}" unless getcwd eq $RealDir;
 453 push @makeargs, "-j${\(get_cpu_count() + 1)}";
 454
 455 print console_format <<"EOM";
 456
 457 <|GREEN Paths:|>
 458   <|GREEN Binary:|>  $config{BINARY_DIR}
 459   <|GREEN Config:|>  $config{CONFIG_DIR}
 460   <|GREEN Data:|>    $config{DATA_DIR}
 461   <|GREEN Example:|> $config{EXAMPLE_DIR}
 462   <|GREEN Log:|>     $config{LOG_DIR}
 463   <|GREEN Manual:|>  $config{MANUAL_DIR}
 464   <|GREEN Module:|>  $config{MODULE_DIR}
 465   <|GREEN Runtime:|> $config{RUNTIME_DIR}
 466   <|GREEN Script:|>  $config{SCRIPT_DIR}
 467
 468 <|GREEN Execution Group:|> $config{GROUP} ($config{GID})
 469 <|GREEN Execution User:|>  $config{USER} ($config{UID})
 470 <|GREEN Socket Engine:|>   $config{SOCKETENGINE}
 471
 472 To build with these settings run '<|GREEN make ${\join ' ', @makeargs} install|>' now.
 473
 474 EOM
 475
 476 # Routine to list out the extra/ modules that have been enabled.
 477 # Note: when getting any filenames out and comparing, it's important to lc it if the
 478 # file system is not case-sensitive (== Epoc, MacOS, OS/2 (incl DOS/DJGPP), VMS, Win32
 479 # (incl NetWare, Symbian)). Cygwin may or may not be case-sensitive, depending on
 480 # configuration, however, File::Spec does not currently tell us (it assumes Unix behavior).
 481 sub list_extras () {
 482         use File::Spec;
 483         # @_ not used
 484         my $srcdir = File::Spec->catdir("src", "modules");
 485         my $abs_srcdir = File::Spec->rel2abs($srcdir);
 486         local $_;
 487         my $dd;
 488         opendir $dd, File::Spec->catdir($abs_srcdir, "extra") or die (File::Spec->catdir($abs_srcdir, "extra") . ": $!\n");
 489         my @extras = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 490         closedir $dd;
 491         undef $dd;
 492         opendir $dd, $abs_srcdir or die "$abs_srcdir: $!\n";
 493         my @sources = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 494         closedir $dd;
 495         undef $dd;
 496         my $maxlen = (sort { $b <=> $a } (map { length module_shrink $_ } (@extras)))[0];
 497         my %extras = ();
 498 EXTRA:  for my $extra (@extras) {
 499                 next if (File::Spec->curdir() eq $extra || File::Spec->updir() eq $extra);
 500                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 501                 my $abs_source = File::Spec->catfile($abs_srcdir, $extra);
 502                 next unless ($extra =~ m/\.(cpp|h)$/ || (-d $abs_extra)); # C++ Source/Header, or directory
 503                 if (-l $abs_source) {
 504                         # Symlink, is it in the right place?
 505                         my $targ = readlink($abs_source);
 506                         my $abs_targ = File::Spec->rel2abs($targ, $abs_srcdir);
 507                         if ($abs_targ eq $abs_extra) {
 508                                 $extras{$extra} = "\e[32;1menabled\e[0m";
 509                         } else {
 510                                 $extras{$extra} = sprintf("\e[31;1mwrong symlink target (%s)\e[0m", $abs_targ);
 511                         }
 512                 } elsif (-e $abs_source) {
 513                         my ($devext, $inoext) = stat($abs_extra);
 514                         my ($devsrc, $inosrc, undef, $lnksrc) = stat($abs_source);
 515                         if ($lnksrc > 1) {
 516                                 if ($devsrc == $devext && $inosrc == $inoext) {
 517                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 518                                 } else {
 519                                         $extras{$extra} = sprintf("\e[31;1mwrong hardlink target (%d:%d)\e[0m", $devsrc, $inosrc);
 520                                 }
 521                         } else {
 522                                 open my $extfd, "<", $abs_extra;
 523                                 open my $srcfd, "<", $abs_source;
 524                                 local $/ = undef;
 525                                 if (scalar(<$extfd>) eq scalar(<$srcfd>)) {
 526                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 527                                 } else {
 528                                         $extras{$extra} = sprintf("\e[31;1mout of synch (re-copy)\e[0m");
 529                                 }
 530                         }
 531                 } else {
 532                         $extras{$extra} = "\e[33;1mdisabled\e[0m";
 533                 }
 534         }
 535         # Now let's add dependency info
 536         for my $extra (keys(%extras)) {
 537                 next unless $extras{$extra} =~ m/enabled/; # only process enabled extras.
 538                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 539                 my @deps = split /\s+/, get_directive($abs_extra, 'ModDep', '');
 540                 for my $dep (@deps) {
 541                         if (exists($extras{$dep})) {
 542                                 my $ref = \$extras{$dep}; # Take reference.
 543                                 if ($$ref !~ m/needed by/) {
 544                                         # First dependency found.
 545                                         if ($$ref =~ m/enabled/) {
 546                                                 $$ref .= " (needed by \e[32;1m$extra\e[0m";
 547                                         } else {
 548                                                 $$ref =~ s/\e\[.*?m//g; # Strip out previous coloring. Will be set in bold+red+blink later.
 549                                                 $$ref .= " (needed by \e[0;32;1;5m$extra\e[0;31;1;5m";
 550                                         }
 551                                 } else {
 552                                         if ($$ref =~ m/enabled/) {
 553                                                 $$ref .= ", \e[32;1m$extra\e[0m";
 554                                         } else {
 555                                                 $$ref .= ", \e[0;32;1;5m$extra\e[0;31;1;5m";
 556                                         }
 557                                 }
 558                         }
 559                 }
 560         }
 561         for my $extra (sort {$a cmp $b} keys(%extras)) {
 562                 my $text = $extras{$extra};
 563                 if ($text =~ m/needed by/ && $text !~ m/enabled/) {
 564                         printf "\e[31;1;5m%-*s = %s%s\e[0m\n", $maxlen, module_shrink($extra), $text, ($text =~ m/needed by/ ? ")" : "");
 565                 } else {
 566                         printf "%-*s = %s%s\n", $maxlen, module_shrink($extra), $text, ($text =~ m/needed by/ ? "\e[0m)" : "");
 567                 }
 568         }
 569         return keys(%extras) if wantarray; # Can be used by manage_extras.
 570 }
 571
 572 sub enable_extras(@) {
 573         my $moduledir = catdir $RealDir, 'src', 'modules';
 574         my $extradir = catdir $moduledir, 'extra';
 575
 576         for my $extra (@_) {
 577                 my $shortname = module_shrink $extra;
 578                 my $extrafile = module_expand $extra;
 579
 580                 my $extrapath = catfile $extradir, $extrafile;
 581                 if (!-f $extrapath) {
 582                         print_error "<|GREEN $extra|> is not an extra module!";
 583                 }
 584
 585                 my $modulepath = catfile $moduledir, $extrafile;
 586                 if (-l $modulepath) {
 587                         if (readlink($modulepath) ne $extrapath) {
 588                                 unlink $modulepath; # Remove the dead symlink.
 589                         } else {
 590                                 next; # Module is already enabled.
 591                         }
 592                 }
 593
 594                 if (-e $modulepath) {
 595                         print_error "unable to symlink <|GREEN ${\abs2rel $modulepath}|> to <|GREEN ${\abs2rel $extrapath}|>: the target exists and is not a symlink.";
 596                 } else {
 597                         say console_format "Enabling the <|GREEN $shortname|> module ...";
 598                         symlink $extrapath, $modulepath or print_error "unable to symlink <|GREEN ${\abs2rel $modulepath}|> to <|GREEN ${\abs2rel $extrapath}|>: $!";
 599                 }
 600         }
 601 }
 602
 603 sub disable_extras(@) {
 604         my $moduledir = catdir $RealDir, 'src', 'modules';
 605         my $extradir = catdir $moduledir, 'extra';
 606
 607         for my $extra (@_) {
 608                 my $shortname = module_shrink $extra;
 609                 my $extrafile = module_expand $extra;
 610
 611                 my $modulepath = catfile $moduledir, $extrafile;
 612                 my $extrapath = catfile $extradir, $extrafile;
 613                 if (!-e $modulepath && !-e $extrapath) {
 614                         print_error "the <|GREEN $shortname|> module does not exist!";
 615                 } elsif (!-e $modulepath && -e $extrapath) {
 616                         print_error "the <|GREEN $shortname|> module is not currently enabled!";
 617                 } elsif ((-e $modulepath && !-e $extrapath) || !-l $modulepath) {
 618                         print_error "the <|GREEN $shortname|> module is not an extra module!";
 619                 } else {
 620                         say console_format "Disabling the <|GREEN $shortname|> module ...";
 621                         unlink $modulepath or print_error "unable to unlink <|GREEN $extrapath|>: $!";
 622                 }
 623         }
 624 }