make/common.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2013-2014 Peter Powell <petpow@saberuk.com>
   5 #
   6 # This file is part of InspIRCd.  InspIRCd is free software: you can
   7 # redistribute it and/or modify it under the terms of the GNU General Public
   8 # License as published by the Free Software Foundation, version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but WITHOUT
  11 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  12 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  13 # details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17 #
  18
  19
  20 BEGIN {
  21         require 5.10.0;
  22 }
  23
  24 package make::common;
  25
  26 use feature ':5.10';
  27 use strict;
  28 use warnings FATAL => qw(all);
  29
  30 use Exporter              qw(import);
  31 use File::Path            qw(mkpath);
  32 use File::Spec::Functions qw(rel2abs);
  33
  34 our @EXPORT = qw(create_directory
  35                  get_cpu_count
  36                  get_version
  37                  module_installed);
  38
  39 sub create_directory($$) {
  40         my ($location, $permissions) = @_;
  41         return eval {
  42                 mkpath($location, 0, $permissions);
  43                 return 1;
  44         } // 0;
  45 }
  46
  47 sub get_version {
  48         state %version;
  49         return %version if %version;
  50
  51         # Attempt to retrieve version information from src/version.sh
  52         chomp(my $vf = `sh src/version.sh 2>/dev/null`);
  53         if ($vf =~ /^InspIRCd-([0-9]+)\.([0-9]+)\.([0-9]+)(?:-(\w+))?$/) {
  54                 %version = ( MAJOR => $1, MINOR => $2, PATCH => $3, LABEL => $4 );
  55         }
  56
  57         # Attempt to retrieve missing version information from Git
  58         chomp(my $gr = `git describe --tags 2>/dev/null`);
  59         if ($gr =~ /^v([0-9]+)\.([0-9]+)\.([0-9]+)(?:-\d+-g(\w+))?$/) {
  60                 $version{MAJOR} //= $1;
  61                 $version{MINOR} //= $2;
  62                 $version{PATCH} //= $3;
  63                 $version{LABEL} = $4 if defined $4;
  64         }
  65
  66         # If the user has specified a distribution label then we use it in
  67         # place of the label from src/version.sh or Git.
  68         $version{LABEL} = shift // $version{LABEL};
  69
  70         # If any of these fields are missing then the user has deleted the
  71         # version file and is not running from Git. Fill in the fields with
  72         # dummy data so we don't get into trouble with undef values later.
  73         $version{MAJOR} //= '0';
  74         $version{MINOR} //= '0';
  75         $version{PATCH} //= '0';
  76
  77         # If there is no label then the user is using a stable release which
  78         # does not have a label attached.
  79         if (defined $version{LABEL}) {
  80                 $version{FULL} = "$version{MAJOR}.$version{MINOR}.$version{PATCH}-$version{LABEL}"
  81         } else {
  82                 $version{LABEL} = 'release';
  83                 $version{FULL} = "$version{MAJOR}.$version{MINOR}.$version{PATCH}"
  84         }
  85
  86         return %version;
  87 }
  88
  89 sub module_installed($) {
  90         my $module = shift;
  91         eval("use $module;");
  92         return !$@;
  93 }
  94
  95 sub get_cpu_count {
  96         my $count = 1;
  97         if ($^O =~ /bsd/) {
  98                 $count = `sysctl -n hw.ncpu 2>/dev/null` || 1;
  99         } elsif ($^O eq 'darwin') {
 100                 $count = `sysctl -n hw.activecpu 2>/dev/null` || 1;
 101         } elsif ($^O eq 'linux') {
 102                 $count = `getconf _NPROCESSORS_ONLN 2>/dev/null` || 1;
 103         } elsif ($^O eq 'solaris') {
 104                 $count = `psrinfo -p 2>/dev/null` || 1;
 105         }
 106         chomp($count);
 107         return $count;
 108 }
 109
 110 1;