make/configure.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2020 Nicole Kleinhoff <ilbelkyr@shalture.org>
   5 #   Copyright (C) 2013-2020 Sadie Powell <sadie@witchery.services>
   6 #   Copyright (C) 2012 Robby <robby@chatbelgie.be>
   7 #   Copyright (C) 2007-2008 Craig Edwards <brain@inspircd.org>
   8 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
   9 #
  10 # This file is part of InspIRCd.  InspIRCd is free software: you can
  11 # redistribute it and/or modify it under the terms of the GNU General Public
  12 # License as published by the Free Software Foundation, version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but WITHOUT
  15 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  16 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  17 # details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22
  23
  24 package make::configure;
  25
  26 use v5.10.0;
  27 use strict;
  28 use warnings FATAL => qw(all);
  29
  30 use Exporter              qw(import);
  31 use File::Basename        qw(basename dirname);
  32 use File::Spec::Functions qw(abs2rel catdir catfile);
  33
  34 use make::common;
  35 use make::console;
  36
  37 use constant CONFIGURE_ROOT          => dirname dirname __FILE__;
  38 use constant CONFIGURE_DIRECTORY     => catdir(CONFIGURE_ROOT, '.configure');
  39 use constant CONFIGURE_CACHE_FILE    => catfile(CONFIGURE_DIRECTORY, 'cache.cfg');
  40 use constant CONFIGURE_CACHE_VERSION => '1';
  41 use constant CONFIGURE_ERROR_PIPE    => $ENV{INSPIRCD_VERBOSE} ? '' : '1>/dev/null 2>/dev/null';
  42
  43 our @EXPORT = qw(CONFIGURE_CACHE_FILE
  44                  CONFIGURE_CACHE_VERSION
  45                  CONFIGURE_DIRECTORY
  46                  cmd_clean
  47                  cmd_help
  48                  cmd_update
  49                  run_test
  50                  test_file
  51                  test_header
  52                  module_expand
  53                  module_shrink
  54                  write_configure_cache
  55                  get_compiler_info
  56                  find_compiler
  57                  parse_templates);
  58
  59 sub __get_socketengines {
  60         my @socketengines;
  61         foreach (<${\CONFIGURE_ROOT}/src/socketengines/socketengine_*.cpp>) {
  62                 s/src\/socketengines\/socketengine_(\w+)\.cpp/$1/;
  63                 push @socketengines, $1;
  64         }
  65         return @socketengines;
  66 }
  67
  68 # TODO: when buildtool is done this can be mostly removed with
  69 #       the remainder being merged into parse_templates.
  70 sub __get_template_settings($$$) {
  71
  72         # These are actually hash references
  73         my ($config, $compiler, $version) = @_;
  74
  75         # Start off by populating with the config
  76         my %settings = %$config;
  77
  78         # Compiler information
  79         while (my ($key, $value) = each %{$compiler}) {
  80                 $settings{'COMPILER_' . $key} = $value;
  81         }
  82
  83         # Version information
  84         while (my ($key, $value) = each %{$version}) {
  85                 $settings{'VERSION_' . $key} = $value;
  86         }
  87
  88         # Miscellaneous information
  89         $settings{CONFIGURE_DIRECTORY} = CONFIGURE_DIRECTORY;
  90         $settings{CONFIGURE_CACHE_FILE} = CONFIGURE_CACHE_FILE;
  91         $settings{SYSTEM_NAME} = lc $^O;
  92
  93         return %settings;
  94 }
  95
  96 sub __test_compiler($) {
  97         my $compiler = shift;
  98         return 0 unless run_test("`$compiler`", !system "$compiler -v ${\CONFIGURE_ERROR_PIPE}");
  99         return 0 unless run_test("`$compiler`", test_file($compiler, 'compiler.cpp', '-fno-rtti'), 'compatible');
 100         return 1;
 101 }
 102
 103 sub cmd_clean {
 104         unlink CONFIGURE_CACHE_FILE;
 105 }
 106
 107 sub cmd_help {
 108         my $SELIST = join ', ', __get_socketengines();
 109         print <<EOH;
 110 Usage: $0 [options]
 111
 112 When no options are specified, configure runs in interactive mode and you must
 113 specify any required values manually. If one or more options are specified,
 114 non-interactive configuration is started and any omitted values are defaulted.
 115
 116 PATH OPTIONS
 117
 118   --system                      Automatically set up the installation paths
 119                                 for system-wide installation.
 120   --prefix=[dir]                The root install directory. If this is set then
 121                                 all subdirectories will be adjusted accordingly.
 122                                 [${\CONFIGURE_ROOT}/run]
 123   --binary-dir=[dir]            The location where the main server binary is
 124                                 stored.
 125                                 [${\CONFIGURE_ROOT}/run/bin]
 126   --config-dir=[dir]            The location where the configuration files and
 127                                 SSL certificates are stored.
 128                                 [${\CONFIGURE_ROOT}/run/conf]
 129   --data-dir=[dir]              The location where the data files, such as the
 130                                 pid file, are stored.
 131                                 [${\CONFIGURE_ROOT}/run/data]
 132   --example-dir=[dir]           The location where the example configuration files
 133                                 and SQL schemas are stored.
 134                                 [${\CONFIGURE_ROOT}/run/conf/examples]
 135   --log-dir=[dir]               The location where the log files are stored.
 136                                 [${\CONFIGURE_ROOT}/run/logs]
 137   --manual-dir=[dir]            The location where the manual files are stored.
 138                                 [${\CONFIGURE_ROOT}/run/manuals]
 139   --module-dir=[dir]            The location where the loadable modules are
 140                                 stored.
 141                                 [${\CONFIGURE_ROOT}/run/modules]
 142   --script-dir=[dir]            The location where the scripts, such as the
 143                                 init scripts, are stored.
 144                                 [${\CONFIGURE_ROOT}/run]
 145
 146 EXTRA MODULE OPTIONS
 147
 148   --enable-extras=[extras]      Enables a comma separated list of extra modules.
 149   --disable-extras=[extras]     Disables a comma separated list of extra modules.
 150   --list-extras                 Shows the availability status of all extra
 151                                 modules.
 152
 153 MISC OPTIONS
 154
 155   --clean                       Remove the configuration cache file and start
 156                                 the interactive configuration wizard.
 157   --disable-auto-extras         Disables automatically enabling extra modules
 158                                 for which the dependencies are available.
 159   --disable-interactive         Disables the interactive configuration wizard.
 160   --distribution-label=[text]   Sets a distribution specific version label in
 161                                 the build configuration.
 162   --gid=[id|name]               Sets the group to run InspIRCd as.
 163   --help                        Show this message and exit.
 164   --socketengine=[name]         Sets the socket engine to be used. Possible
 165                                 values are $SELIST.
 166   --uid=[id|name]               Sets the user to run InspIRCd as.
 167   --update                      Updates the build environment with the settings
 168                                 from the cache.
 169
 170
 171 FLAGS
 172
 173   CXX=[name]                    Sets the C++ compiler to use when building the
 174                                 server. If not specified then the build system
 175                                 will search for c++, g++, clang++ or icpc.
 176
 177 If you have any problems with configuring InspIRCd then visit our IRC channel
 178 at irc.inspircd.org #InspIRCd or create a support discussion at
 179 https://github.com/inspircd/inspircd/discussions.
 180
 181 Packagers: see https://docs.inspircd.org/packaging/ for packaging advice.
 182 EOH
 183         exit 0;
 184 }
 185
 186 sub cmd_update {
 187         print_error "You have not run $0 before. Please do this before trying to update the generated files." unless -f CONFIGURE_CACHE_FILE;
 188         say 'Updating...';
 189         my %config = read_config_file(CONFIGURE_CACHE_FILE);
 190         $config{EXAMPLE_DIR} //= catdir $config{CONFIG_DIR}, 'examples';
 191         $config{RUNTIME_DIR} //= $config{DATA_DIR};
 192         my %compiler = get_compiler_info($config{CXX});
 193         my %version = get_version $config{DISTRIBUTION};
 194         parse_templates(\%config, \%compiler, \%version);
 195         say 'Update complete!';
 196         exit 0;
 197 }
 198
 199 sub run_test($$;$) {
 200         my ($what, $result, $adjective) = @_;
 201         $adjective //= 'available';
 202         print console_format "Checking whether <|GREEN $what|> is $adjective ... ";
 203         say console_format $result ? "<|GREEN yes|>" : "<|RED no|>";
 204         return $result;
 205 }
 206
 207 sub test_file($$;$) {
 208         my ($compiler, $file, $args) = @_;
 209         my $status = 0;
 210         $args //= '';
 211         $status ||= system "$compiler -o ${\CONFIGURE_ROOT}/__test_$file ${\CONFIGURE_ROOT}/make/test/$file $args ${\CONFIGURE_ERROR_PIPE}";
 212         $status ||= system "${\CONFIGURE_ROOT}/__test_$file ${\CONFIGURE_ERROR_PIPE}";
 213         unlink "${\CONFIGURE_ROOT}/__test_$file";
 214         return !$status;
 215 }
 216
 217 sub test_header($$;$) {
 218         my ($compiler, $header, $args) = @_;
 219         $args //= '';
 220         open(my $fh, "| $compiler -E - $args ${\CONFIGURE_ERROR_PIPE}") or return 0;
 221         print $fh "#include <$header>";
 222         close $fh;
 223         return !$?;
 224 }
 225
 226 sub module_expand($) {
 227         my $module = shift;
 228         $module = "m_$module" unless $module =~ /^(?:m|core)_/;
 229         $module = "$module.cpp" unless $module =~ /\.cpp$/;
 230         return $module;
 231 }
 232
 233 sub module_shrink($) {
 234         my $module = basename shift;
 235         return $module =~ s/(?:^m_|\.cpp$)//gr;
 236 }
 237
 238 sub write_configure_cache(%) {
 239         unless (-e CONFIGURE_DIRECTORY) {
 240                 say console_format "Creating <|GREEN ${\abs2rel CONFIGURE_DIRECTORY, CONFIGURE_ROOT}|> ...";
 241                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 242         }
 243
 244         say console_format "Writing <|GREEN ${\abs2rel CONFIGURE_CACHE_FILE, CONFIGURE_ROOT}|> ...";
 245         my %config = @_;
 246         write_config_file CONFIGURE_CACHE_FILE, %config;
 247 }
 248
 249 sub get_compiler_info($) {
 250         my $binary = shift;
 251         my %info = (NAME => 'Unknown', VERSION => '0.0');
 252         return %info if system "$binary -o __compiler_info ${\CONFIGURE_ROOT}/make/test/compiler_info.cpp ${\CONFIGURE_ERROR_PIPE}";
 253         open(my $fh, '-|', './__compiler_info 2>/dev/null');
 254         while (my $line = <$fh>) {
 255                 $info{$1} = $2 if $line =~ /^([A-Z]+)\s(.+)$/;
 256         }
 257         close $fh;
 258         unlink './__compiler_info';
 259         return %info;
 260 }
 261
 262 sub find_compiler {
 263         my @compilers = qw(c++ g++ clang++ icpc);
 264         foreach my $compiler (shift // @compilers) {
 265                 return $compiler if __test_compiler $compiler;
 266                 return "xcrun $compiler" if $^O eq 'darwin' && __test_compiler "xcrun $compiler";
 267         }
 268 }
 269
 270 sub parse_templates($$$) {
 271
 272         # These are actually hash references
 273         my ($config, $compiler, $version) = @_;
 274
 275         # Collect settings to be used when generating files
 276         my %settings = __get_template_settings($config, $compiler, $version);
 277
 278         # Iterate through files in make/template.
 279         foreach my $template (<${\CONFIGURE_ROOT}/make/template/*>) {
 280                 say console_format "Parsing <|GREEN ${\abs2rel $template, CONFIGURE_ROOT}|> ...";
 281                 open(my $fh, $template) or print_error "unable to read $template: $!";
 282                 my (@lines, $mode, @platforms, @targets);
 283
 284                 # First pass: parse template variables and directives.
 285                 while (my $line = <$fh>) {
 286                         chomp $line;
 287
 288                         # Does this line match a variable?
 289                         while ($line =~ /(@(\w+?)(?:\|(\w*))?@)/) {
 290                                 my ($variable, $name, $default) = ($1, $2, $3);
 291                                 if (defined $settings{$name}) {
 292                                         $line =~ s/\Q$variable\E/$settings{$name}/;
 293                                 } elsif (defined $default) {
 294                                         $line =~ s/\Q$variable\E/$default/;
 295                                 } else {
 296                                         print_warning "unknown template variable '$name' in $template!";
 297                                         last;
 298                                 }
 299                         }
 300
 301                         # Does this line match a directive?
 302                         if ($line =~ /^(\s*)%(\w+)\s+(.+)$/) {
 303                                 if ($2 eq 'define') {
 304                                         if ($settings{$3}) {
 305                                                 push @lines, "#$1define $3";
 306                                         } else {
 307                                                 push @lines, "#$1undef $3";
 308                                         }
 309                                 } elsif ($2 eq 'mode') {
 310                                         $mode = oct $3;
 311                                 } elsif ($2 eq 'platform') {
 312                                         push @platforms, $3;
 313                                 } elsif ($2 eq 'target') {
 314                                         push @targets, catfile CONFIGURE_ROOT, $3;
 315                                 } else {
 316                                         print_warning "unknown template command '$2' in $template!";
 317                                         push @lines, $line;
 318                                 }
 319                                 next;
 320                         }
 321                         push @lines, $line;
 322                 }
 323                 close $fh;
 324
 325                 # Only proceed if this file should be templated on this platform.
 326                 if ($#platforms < 0 || grep { $_ eq $^O } @platforms) {
 327
 328                         # Add a default target if the template has not defined one.
 329                         unless (@targets) {
 330                                 push @targets, catfile(CONFIGURE_DIRECTORY, basename $template);
 331                         }
 332
 333                         # Write the templated files to disk.
 334                         for my $target (@targets) {
 335
 336                                 # Create the directory if it doesn't already exist.
 337                                 my $directory = dirname $target;
 338                                 unless (-e $directory) {
 339                                         say console_format "Creating <|GREEN ${\abs2rel $directory, CONFIGURE_ROOT}|> ...";
 340                                         create_directory $directory, 0750 or print_error "unable to create $directory: $!";
 341                                 };
 342
 343                                 # Write the template file.
 344                                 say console_format "Writing <|GREEN ${\abs2rel $target, CONFIGURE_ROOT}|> ...";
 345                                 open(my $fh, '>', $target) or print_error "unable to write $target: $!";
 346                                 foreach (@lines) {
 347                                         say $fh $_;
 348                                 }
 349                                 close $fh;
 350
 351                                 # Set file permissions.
 352                                 if (defined $mode) {
 353                                         chmod $mode, $target;
 354                                 }
 355                         }
 356                 }
 357         }
 358 }
 359
 360 1;