make/configure.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   5 #   Copyright (C) 2008 Robin Burchell <robin+git@viroteck.net>
   6 #   Copyright (C) 2007-2008 Craig Edwards <craigedwards@brainbox.cc>
   7 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
   8 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
   9 #
  10 # This file is part of InspIRCd.  InspIRCd is free software: you can
  11 # redistribute it and/or modify it under the terms of the GNU General Public
  12 # License as published by the Free Software Foundation, version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but WITHOUT
  15 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  16 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  17 # details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22
  23
  24 BEGIN {
  25         require 5.10.0;
  26 }
  27
  28 package make::configure;
  29
  30 use feature ':5.10';
  31 use strict;
  32 use warnings FATAL => qw(all);
  33
  34 use Cwd                   qw(getcwd);
  35 use Exporter              qw(import);
  36 use File::Basename        qw(basename dirname);
  37 use File::Spec::Functions qw(catdir catfile);
  38
  39 use make::common;
  40 use make::console;
  41
  42 use constant CONFIGURE_ROOT          => dirname dirname __FILE__;
  43 use constant CONFIGURE_DIRECTORY     => catdir(CONFIGURE_ROOT, '.configure');
  44 use constant CONFIGURE_CACHE_FILE    => catfile(CONFIGURE_DIRECTORY, 'cache.cfg');
  45 use constant CONFIGURE_CACHE_VERSION => '1';
  46 use constant CONFIGURE_ERROR_PIPE    => $ENV{INSPIRCD_VERBOSE} ? '' : '1>/dev/null 2>/dev/null';
  47
  48 our @EXPORT = qw(CONFIGURE_CACHE_FILE
  49                  CONFIGURE_CACHE_VERSION
  50                  cmd_clean
  51                  cmd_help
  52                  cmd_update
  53                  run_test
  54                  test_file
  55                  test_header
  56                  write_configure_cache
  57                  get_compiler_info
  58                  find_compiler
  59                  parse_templates);
  60
  61 sub __get_socketengines {
  62         my @socketengines;
  63         foreach (<src/socketengines/socketengine_*.cpp>) {
  64                 s/src\/socketengines\/socketengine_(\w+)\.cpp/$1/;
  65                 push @socketengines, $1;
  66         }
  67         return @socketengines;
  68 }
  69
  70 # TODO: when buildtool is done this can be mostly removed with
  71 #       the remainder being merged into parse_templates.
  72 sub __get_template_settings($$$) {
  73
  74         # These are actually hash references
  75         my ($config, $compiler, $version) = @_;
  76
  77         # Start off by populating with the config
  78         my %settings = %$config;
  79
  80         # Compiler information
  81         while (my ($key, $value) = each %{$compiler}) {
  82                 $settings{'COMPILER_' . $key} = $value;
  83         }
  84
  85         # Version information
  86         while (my ($key, $value) = each %{$version}) {
  87                 $settings{'VERSION_' . $key} = $value;
  88         }
  89
  90         # Miscellaneous information
  91         $settings{CONFIGURE_DIRECTORY} = CONFIGURE_DIRECTORY;
  92         $settings{CONFIGURE_CACHE_FILE} = CONFIGURE_CACHE_FILE;
  93         $settings{SYSTEM_NAME} = lc $^O;
  94
  95         return %settings;
  96 }
  97
  98 sub __test_compiler($) {
  99         my $compiler = shift;
 100         return 0 unless run_test("`$compiler`", !system "$compiler -v ${\CONFIGURE_ERROR_PIPE}");
 101         return 0 unless run_test("`$compiler`", test_file($compiler, 'compiler.cpp', '-fno-rtti'), 'compatible');
 102         return 1;
 103 }
 104
 105 sub cmd_clean {
 106         unlink CONFIGURE_CACHE_FILE;
 107 }
 108
 109 sub cmd_help {
 110         my $PWD = getcwd();
 111         my $SELIST = join ', ', __get_socketengines();
 112         print <<EOH;
 113 Usage: $0 [options]
 114
 115 When no options are specified, configure runs in interactive mode and you must
 116 specify any required values manually. If one or more options are specified,
 117 non-interactive configuration is started and any omitted values are defaulted.
 118
 119 PATH OPTIONS
 120
 121   --system                      Automatically set up the installation paths
 122                                 for system-wide installation.
 123   --prefix=[dir]                The root install directory. If this is set then
 124                                 all subdirectories will be adjusted accordingly.
 125                                 [$PWD/run]
 126   --binary-dir=[dir]            The location where the main server binary is
 127                                 stored.
 128                                 [$PWD/run/bin]
 129   --config-dir=[dir]            The location where the configuration files and
 130                                 SSL certificates are stored.
 131                                 [$PWD/run/conf]
 132   --data-dir=[dir]              The location where the data files, such as the
 133                                 pid file, are stored.
 134                                 [$PWD/run/data]
 135   --example-dir=[dir]           The location where the example configuration files
 136                                 and SQL schemas are stored.
 137                                 [$PWD/run/conf/examples]
 138   --log-dir=[dir]               The location where the log files are stored.
 139                                 [$PWD/run/logs]
 140   --manual-dir=[dir]            The location where the manual files are stored.
 141                                 [$PWD/run/manuals]
 142   --module-dir=[dir]            The location where the loadable modules are
 143                                 stored.
 144                                 [$PWD/run/modules]
 145   --script-dir=[dir]            The location where the scripts, such as the
 146                                 init scripts, are stored.
 147                                 [$PWD/run]
 148
 149 EXTRA MODULE OPTIONS
 150
 151   --enable-extras=[extras]      Enables a comma separated list of extra modules.
 152   --disable-extras=[extras]     Disables a comma separated list of extra modules.
 153   --list-extras                 Shows the availability status of all extra
 154                                 modules.
 155
 156 MISC OPTIONS
 157
 158   --clean                       Remove the configuration cache file and start
 159                                 the interactive configuration wizard.
 160   --disable-auto-extras         Disables automatically enabling extra modules
 161                                 for which the dependencies are available.
 162   --disable-interactive         Disables the interactive configuration wizard.
 163   --distribution-label=[text]   Sets a distribution specific version label in
 164                                 the build configuration.
 165   --gid=[id|name]               Sets the group to run InspIRCd as.
 166   --help                        Show this message and exit.
 167   --socketengine=[name]         Sets the socket engine to be used. Possible
 168                                 values are $SELIST.
 169   --uid=[id|name]               Sets the user to run InspIRCd as.
 170   --update                      Updates the build environment with the settings
 171                                 from the cache.
 172
 173
 174 FLAGS
 175
 176   CXX=[name]                    Sets the C++ compiler to use when building the
 177                                 server. If not specified then the build system
 178                                 will search for c++, g++, clang++ or icpc.
 179
 180 If you have any problems with configuring InspIRCd then visit our IRC channel
 181 at irc.inspircd.org #InspIRCd for support.
 182
 183 EOH
 184         exit 0;
 185 }
 186
 187 sub cmd_update {
 188         print_error "You have not run $0 before. Please do this before trying to update the generated files." unless -f CONFIGURE_CACHE_FILE;
 189         say 'Updating...';
 190         my %config = read_config_file(CONFIGURE_CACHE_FILE);
 191         my %compiler = get_compiler_info($config{CXX});
 192         my %version = get_version $config{DISTRIBUTION};
 193         parse_templates(\%config, \%compiler, \%version);
 194         say 'Update complete!';
 195         exit 0;
 196 }
 197
 198 sub run_test($$;$) {
 199         my ($what, $result, $adjective) = @_;
 200         $adjective //= 'available';
 201         print_format "Checking whether <|GREEN $what|> is $adjective ... ";
 202         print_format $result ? "<|GREEN yes|>\n" : "<|RED no|>\n";
 203         return $result;
 204 }
 205
 206 sub test_file($$;$) {
 207         my ($compiler, $file, $args) = @_;
 208         my $status = 0;
 209         $args //= '';
 210         $status ||= system "$compiler -o __test_$file ${\CONFIGURE_ROOT}/make/test/$file $args ${\CONFIGURE_ERROR_PIPE}";
 211         $status ||= system "./__test_$file ${\CONFIGURE_ERROR_PIPE}";
 212         unlink "./__test_$file";
 213         return !$status;
 214 }
 215
 216 sub test_header($$;$) {
 217         my ($compiler, $header, $args) = @_;
 218         $args //= '';
 219         open(my $fh, "| $compiler -E - $args ${\CONFIGURE_ERROR_PIPE}") or return 0;
 220         print $fh "#include <$header>";
 221         close $fh;
 222         return !$?;
 223 }
 224
 225 sub write_configure_cache(%) {
 226         unless (-e CONFIGURE_DIRECTORY) {
 227                 print_format "Creating <|GREEN ${\CONFIGURE_DIRECTORY}|> ...\n";
 228                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 229         }
 230
 231         print_format "Writing <|GREEN ${\CONFIGURE_CACHE_FILE}|> ...\n";
 232         my %config = @_;
 233         write_config_file CONFIGURE_CACHE_FILE, %config;
 234 }
 235
 236 sub get_compiler_info($) {
 237         my $binary = shift;
 238         my %info = (NAME => 'Unknown', VERSION => '0.0');
 239         return %info if system "$binary -o __compiler_info ${\CONFIGURE_ROOT}/make/test/compiler_info.cpp ${\CONFIGURE_ERROR_PIPE}";
 240         open(my $fh, '-|', './__compiler_info 2>/dev/null');
 241         while (my $line = <$fh>) {
 242                 $info{$1} = $2 if $line =~ /^([A-Z]+)\s(.+)$/;
 243         }
 244         close $fh;
 245         unlink './__compiler_info';
 246         return %info;
 247 }
 248
 249 sub find_compiler {
 250         my @compilers = qw(c++ g++ clang++ icpc);
 251         foreach my $compiler (shift // @compilers) {
 252                 return $compiler if __test_compiler $compiler;
 253                 return "xcrun $compiler" if $^O eq 'darwin' && __test_compiler "xcrun $compiler";
 254         }
 255 }
 256
 257 sub parse_templates($$$) {
 258
 259         # These are actually hash references
 260         my ($config, $compiler, $version) = @_;
 261
 262         # Collect settings to be used when generating files
 263         my %settings = __get_template_settings($config, $compiler, $version);
 264
 265         # Iterate through files in make/template.
 266         foreach (<make/template/*>) {
 267                 print_format "Parsing <|GREEN $_|> ...\n";
 268                 open(my $fh, $_) or print_error "unable to read $_: $!";
 269                 my (@lines, $mode, @platforms, @targets);
 270
 271                 # First pass: parse template variables and directives.
 272                 while (my $line = <$fh>) {
 273                         chomp $line;
 274
 275                         # Does this line match a variable?
 276                         while ($line =~ /(@(\w+?)@)/) {
 277                                 my ($variable, $name) = ($1, $2);
 278                                 if (defined $settings{$name}) {
 279                                         $line =~ s/\Q$variable\E/$settings{$name}/;
 280                                 } else {
 281                                         print_warning "unknown template variable '$name' in $_!";
 282                                         last;
 283                                 }
 284                         }
 285
 286                         # Does this line match a directive?
 287                         if ($line =~ /^(\s*)%(\w+)\s+(.+)$/) {
 288                                 if ($2 eq 'define') {
 289                                         if ($settings{$3}) {
 290                                                 push @lines, "#$1define $3";
 291                                         } else {
 292                                                 push @lines, "#$1undef $3";
 293                                         }
 294                                 } elsif ($2 eq 'mode') {
 295                                         $mode = oct $3;
 296                                 } elsif ($2 eq 'platform') {
 297                                         push @platforms, $3;
 298                                 } elsif ($2 eq 'target') {
 299                                         push @targets, $3
 300                                 } else {
 301                                         print_warning "unknown template command '$2' in $_!";
 302                                         push @lines, $line;
 303                                 }
 304                                 next;
 305                         }
 306                         push @lines, $line;
 307                 }
 308                 close $fh;
 309
 310                 # Only proceed if this file should be templated on this platform.
 311                 if ($#platforms < 0 || grep { $_ eq $^O } @platforms) {
 312
 313                         # Add a default target if the template has not defined one.
 314                         unless (@targets) {
 315                                 push @targets, catfile(CONFIGURE_DIRECTORY, basename $_);
 316                         }
 317
 318                         # Write the templated files to disk.
 319                         for my $target (@targets) {
 320
 321                                 # Create the directory if it doesn't already exist.
 322                                 my $directory = dirname $target;
 323                                 unless (-e $directory) {
 324                                         print_format "Creating <|GREEN $directory|> ...\n";
 325                                         create_directory $directory, 0750 or print_error "unable to create $directory: $!";
 326                                 };
 327
 328                                 # Write the template file.
 329                                 print_format "Writing <|GREEN $target|> ...\n";
 330                                 open(my $fh, '>', $target) or print_error "unable to write $target: $!";
 331                                 foreach (@lines) {
 332                                         say $fh $_;
 333                                 }
 334                                 close $fh;
 335
 336                                 # Set file permissions.
 337                                 if (defined $mode) {
 338                                         chmod $mode, $target;
 339                                 }
 340                         }
 341                 }
 342         }
 343 }
 344
 345 1;