make/common.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2013-2017 Peter Powell <petpow@saberuk.com>
   5 #
   6 # This file is part of InspIRCd.  InspIRCd is free software: you can
   7 # redistribute it and/or modify it under the terms of the GNU General Public
   8 # License as published by the Free Software Foundation, version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but WITHOUT
  11 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  12 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  13 # details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17 #
  18
  19
  20 BEGIN {
  21         require 5.10.0;
  22 }
  23
  24 package make::common;
  25
  26 use feature ':5.10';
  27 use strict;
  28 use warnings FATAL => qw(all);
  29
  30 use Exporter              qw(import);
  31 use File::Path            qw(mkpath);
  32 use File::Spec::Functions qw(rel2abs);
  33
  34 use make::console;
  35
  36 our @EXPORT = qw(create_directory
  37                  get_cpu_count
  38                  get_version
  39                  read_config_file
  40                  write_config_file);
  41
  42 sub create_directory($$) {
  43         my ($location, $permissions) = @_;
  44         return eval {
  45                 mkpath($location, 0, $permissions);
  46                 return 1;
  47         } // 0;
  48 }
  49
  50 sub get_version {
  51         state %version;
  52         return %version if %version;
  53
  54         # Attempt to retrieve version information from src/version.sh
  55         chomp(my $vf = `sh src/version.sh 2>/dev/null`);
  56         if ($vf =~ /^InspIRCd-([0-9]+)\.([0-9]+)\.([0-9]+)(?:-(\w+))?$/) {
  57                 %version = ( MAJOR => $1, MINOR => $2, PATCH => $3, LABEL => $4 );
  58         }
  59
  60         # Attempt to retrieve missing version information from Git
  61         chomp(my $gr = `git describe --tags 2>/dev/null`);
  62         if ($gr =~ /^v([0-9]+)\.([0-9]+)\.([0-9]+)(?:[a-z]+\d+)?(?:-\d+-g(\w+))?$/) {
  63                 $version{MAJOR} //= $1;
  64                 $version{MINOR} //= $2;
  65                 $version{PATCH} //= $3;
  66                 $version{LABEL} = $4 if defined $4;
  67         }
  68
  69         # If the user has specified a distribution label then we use it in
  70         # place of the label from src/version.sh or Git.
  71         $version{LABEL} = shift // $version{LABEL};
  72
  73         # If any of these fields are missing then the user has deleted the
  74         # version file and is not running from Git. Fill in the fields with
  75         # dummy data so we don't get into trouble with undef values later.
  76         $version{MAJOR} //= '0';
  77         $version{MINOR} //= '0';
  78         $version{PATCH} //= '0';
  79
  80         # If there is no label then the user is using a stable release which
  81         # does not have a label attached.
  82         if (defined $version{LABEL}) {
  83                 $version{FULL} = "$version{MAJOR}.$version{MINOR}.$version{PATCH}-$version{LABEL}"
  84         } else {
  85                 $version{LABEL} = 'release';
  86                 $version{FULL} = "$version{MAJOR}.$version{MINOR}.$version{PATCH}"
  87         }
  88
  89         return %version;
  90 }
  91
  92 sub get_cpu_count {
  93         my $count = 1;
  94         if ($^O =~ /bsd/) {
  95                 $count = `sysctl -n hw.ncpu 2>/dev/null` || 1;
  96         } elsif ($^O eq 'darwin') {
  97                 $count = `sysctl -n hw.activecpu 2>/dev/null` || 1;
  98         } elsif ($^O eq 'linux') {
  99                 $count = `getconf _NPROCESSORS_ONLN 2>/dev/null` || 1;
 100         } elsif ($^O eq 'solaris') {
 101                 $count = `psrinfo -p 2>/dev/null` || 1;
 102         }
 103         chomp($count);
 104         return $count;
 105 }
 106
 107 sub read_config_file($) {
 108         my $path = shift;
 109         my %config;
 110         open(my $fh, $path) or return %config;
 111         while (my $line = <$fh>) {
 112                 next if $line =~ /^\s*($|\#)/;
 113                 my ($key, $value) = ($line =~ /^(\S+)(?:\s(.*))?$/);
 114                 $config{$key} = $value;
 115         }
 116         close $fh;
 117         return %config;
 118 }
 119
 120 sub write_config_file($%) {
 121         my $path = shift;
 122         my %config = @_;
 123         open(my $fh, '>', $path) or print_error "unable to write to $path: $!";
 124         while (my ($key, $value) = each %config) {
 125                 $value //= '';
 126                 say $fh "$key $value";
 127         }
 128         close $fh;
 129 }
 130
 131 1;