configure

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   7 #   Copyright (C) 2009-2010 Daniel De Graaf <danieldg@inspircd.org>
   8 #   Copyright (C) 2007, 2009 Dennis Friis <peavey@inspircd.org>
   9 #   Copyright (C) 2003, 2006-2008 Craig Edwards <craigedwards@brainbox.cc>
  10 #   Copyright (C) 2006-2008 Robin Burchell <robin+git@viroteck.net>
  11 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
  12 #   Copyright (C) 2007 John Brooks <john.brooks@dereferenced.net>
  13 #   Copyright (C) 2006 Oliver Lupton <oliverlupton@gmail.com>
  14 #   Copyright (C) 2003-2006 Craig McLure <craig@chatspike.net>
  15 #
  16 # This file is part of InspIRCd.  InspIRCd is free software: you can
  17 # redistribute it and/or modify it under the terms of the GNU General Public
  18 # License as published by the Free Software Foundation, version 2.
  19 #
  20 # This program is distributed in the hope that it will be useful, but WITHOUT
  21 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  22 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  23 # details.
  24 #
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  27 #
  28
  29
  30 BEGIN {
  31         require 5.10.0;
  32 }
  33
  34 use feature ':5.10';
  35 use strict;
  36 use warnings FATAL => qw(all);
  37
  38 use File::Basename        qw(basename);
  39 use File::Copy            ();
  40 use File::Spec::Functions qw(rel2abs);
  41 use FindBin               qw($RealDir);
  42 use Getopt::Long          qw(GetOptions);
  43 use POSIX                 qw(getgid getuid);
  44
  45 use lib $RealDir;
  46 use make::common;
  47 use make::configure;
  48 use make::console;
  49 use make::directive;
  50
  51 my ($opt_binary_dir,
  52     $opt_config_dir,
  53     $opt_data_dir,
  54     $opt_development,
  55     $opt_disable_interactive,
  56     $opt_distribution_label,
  57     $opt_gid,
  58     $opt_log_dir,
  59     $opt_manual_dir,
  60     $opt_module_dir,
  61     $opt_prefix,
  62     $opt_script_dir,
  63     $opt_socketengine,
  64     $opt_system,
  65     $opt_uid);
  66
  67 sub list_extras ();
  68
  69 sub enable_extras (@);
  70
  71 sub disable_extras (@);
  72
  73 my @opt_enableextras;
  74 my @opt_disableextras;
  75
  76 GetOptions(
  77         'clean'  => \&cmd_clean,
  78         'help'   => \&cmd_help,
  79         'update' => \&cmd_update,
  80
  81         'development'          => \$opt_development,
  82         'disable-interactive'  => \$opt_disable_interactive,
  83         'distribution-label=s' => \$opt_distribution_label,
  84         'binary-dir=s'         => \$opt_binary_dir,
  85         'config-dir=s'         => \$opt_config_dir,
  86         'data-dir=s'           => \$opt_data_dir,
  87         'gid=s'                => \$opt_gid,
  88         'log-dir=s'            => \$opt_log_dir,
  89         'manual-dir=s'         => \$opt_manual_dir,
  90         'module-dir=s'         => \$opt_module_dir,
  91         'prefix=s'             => \$opt_prefix,
  92         'script-dir=s'         => \$opt_script_dir,
  93         'socketengine=s'       => \$opt_socketengine,
  94         'system'               => \$opt_system,
  95         'uid=s'                => \$opt_uid,
  96
  97         # TODO: when the modulemanager rewrite is done these should be removed.
  98         'disable-extras=s@' => \@opt_disableextras,
  99         'enable-extras=s@'  => \@opt_enableextras,
 100         'list-extras'       => sub { list_extras; exit 0; },
 101 );
 102
 103 if (scalar(@opt_enableextras) + scalar(@opt_disableextras) > 0) {
 104         @opt_enableextras = split /,/, join(',', @opt_enableextras);
 105         @opt_disableextras = split /,/, join(',', @opt_disableextras);
 106         enable_extras(@opt_enableextras);
 107         disable_extras(@opt_disableextras);
 108         list_extras;
 109         print "Remember: YOU are responsible for making sure any libraries needed have been installed!\n";
 110         exit 0;
 111 }
 112
 113 our $interactive = !(
 114         !-t STDIN ||
 115         !-t STDOUT ||
 116         defined $opt_binary_dir ||
 117         defined $opt_config_dir ||
 118         defined $opt_data_dir ||
 119         defined $opt_development ||
 120         defined $opt_disable_interactive ||
 121         defined $opt_distribution_label ||
 122         defined $opt_gid ||
 123         defined $opt_log_dir ||
 124         defined $opt_manual_dir ||
 125         defined $opt_module_dir ||
 126         defined $opt_prefix ||
 127         defined $opt_script_dir ||
 128         defined $opt_socketengine ||
 129         defined $opt_system ||
 130         defined $opt_uid
 131 );
 132
 133 my %version = get_version $opt_distribution_label;
 134 print_format "<|BOLD Configuring InspIRCd $version{FULL} on $^O.|>\n";
 135
 136 my %config;
 137 if ($interactive) {
 138         %config = read_config_file(CONFIGURE_CACHE_FILE);
 139         run_test CONFIGURE_CACHE_FILE, %config;
 140         if (!defined $config{VERSION}) {
 141                 $config{VERSION} = CONFIGURE_CACHE_VERSION;
 142         } elsif ($config{VERSION} != CONFIGURE_CACHE_VERSION) {
 143                 print_warning "ignoring contents of ${\CONFIGURE_CACHE_FILE} as it was generated by an incompatible version of $0!";
 144                 %config = ('VERSION', CONFIGURE_CACHE_VERSION);
 145         }
 146 }
 147
 148 $config{CXX} = find_compiler($config{CXX} // $ENV{CXX});
 149 unless ($config{CXX}) {
 150         say 'A suitable C++ compiler could not be detected on your system!';
 151         unless ($interactive) {
 152                 say 'Set the CXX environment variable to the path to a C++ compiler binary if this is incorrect.';
 153                 exit 1;
 154         }
 155         until ($config{CXX}) {
 156                 my $compiler_path = prompt_string 1, 'Please enter the path to a C++ compiler binary:', 'c++';
 157                 $config{CXX} = find_compiler $compiler_path;
 158         }
 159 }
 160 my %compiler = get_compiler_info($config{CXX});
 161
 162 $config{HAS_CLOCK_GETTIME} = run_test 'clock_gettime()', test_file($config{CXX}, 'clock_gettime.cpp', $^O eq 'darwin' ? undef : '-lrt');
 163 $config{HAS_EVENTFD} = run_test 'eventfd()', test_file($config{CXX}, 'eventfd.cpp');
 164
 165 my @socketengines;
 166 push @socketengines, 'epoll'  if run_test 'epoll', test_header $config{CXX}, 'sys/epoll.h';
 167 push @socketengines, 'kqueue' if run_test 'kqueue', test_file $config{CXX}, 'kqueue.cpp';
 168 push @socketengines, 'ports'  if run_test 'Solaris IOCP', test_header $config{CXX}, 'port.h';
 169 push @socketengines, 'poll'   if run_test 'poll', test_header $config{CXX}, 'poll.h';
 170 push @socketengines, 'select';
 171
 172 if (defined $opt_socketengine) {
 173         unless (grep { $_ eq $opt_socketengine } @socketengines) {
 174                 my $reason = -f "src/socketengines/socketengine_$opt_socketengine.cpp" ? 'is not available on this platform' : 'does not exist';
 175                 print_error "The socket engine you requested ($opt_socketengine) $reason!",
 176                         'Available socket engines are:',
 177                         map { "  * $_" } @socketengines;
 178         }
 179 }
 180 $config{SOCKETENGINE} = $opt_socketengine // $socketengines[0];
 181
 182 if (defined $opt_system) {
 183         $config{BASE_DIR}   = $opt_prefix     // '/var/lib/inspircd';
 184         $config{BINARY_DIR} = $opt_binary_dir // '/usr/sbin';
 185         $config{CONFIG_DIR} = $opt_config_dir // '/etc/inspircd';
 186         $config{DATA_DIR}   = $opt_data_dir   // '/var/inspircd';
 187         $config{LOG_DIR}    = $opt_module_dir // '/var/log/inspircd';
 188         $config{MANUAL_DIR} = $opt_manual_dir // '/usr/share/man/man1';
 189         $config{MODULE_DIR} = $opt_module_dir // '/usr/lib/inspircd';
 190         $config{SCRIPT_DIR} = $opt_script_dir // '/usr/share/inspircd'
 191 } else {
 192         $config{BASE_DIR}   = $opt_prefix     // $config{BASE_DIR}   // rel2abs 'run';
 193         $config{BINARY_DIR} = $opt_binary_dir // $config{BINARY_DIR} // rel2abs $config{BASE_DIR} . '/bin';
 194         $config{CONFIG_DIR} = $opt_config_dir // $config{CONFIG_DIR} // rel2abs $config{BASE_DIR} . '/conf';
 195         $config{DATA_DIR}   = $opt_data_dir   // $config{DATA_DIR}   // rel2abs $config{BASE_DIR} . '/data';
 196         $config{LOG_DIR}    = $opt_log_dir    // $config{LOG_DIR}    // rel2abs $config{BASE_DIR} . '/logs';
 197         $config{MANUAL_DIR} = $opt_manual_dir // $config{MANUAL_DIR} // rel2abs $config{BASE_DIR} . '/manuals';
 198         $config{MODULE_DIR} = $opt_module_dir // $config{MODULE_DIR} // rel2abs $config{BASE_DIR} . '/modules';
 199         $config{SCRIPT_DIR} = $opt_script_dir // $config{SCRIPT_DIR} // $config{BASE_DIR};
 200 }
 201
 202 # Parse --gid=123 or --gid=foo and extract the group id.
 203 my @group;
 204 if (defined $opt_gid) {
 205         @group = $opt_gid =~ /^\d+$/ ? getgrgid($opt_gid) : getgrnam($opt_gid);
 206         print_error "there is no '$opt_gid' group on this system!" unless @group;
 207 } else {
 208         @group = $opt_system ? getgrnam('irc') : getgrgid($config{GID} // getgid());
 209         print_error "you need to specify a group to run as using '--gid [id|name]'!" unless @group;
 210 }
 211 $config{GROUP} = $group[0];
 212 $config{GID}   = $group[2];
 213
 214 # Parse --uid=123 or --uid=foo and extract the user id.
 215 my @user;
 216 if (defined $opt_uid) {
 217         @user = $opt_uid =~ /^\d+$/ ? getpwuid($opt_uid) : getpwnam($opt_uid);
 218         print_error "there is no '$opt_uid' user on this system!" unless @user;
 219 } else {
 220         @user = $opt_system ? getpwnam('irc') : getpwuid($config{UID} // getuid());
 221         print_error "you need to specify a user to run as using '--uid [id|name]'!" unless @user;
 222 }
 223 $config{USER} = $user[0];
 224 $config{UID}  = $user[2];
 225
 226 # Clear the screen.
 227 system 'tput', 'clear' if $interactive;
 228
 229 # Warn the user about clock drifting when running on OpenVZ.
 230 if (-e '/proc/user_beancounters' || -e '/proc/vz/vzaquota') {
 231         print_warning <<'EOW';
 232 You are building InspIRCd inside of an an OpenVZ container. If you
 233 plan to use InspIRCd in this container then you should make sure that NTP is
 234 configured on the Hardware Node. Failure to do so may result in clock drifting!
 235 EOW
 236 }
 237
 238 # Check that the user actually wants this version.
 239 if ($version{LABEL} ne 'release') {
 240         print_warning <<'EOW';
 241 You are building a development version. This contains code which has
 242 not been tested as heavily and may contain various faults which could seriously
 243 affect the running of your server. It is recommended that you use a stable
 244 version instead.
 245
 246 You can obtain the latest stable version from http://www.inspircd.org/ or by
 247 running `git checkout insp20` if you are installing from Git.
 248 EOW
 249         if (!prompt_bool $interactive, 'I understand this warning and want to continue anyway.', $opt_development // 0) {
 250                 say STDERR 'If you understand this warning and still want to continue pass the --development flag.' unless $interactive;
 251                 exit 1;
 252         }
 253 }
 254
 255 # Configure directory settings.
 256 my $question = <<"EOQ";
 257 Currently, InspIRCd is configured with the following paths:
 258
 259 <|BOLD Base:|>   $config{BASE_DIR}
 260 <|BOLD Binary:|> $config{BINARY_DIR}
 261 <|BOLD Config:|> $config{CONFIG_DIR}
 262 <|BOLD Data:|>   $config{DATA_DIR}
 263 <|BOLD Log:|>    $config{LOG_DIR}
 264 <|BOLD Manual:|> $config{MANUAL_DIR}
 265 <|BOLD Module:|> $config{MODULE_DIR}
 266 <|BOLD Script:|> $config{SCRIPT_DIR}
 267
 268 Do you want to change these settings?
 269 EOQ
 270 if (prompt_bool $interactive, $question, 0) {
 271         my $original_base_dir = $config{BASE_DIR};
 272         $config{BASE_DIR} = prompt_dir $interactive, 'In what directory do you wish to install the InspIRCd base?', $config{BASE_DIR};
 273         foreach my $key (qw(BINARY_DIR CONFIG_DIR DATA_DIR LOG_DIR MANUAL_DIR MODULE_DIR SCRIPT_DIR)) {
 274                 $config{$key} =~ s/^\Q$original_base_dir\E/$config{BASE_DIR}/;
 275         }
 276         $config{BINARY_DIR} = prompt_dir $interactive, 'In what directory should the InspIRCd binary be placed?', $config{BINARY_DIR};
 277         $config{CONFIG_DIR} = prompt_dir $interactive, 'In what directory are configuration files to be stored?', $config{CONFIG_DIR};
 278         $config{DATA_DIR}   = prompt_dir $interactive, 'In what directory are variable data files to be stored?', $config{DATA_DIR};
 279         $config{LOG_DIR}    = prompt_dir $interactive, 'In what directory are log files to be stored?',           $config{LOG_DIR};
 280         $config{MANUAL_DIR} = prompt_dir $interactive, 'In what directory are manual pages to be placed?',        $config{MANUAL_DIR};
 281         $config{MODULE_DIR} = prompt_dir $interactive, 'In what directory are modules to be placed?',             $config{MODULE_DIR};
 282         $config{SCRIPT_DIR} = prompt_dir $interactive, 'In what directory are scripts to be placed?',             $config{SCRIPT_DIR};
 283 }
 284
 285 # Configure module settings.
 286 $question = <<'EOQ';
 287 Currently, InspIRCd is configured to automatically enable all available extra modules.
 288
 289 Would you like to enable extra modules manually?
 290 EOQ
 291 if (prompt_bool $interactive, $question, 0) {
 292         foreach my $extra (<src/modules/extra/m_*.cpp>) {
 293                 my $module_name = basename $extra, '.cpp';
 294                 if (prompt_bool $interactive, "Would you like to enable $module_name?", 0) {
 295                         enable_extras "$module_name.cpp";
 296                 }
 297         }
 298 } else {
 299         # TODO: finish modulemanager rewrite and replace this code with:
 300         # system './modulemanager', 'enable', '--auto';
 301         enable_extras 'm_ssl_gnutls.cpp' unless system 'pkg-config --exists gnutls >/dev/null 2>&1';
 302         enable_extras 'm_ssl_mbedtls.cpp' if -e '/usr/include/mbedtls/ssl.h';
 303         enable_extras 'm_ssl_openssl.cpp' unless system 'pkg-config --exists openssl >/dev/null 2>&1';
 304 }
 305
 306 # Generate SSL certificates.
 307 if (<src/modules/m_ssl_*.cpp> && prompt_bool $interactive, 'Would you like to generate SSL certificates now?', $interactive) {
 308         system './tools/genssl', 'auto';
 309 }
 310
 311 # Cache the distribution label so that its not lost when --update is run.
 312 $config{DISTRIBUTION} = $opt_distribution_label if $opt_distribution_label;
 313
 314 write_configure_cache %config;
 315 parse_templates \%config, \%compiler, \%version;
 316
 317 print_format <<"EOM";
 318
 319 Configuration is complete! You have chosen to build with the following settings:
 320
 321 <|GREEN Compiler:|>
 322   <|GREEN Binary:|>  $config{CXX}
 323   <|GREEN Name:|>    $compiler{NAME}
 324   <|GREEN Version:|> $compiler{VERSION}
 325
 326 <|GREEN Extra Modules:|>
 327 EOM
 328
 329 for my $file (<src/modules/m_*>) {
 330         my $module = basename $file, '.cpp';
 331         say "  * $module" if -l $file;
 332 }
 333
 334 print_format <<"EOM";
 335
 336 <|GREEN Paths:|>
 337   <|GREEN Base:|>   $config{BASE_DIR}
 338   <|GREEN Binary:|> $config{BINARY_DIR}
 339   <|GREEN Config:|> $config{CONFIG_DIR}
 340   <|GREEN Data:|>   $config{DATA_DIR}
 341   <|GREEN Log:|>    $config{LOG_DIR}
 342   <|GREEN Manual:|> $config{MANUAL_DIR}
 343   <|GREEN Module:|> $config{MODULE_DIR}
 344   <|GREEN Script:|> $config{SCRIPT_DIR}
 345
 346 <|GREEN Execution Group:|> $config{GROUP} ($config{GID})
 347 <|GREEN Execution User:|>  $config{USER} ($config{UID})
 348 <|GREEN Socket Engine:|>   $config{SOCKETENGINE}
 349
 350 To build with these settings run '<|GREEN make -j${\get_cpu_count}|>' now.
 351
 352 EOM
 353
 354 # Routine to list out the extra/ modules that have been enabled.
 355 # Note: when getting any filenames out and comparing, it's important to lc it if the
 356 # file system is not case-sensitive (== Epoc, MacOS, OS/2 (incl DOS/DJGPP), VMS, Win32
 357 # (incl NetWare, Symbian)). Cygwin may or may not be case-sensitive, depending on
 358 # configuration, however, File::Spec does not currently tell us (it assumes Unix behavior).
 359 sub list_extras () {
 360         use File::Spec;
 361         # @_ not used
 362         my $srcdir = File::Spec->catdir("src", "modules");
 363         my $abs_srcdir = File::Spec->rel2abs($srcdir);
 364         local $_;
 365         my $dd;
 366         opendir $dd, File::Spec->catdir($abs_srcdir, "extra") or die (File::Spec->catdir($abs_srcdir, "extra") . ": $!\n");
 367         my @extras = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 368         closedir $dd;
 369         undef $dd;
 370         opendir $dd, $abs_srcdir or die "$abs_srcdir: $!\n";
 371         my @sources = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 372         closedir $dd;
 373         undef $dd;
 374         my $maxlen = (sort { $b <=> $a } (map {length($_)} (@extras)))[0];
 375         my %extras = ();
 376 EXTRA:  for my $extra (@extras) {
 377                 next if (File::Spec->curdir() eq $extra || File::Spec->updir() eq $extra);
 378                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 379                 my $abs_source = File::Spec->catfile($abs_srcdir, $extra);
 380                 next unless ($extra =~ m/\.(cpp|h)$/ || (-d $abs_extra)); # C++ Source/Header, or directory
 381                 if (-l $abs_source) {
 382                         # Symlink, is it in the right place?
 383                         my $targ = readlink($abs_source);
 384                         my $abs_targ = File::Spec->rel2abs($targ, $abs_srcdir);
 385                         if ($abs_targ eq $abs_extra) {
 386                                 $extras{$extra} = "\e[32;1menabled\e[0m";
 387                         } else {
 388                                 $extras{$extra} = sprintf("\e[31;1mwrong symlink target (%s)\e[0m", $abs_targ);
 389                         }
 390                 } elsif (-e $abs_source) {
 391                         my ($devext, $inoext) = stat($abs_extra);
 392                         my ($devsrc, $inosrc, undef, $lnksrc) = stat($abs_source);
 393                         if ($lnksrc > 1) {
 394                                 if ($devsrc == $devext && $inosrc == $inoext) {
 395                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 396                                 } else {
 397                                         $extras{$extra} = sprintf("\e[31;1mwrong hardlink target (%d:%d)\e[0m", $devsrc, $inosrc);
 398                                 }
 399                         } else {
 400                                 open my $extfd, "<", $abs_extra;
 401                                 open my $srcfd, "<", $abs_source;
 402                                 local $/ = undef;
 403                                 if (scalar(<$extfd>) eq scalar(<$srcfd>)) {
 404                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 405                                 } else {
 406                                         $extras{$extra} = sprintf("\e[31;1mout of synch (re-copy)\e[0m");
 407                                 }
 408                         }
 409                 } else {
 410                         $extras{$extra} = "\e[33;1mdisabled\e[0m";
 411                 }
 412         }
 413         # Now let's add dependency info
 414         for my $extra (keys(%extras)) {
 415                 next unless $extras{$extra} =~ m/enabled/; # only process enabled extras.
 416                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 417                 my @deps = split /\s+/, get_directive($abs_extra, 'ModDep', '');
 418                 for my $dep (@deps) {
 419                         if (exists($extras{$dep})) {
 420                                 my $ref = \$extras{$dep}; # Take reference.
 421                                 if ($$ref !~ m/needed by/) {
 422                                         # First dependency found.
 423                                         if ($$ref =~ m/enabled/) {
 424                                                 $$ref .= " (needed by \e[32;1m$extra\e[0m";
 425                                         } else {
 426                                                 $$ref =~ s/\e\[.*?m//g; # Strip out previous coloring. Will be set in bold+red+blink later.
 427                                                 $$ref .= " (needed by \e[0;32;1;5m$extra\e[0;31;1;5m";
 428                                         }
 429                                 } else {
 430                                         if ($$ref =~ m/enabled/) {
 431                                                 $$ref .= ", \e[32;1m$extra\e[0m";
 432                                         } else {
 433                                                 $$ref .= ", \e[0;32;1;5m$extra\e[0;31;1;5m";
 434                                         }
 435                                 }
 436                         }
 437                 }
 438         }
 439         for my $extra (sort {$a cmp $b} keys(%extras)) {
 440                 my $text = $extras{$extra};
 441                 if ($text =~ m/needed by/ && $text !~ m/enabled/) {
 442                         printf "\e[31;1;5m%-*s = %s%s\e[0m\n", $maxlen, $extra, $text, ($text =~ m/needed by/ ? ")" : "");
 443                 } else {
 444                         printf "%-*s = %s%s\n", $maxlen, $extra, $text, ($text =~ m/needed by/ ? "\e[0m)" : "");
 445                 }
 446         }
 447         return keys(%extras) if wantarray; # Can be used by manage_extras.
 448 }
 449
 450 sub enable_extras (@) {
 451         my (@extras) = @_;
 452         for my $extra (@extras) {
 453                 my $extrapath = "src/modules/extra/$extra";
 454                 if (!-e $extrapath) {
 455                         print STDERR "Cannot enable \e[32;1m$extra\e[0m : No such file or directory in src/modules/extra\n";
 456                         next;
 457                 }
 458                 my $source = "src/modules/$extra";
 459                 if (-e $source) {
 460                         print STDERR "Cannot enable \e[32;1m$extra\e[0m : destination in src/modules exists (might already be enabled?)\n";
 461                         next;
 462                 }
 463                 # Get dependencies, and add them to be processed.
 464                 my @deps = split /\s+/, get_directive($extrapath, 'ModDep', '');
 465                 for my $dep (@deps) {
 466                         next if scalar(grep { $_ eq $dep } (@extras)) > 0; # Skip if we're going to be enabling it anyway.
 467                         if (!-e "src/modules/$dep" && !-e "include/$dep") {
 468                                 if (-e "src/modules/extra/$dep") {
 469                                         print STDERR "Will also enable extra \e[32;1m$dep\e[0m (needed by \e[32;1m$extra\e[0m)\n";
 470                                         push @extras, $dep;
 471                                 } else {
 472                                         print STDERR "\e[33;1mWARNING:\e[0m module \e[32;1m$extra\e[0m might be missing dependency \e[32;1m$dep\e[0m - YOU are responsible for satisfying it!\n";
 473                                 }
 474                         }
 475                 }
 476                 print "Enabling $extra ... \n";
 477                 symlink "extra/$extra", $source or print STDERR "$source: Cannot link to 'extra/$extra': $!\n";
 478         }
 479 }
 480
 481 sub disable_extras (@)
 482 {
 483         opendir my $dd, "src/modules/extra/";
 484         my @files = readdir($dd);
 485         closedir $dd;
 486         my (@extras) = @_;
 487 EXTRA:  for my $extra (@extras) {
 488                 my $extrapath = "src/modules/extra/$extra";
 489                 my $source = "src/modules/$extra";
 490                 if (!-e $extrapath) {
 491                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : Is not an extra\n";
 492                         next;
 493                 }
 494                 if ((! -l $source) || readlink($source) ne "extra/$extra") {
 495                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : Source is not a link or doesn't refer to the right file. Remove manually if this is in error.\n";
 496                         next;
 497                 }
 498                 # Check if anything needs this.
 499                 for my $file (@files) {
 500                         my @deps = split /\s+/, get_directive("src/modules/extra/$file", 'ModDep', '');
 501                         # File depends on this extra...
 502                         if (scalar(grep { $_ eq $extra } @deps) > 0) {
 503                                 # And is both enabled and not about to be disabled.
 504                                 if (-e "src/modules/$file" && scalar(grep { $_ eq $file } @extras) < 1) {
 505                                         print STDERR "Cannot disable \e[32;1m$extra\e[0m : is needed by \e[32;1m$file\e[0m\n";
 506                                         next EXTRA;
 507                                 }
 508                         }
 509                 }
 510                 # Now remove.
 511                 print "Disabling $extra ... \n";
 512                 unlink "src/modules/$extra" or print STDERR "Cannot disable \e[32;1m$extra\e[0m : $!\n";
 513         }
 514 }