make/configure.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   5 #   Copyright (C) 2008 Robin Burchell <robin+git@viroteck.net>
   6 #   Copyright (C) 2007-2008 Craig Edwards <craigedwards@brainbox.cc>
   7 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
   8 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
   9 #
  10 # This file is part of InspIRCd.  InspIRCd is free software: you can
  11 # redistribute it and/or modify it under the terms of the GNU General Public
  12 # License as published by the Free Software Foundation, version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but WITHOUT
  15 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  16 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  17 # details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22
  23
  24 BEGIN {
  25         require 5.10.0;
  26 }
  27
  28 package make::configure;
  29
  30 use feature ':5.10';
  31 use strict;
  32 use warnings FATAL => qw(all);
  33
  34 use Cwd                   qw(getcwd);
  35 use Exporter              qw(import);
  36 use File::Basename        qw(basename dirname);
  37 use File::Spec::Functions qw(catfile);
  38
  39 use make::common;
  40 use make::console;
  41
  42 use constant CONFIGURE_DIRECTORY     => '.configure';
  43 use constant CONFIGURE_CACHE_FILE    => catfile(CONFIGURE_DIRECTORY, 'cache.cfg');
  44 use constant CONFIGURE_CACHE_VERSION => '1';
  45 use constant CONFIGURE_ERROR_PIPE    => $ENV{INSPIRCD_VERBOSE} ? '' : '1>/dev/null 2>/dev/null';
  46
  47 our @EXPORT = qw(CONFIGURE_CACHE_FILE
  48                  CONFIGURE_CACHE_VERSION
  49                  cmd_clean
  50                  cmd_help
  51                  cmd_update
  52                  run_test
  53                  test_file
  54                  test_header
  55                  write_configure_cache
  56                  get_compiler_info
  57                  find_compiler
  58                  parse_templates);
  59
  60 sub __get_socketengines {
  61         my @socketengines;
  62         foreach (<src/socketengines/socketengine_*.cpp>) {
  63                 s/src\/socketengines\/socketengine_(\w+)\.cpp/$1/;
  64                 push @socketengines, $1;
  65         }
  66         return @socketengines;
  67 }
  68
  69 # TODO: when buildtool is done this can be mostly removed with
  70 #       the remainder being merged into parse_templates.
  71 sub __get_template_settings($$$) {
  72
  73         # These are actually hash references
  74         my ($config, $compiler, $version) = @_;
  75
  76         # Start off by populating with the config
  77         my %settings = %$config;
  78
  79         # Compiler information
  80         while (my ($key, $value) = each %{$compiler}) {
  81                 $settings{'COMPILER_' . $key} = $value;
  82         }
  83
  84         # Version information
  85         while (my ($key, $value) = each %{$version}) {
  86                 $settings{'VERSION_' . $key} = $value;
  87         }
  88
  89         # Miscellaneous information
  90         $settings{CONFIGURE_DIRECTORY} = CONFIGURE_DIRECTORY;
  91         $settings{CONFIGURE_CACHE_FILE} = CONFIGURE_CACHE_FILE;
  92         $settings{SYSTEM_NAME} = lc $^O;
  93         chomp($settings{SYSTEM_NAME_VERSION} = `uname -sr 2>/dev/null`);
  94
  95         return %settings;
  96 }
  97
  98 sub __test_compiler($) {
  99         my $compiler = shift;
 100         return 0 unless run_test("`$compiler`", !system "$compiler -v ${\CONFIGURE_ERROR_PIPE}");
 101         return 0 unless run_test("`$compiler`", test_file($compiler, 'compiler.cpp', '-fno-rtti'), 'compatible');
 102         return 1;
 103 }
 104
 105 sub cmd_clean {
 106         unlink CONFIGURE_CACHE_FILE;
 107 }
 108
 109 sub cmd_help {
 110         my $PWD = getcwd();
 111         my $SELIST = join ', ', __get_socketengines();
 112         print <<EOH;
 113 Usage: $0 [options]
 114
 115 When no options are specified, configure runs in interactive mode and you must
 116 specify any required values manually. If one or more options are specified,
 117 non-interactive configuration is started and any omitted values are defaulted.
 118
 119 PATH OPTIONS
 120
 121   --system                      Automatically set up the installation paths
 122                                 for system-wide installation.
 123   --prefix=[dir]                The root install directory. If this is set then
 124                                 all subdirectories will be adjusted accordingly.
 125                                 [$PWD/run]
 126   --binary-dir=[dir]            The location where the main server binary is
 127                                 stored.
 128                                 [$PWD/run/bin]
 129   --config-dir=[dir]            The location where the configuration files and
 130                                 SSL certificates are stored.
 131                                 [$PWD/run/conf]
 132   --data-dir=[dir]              The location where the data files, such as the
 133                                 pid file, are stored.
 134                                 [$PWD/run/data]
 135   --log-dir=[dir]               The location where the log files are stored.
 136                                 [$PWD/run/logs]
 137   --manual-dir=[dir]            The location where the manual files are stored.
 138                                 [$PWD/run/manuals]
 139   --module-dir=[dir]            The location where the loadable modules are
 140                                 stored.
 141                                 [$PWD/run/modules]
 142
 143 EXTRA MODULE OPTIONS
 144
 145   --enable-extras=[extras]      Enables a comma separated list of extra modules.
 146   --disable-extras=[extras]     Disables a comma separated list of extra modules.
 147   --list-extras                 Shows the availability status of all extra
 148                                 modules.
 149
 150 MISC OPTIONS
 151
 152   --clean                       Remove the configuration cache file and start
 153                                 the interactive configuration wizard.
 154   --disable-interactive         Disables the interactive configuration wizard.
 155   --distribution-label=[text]   Sets a distribution specific version label in
 156                                 the build configuration.
 157   --gid=[id|name]               Sets the group to run InspIRCd as.
 158   --help                        Show this message and exit.
 159   --socketengine=[name]         Sets the socket engine to be used. Possible
 160                                 values are $SELIST.
 161   --uid=[id|name]               Sets the user to run InspIRCd as.
 162   --update                      Updates the build environment with the settings
 163                                 from the cache.
 164
 165
 166 FLAGS
 167
 168   CXX=[name]                    Sets the C++ compiler to use when building the
 169                                 server. If not specified then the build system
 170                                 will search for c++, g++, clang++ or icpc.
 171
 172 If you have any problems with configuring InspIRCd then visit our IRC channel
 173 at irc.inspircd.org #InspIRCd for support.
 174
 175 EOH
 176         exit 0;
 177 }
 178
 179 sub cmd_update {
 180         print_error "You have not run $0 before. Please do this before trying to update the generated files." unless -f CONFIGURE_CACHE_FILE;
 181         say 'Updating...';
 182         my %config = read_config_file(CONFIGURE_CACHE_FILE);
 183         my %compiler = get_compiler_info($config{CXX});
 184         my %version = get_version $config{DISTRIBUTION};
 185         parse_templates(\%config, \%compiler, \%version);
 186         say 'Update complete!';
 187         exit 0;
 188 }
 189
 190 sub run_test($$;$) {
 191         my ($what, $result, $adjective) = @_;
 192         $adjective //= 'available';
 193         print_format "Checking whether <|GREEN $what|> is $adjective ... ";
 194         print_format $result ? "<|GREEN yes|>\n" : "<|RED no|>\n";
 195         return $result;
 196 }
 197
 198 sub test_file($$;$) {
 199         my ($compiler, $file, $args) = @_;
 200         my $status = 0;
 201         $args //= '';
 202         $status ||= system "$compiler -o __test_$file make/test/$file $args ${\CONFIGURE_ERROR_PIPE}";
 203         $status ||= system "./__test_$file ${\CONFIGURE_ERROR_PIPE}";
 204         unlink "./__test_$file";
 205         return !$status;
 206 }
 207
 208 sub test_header($$;$) {
 209         my ($compiler, $header, $args) = @_;
 210         $args //= '';
 211         open(COMPILER, "| $compiler -E - $args ${\CONFIGURE_ERROR_PIPE}") or return 0;
 212         print COMPILER "#include <$header>";
 213         close(COMPILER);
 214         return !$?;
 215 }
 216
 217 sub write_configure_cache(%) {
 218         unless (-e CONFIGURE_DIRECTORY) {
 219                 print_format "Creating <|GREEN ${\CONFIGURE_DIRECTORY}|> ...\n";
 220                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 221         }
 222
 223         print_format "Writing <|GREEN ${\CONFIGURE_CACHE_FILE}|> ...\n";
 224         my %config = @_;
 225         write_config_file CONFIGURE_CACHE_FILE, %config;
 226 }
 227
 228 sub get_compiler_info($) {
 229         my $binary = shift;
 230         my %info = (NAME => 'Unknown', VERSION => '0.0');
 231         return %info if system "$binary -o __compiler_info make/test/compiler_info.cpp ${\CONFIGURE_ERROR_PIPE}";
 232         open(my $fh, '-|', './__compiler_info 2>/dev/null');
 233         while (my $line = <$fh>) {
 234                 $info{$1} = $2 if $line =~ /^([A-Z]+)\s(.+)$/;
 235         }
 236         close $fh;
 237         unlink './__compiler_info';
 238         return %info;
 239 }
 240
 241 sub find_compiler {
 242         my @compilers = qw(c++ g++ clang++ icpc);
 243         foreach my $compiler (shift // @compilers) {
 244                 return $compiler if __test_compiler $compiler;
 245                 return "xcrun $compiler" if $^O eq 'darwin' && __test_compiler "xcrun $compiler";
 246         }
 247 }
 248
 249 sub parse_templates($$$) {
 250
 251         # These are actually hash references
 252         my ($config, $compiler, $version) = @_;
 253
 254         # Collect settings to be used when generating files
 255         my %settings = __get_template_settings($config, $compiler, $version);
 256
 257         # Iterate through files in make/template.
 258         foreach (<make/template/*>) {
 259                 print_format "Parsing <|GREEN $_|> ...\n";
 260                 open(TEMPLATE, $_) or print_error "unable to read $_: $!";
 261                 my (@lines, $mode, @platforms, %targets);
 262
 263                 # First pass: parse template variables and directives.
 264                 while (my $line = <TEMPLATE>) {
 265                         chomp $line;
 266
 267                         # Does this line match a variable?
 268                         while ($line =~ /(@(\w+?)@)/) {
 269                                 my ($variable, $name) = ($1, $2);
 270                                 if (defined $settings{$name}) {
 271                                         $line =~ s/\Q$variable\E/$settings{$name}/;
 272                                 } else {
 273                                         print_warning "unknown template variable '$name' in $_!";
 274                                         last;
 275                                 }
 276                         }
 277
 278                         # Does this line match a directive?
 279                         if ($line =~ /^\s*%(\w+)\s+(.+)$/) {
 280                                 if ($1 eq 'define') {
 281                                         if ($settings{$2}) {
 282                                                 push @lines, "#define $2";
 283                                         } else {
 284                                                 push @lines, "#undef $2";
 285                                         }
 286                                 } elsif ($1 eq 'mode') {
 287                                         $mode = oct $2;
 288                                 } elsif ($1 eq 'platform') {
 289                                         push @platforms, $2;
 290                                 } elsif ($1 eq 'target') {
 291                                         if ($2 =~ /(\w+)\s(.+)/) {
 292                                                 $targets{$1} = $2;
 293                                         } else {
 294                                                 $targets{DEFAULT} = $2;
 295                                         }
 296                                 } else {
 297                                         print_warning "unknown template command '$1' in $_!";
 298                                         push @lines, $line;
 299                                 }
 300                                 next;
 301                         }
 302                         push @lines, $line;
 303                 }
 304                 close(TEMPLATE);
 305
 306                 # Only proceed if this file should be templated on this platform.
 307                 if ($#platforms < 0 || grep { $_ eq $^O } @platforms) {
 308
 309                         # Add a default target if the template has not defined one.
 310                         unless (scalar keys %targets) {
 311                                 $targets{DEFAULT} = catfile(CONFIGURE_DIRECTORY, basename $_);
 312                         }
 313
 314                         # Second pass: parse makefile junk and write files.
 315                         while (my ($name, $target) = each %targets) {
 316
 317                                 # TODO: when buildtool is done this mess can be removed completely.
 318                                 my @final_lines;
 319                                 foreach my $line (@lines) {
 320
 321                                         # Are we parsing a makefile and does this line match a statement?
 322                                         if ($name =~ /(?:BSD|GNU)_MAKE/ && $line =~ /^\s*\@(\w+)(?:\s+(.+))?$/) {
 323                                                 my @tokens = split /\s/, $2 if defined $2;
 324                                                 if ($1 eq 'DO_EXPORT' && defined $2) {
 325                                                         if ($name eq 'BSD_MAKE') {
 326                                                                 foreach my $variable (@tokens) {
 327                                                                         push @final_lines, "MAKEENV += $variable='\${$variable}'";
 328                                                                 }
 329                                                         } elsif ($name eq 'GNU_MAKE') {
 330                                                                 push @final_lines, "export $2";
 331                                                         }
 332                                                 } elsif ($1 eq 'ELSE') {
 333                                                         if ($name eq 'BSD_MAKE') {
 334                                                                 push @final_lines, ".else";
 335                                                         } elsif ($name eq 'GNU_MAKE') {
 336                                                                 push @final_lines, "else";
 337                                                         }
 338                                                 } elsif ($1 eq 'ENDIF') {
 339                                                         if ($name eq 'BSD_MAKE') {
 340                                                                 push @final_lines, ".endif";
 341                                                         } elsif ($name eq 'GNU_MAKE') {
 342                                                                 push @final_lines, "endif";
 343                                                         }
 344                                                 } elsif ($1 eq 'ELSIFEQ' && defined $2) {
 345                                                         if ($name eq 'BSD_MAKE') {
 346                                                                 push @final_lines, ".elif $tokens[0] == $tokens[1]";
 347                                                         } elsif ($name eq 'GNU_MAKE') {
 348                                                                 push @final_lines, "else ifeq ($tokens[0], $tokens[1])";
 349                                                         }
 350                                                 } elsif ($1 eq 'IFDEF' && defined $2) {
 351                                                         if ($name eq 'BSD_MAKE') {
 352                                                                 push @final_lines, ".if defined($2)";
 353                                                         } elsif ($name eq 'GNU_MAKE') {
 354                                                                 push @final_lines, "ifdef $2";
 355                                                         }
 356                                                 } elsif ($1 eq 'IFEQ' && defined $2) {
 357                                                         if ($name eq 'BSD_MAKE') {
 358                                                                 push @final_lines, ".if $tokens[0] == $tokens[1]";
 359                                                         } elsif ($name eq 'GNU_MAKE') {
 360                                                                 push @final_lines, "ifeq ($tokens[0],$tokens[1])";
 361                                                         }
 362                                                 } elsif ($1 eq 'IFNEQ' && defined $2) {
 363                                                         if ($name eq 'BSD_MAKE') {
 364                                                                 push @final_lines, ".if $tokens[0] != $tokens[1]";
 365                                                         } elsif ($name eq 'GNU_MAKE') {
 366                                                                 push @final_lines, "ifneq ($tokens[0],$tokens[1])";
 367                                                         }
 368                                                 } elsif ($1 eq 'IFNDEF' && defined $2) {
 369                                                         if ($name eq 'BSD_MAKE') {
 370                                                                 push @final_lines, ".if !defined($2)";
 371                                                         } elsif ($name eq 'GNU_MAKE') {
 372                                                                 push @final_lines, "ifndef $2";
 373                                                         }
 374                                                 } elsif ($1 eq 'TARGET' && defined $2) {
 375                                                         if ($tokens[0] eq $name) {
 376                                                                 push @final_lines, substr($2, length($tokens[0]) + 1);
 377                                                         }
 378                                                 } elsif ($1 !~ /[A-Z]/) {
 379                                                         # HACK: silently ignore if lower case as these are probably make commands.
 380                                                         push @final_lines, $line;
 381                                                 } else {
 382                                                         print_warning "unknown template command '$1' in $_!";
 383                                                         push @final_lines, $line;
 384                                                 }
 385                                                 next;
 386                                         }
 387
 388                                         push @final_lines, $line;
 389                                 }
 390
 391                                 # Create the directory if it doesn't already exist.
 392                                 my $directory = dirname $target;
 393                                 unless (-e $directory) {
 394                                         print_format "Creating <|GREEN $directory|> ...\n";
 395                                         create_directory $directory, 0750 or print_error "unable to create $directory: $!";
 396                                 };
 397
 398                                 # Write the template file.
 399                                 print_format "Writing <|GREEN $target|> ...\n";
 400                                 open(TARGET, '>', $target) or print_error "unable to write $target: $!";
 401                                 foreach (@final_lines) {
 402                                         say TARGET $_;
 403                                 }
 404                                 close(TARGET);
 405
 406                                 # Set file permissions.
 407                                 if (defined $mode) {
 408                                         chmod $mode, $target;
 409                                 }
 410                         }
 411                 }
 412         }
 413 }
 414
 415 1;