make/configure.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2012-2014 Peter Powell <petpow@saberuk.com>
   5 #   Copyright (C) 2008 Robin Burchell <robin+git@viroteck.net>
   6 #   Copyright (C) 2007-2008 Craig Edwards <craigedwards@brainbox.cc>
   7 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
   8 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
   9 #
  10 # This file is part of InspIRCd.  InspIRCd is free software: you can
  11 # redistribute it and/or modify it under the terms of the GNU General Public
  12 # License as published by the Free Software Foundation, version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but WITHOUT
  15 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  16 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  17 # details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22
  23
  24 BEGIN {
  25         require 5.10.0;
  26 }
  27
  28 package make::configure;
  29
  30 use feature ':5.10';
  31 use strict;
  32 use warnings FATAL => qw(all);
  33
  34 use Cwd                   qw(getcwd);
  35 use Exporter              qw(import);
  36 use File::Basename        qw(basename dirname);
  37 use File::Spec::Functions qw(catfile);
  38
  39 use make::common;
  40 use make::console;
  41
  42 use constant CONFIGURE_DIRECTORY     => '.configure';
  43 use constant CONFIGURE_CACHE_FILE    => catfile(CONFIGURE_DIRECTORY, 'cache.cfg');
  44 use constant CONFIGURE_CACHE_VERSION => '1';
  45
  46 our @EXPORT = qw(CONFIGURE_CACHE_FILE
  47                  CONFIGURE_CACHE_VERSION
  48                  cmd_clean
  49                  cmd_help
  50                  cmd_update
  51                  run_test
  52                  test_file
  53                  test_header
  54                  read_configure_cache
  55                  write_configure_cache
  56                  get_compiler_info
  57                  find_compiler
  58                  parse_templates);
  59
  60 sub __get_socketengines {
  61         my @socketengines;
  62         foreach (<src/socketengines/socketengine_*.cpp>) {
  63                 s/src\/socketengines\/socketengine_(\w+)\.cpp/$1/;
  64                 push @socketengines, $1;
  65         }
  66         return @socketengines;
  67 }
  68
  69 # TODO: when buildtool is done this can be mostly removed with
  70 #       the remainder being merged into parse_templates.
  71 sub __get_template_settings($$$) {
  72
  73         # These are actually hash references
  74         my ($config, $compiler, $version) = @_;
  75
  76         # Start off by populating with the config
  77         my %settings = %$config;
  78
  79         # Compiler information
  80         while (my ($key, $value) = each %{$compiler}) {
  81                 $settings{'COMPILER_' . $key} = $value;
  82         }
  83
  84         # Version information
  85         while (my ($key, $value) = each %{$version}) {
  86                 $settings{'VERSION_' . $key} = $value;
  87         }
  88
  89         # Miscellaneous information
  90         $settings{CONFIGURE_DIRECTORY} = CONFIGURE_DIRECTORY;
  91         $settings{CONFIGURE_CACHE_FILE} = CONFIGURE_CACHE_FILE;
  92         $settings{SYSTEM_NAME} = lc $^O;
  93         chomp($settings{SYSTEM_NAME_VERSION} = `uname -sr 2>/dev/null`);
  94
  95         return %settings;
  96 }
  97
  98 sub __test_compiler($) {
  99         my $compiler = shift;
 100         return 0 unless run_test("`$compiler`", !system "$compiler -v >/dev/null 2>&1");
 101         return 0 unless run_test("`$compiler`", test_file($compiler, 'compiler.cpp', '-fno-rtti'), 'compatible');
 102         return 1;
 103 }
 104
 105 sub cmd_clean {
 106         unlink CONFIGURE_CACHE_FILE;
 107 }
 108
 109 sub cmd_help {
 110         my $PWD = getcwd();
 111         my $SELIST = join ', ', __get_socketengines();
 112         print <<EOH;
 113 Usage: $0 [options]
 114
 115 When no options are specified, configure runs in interactive mode and you must
 116 specify any required values manually. If one or more options are specified,
 117 non-interactive configuration is started and any omitted values are defaulted.
 118
 119 PATH OPTIONS
 120
 121   --system                      Automatically set up the installation paths
 122                                 for system-wide installation.
 123   --prefix=[dir]                The root install directory. If this is set then
 124                                 all subdirectories will be adjusted accordingly.
 125                                 [$PWD/run]
 126   --binary-dir=[dir]            The location where the main server binary is
 127                                 stored.
 128                                 [$PWD/run/bin]
 129   --config-dir=[dir]            The location where the configuration files and
 130                                 SSL certificates are stored.
 131                                 [$PWD/run/conf]
 132   --data-dir=[dir]              The location where the data files, such as the
 133                                 pid file, are stored.
 134                                 [$PWD/run/data]
 135   --log-dir=[dir]               The location where the log files are stored.
 136                                 [$PWD/run/logs]
 137   --manual-dir=[dir]            The location where the manual files are stored.
 138                                 [$PWD/run/manuals]
 139   --module-dir=[dir]            The location where the loadable modules are
 140                                 stored.
 141                                 [$PWD/run/modules]
 142
 143 EXTRA MODULE OPTIONS
 144
 145   --enable-extras=[extras]      Enables a comma separated list of extra modules.
 146   --disable-extras=[extras]     Disables a comma separated list of extra modules.
 147   --list-extras                 Shows the availability status of all extra
 148                                 modules.
 149
 150 MISC OPTIONS
 151
 152   --clean                       Remove the configuration cache file and start
 153                                 the interactive configuration wizard.
 154   --disable-interactive         Disables the interactive configuration wizard.
 155   --distribution-label=[text]   Sets a distribution specific version label in
 156                                 the build configuration.
 157   --gid=[id|name]               Sets the group to run InspIRCd as.
 158   --help                        Show this message and exit.
 159   --socketengine=[name]         Sets the socket engine to be used. Possible
 160                                 values are $SELIST.
 161   --uid=[id|name]               Sets the user to run InspIRCd as.
 162   --update                      Updates the build environment.
 163
 164
 165 FLAGS
 166
 167   CXX=[name]                    Sets the C++ compiler to use when building the
 168                                 server. If not specified then the build system
 169                                 will search for c++, g++, clang++ or icpc.
 170
 171 If you have any problems with configuring InspIRCd then visit our IRC channel
 172 at irc.inspircd.org #InspIRCd for support.
 173
 174 EOH
 175         exit 0;
 176 }
 177
 178 sub cmd_update {
 179         print_error "You have not run $0 before. Please do this before trying to update the generated files." unless -f CONFIGURE_CACHE_FILE;
 180         say 'Updating...';
 181         my %config = read_configure_cache();
 182         my %compiler = get_compiler_info($config{CXX});
 183         my %version = get_version();
 184         parse_templates(\%config, \%compiler, \%version);
 185         say 'Update complete!';
 186         exit 0;
 187 }
 188
 189 sub run_test($$;$) {
 190         my ($what, $result, $adjective) = @_;
 191         $adjective //= 'available';
 192         print_format "Checking whether <|GREEN $what|> is $adjective ... ";
 193         print_format $result ? "<|GREEN yes|>\n" : "<|RED no|>\n";
 194         return $result;
 195 }
 196
 197 sub test_file($$;$) {
 198         my ($compiler, $file, $args) = @_;
 199         my $status = 0;
 200         $args //= '';
 201         $status ||= system "$compiler -o __test_$file make/test/$file $args >/dev/null 2>&1";
 202         $status ||= system "./__test_$file >/dev/null 2>&1";
 203         unlink "./__test_$file";
 204         return !$status;
 205 }
 206
 207 sub test_header($$;$) {
 208         my ($compiler, $header, $args) = @_;
 209         $args //= '';
 210         open(COMPILER, "| $compiler -E - $args >/dev/null 2>&1") or return 0;
 211         print COMPILER "#include <$header>";
 212         close(COMPILER);
 213         return !$?;
 214 }
 215
 216 sub read_configure_cache {
 217         my %config;
 218         open(CACHE, CONFIGURE_CACHE_FILE) or return %config;
 219         while (my $line = <CACHE>) {
 220                 next if $line =~ /^\s*($|\#)/;
 221                 my ($key, $value) = ($line =~ /^(\S+)(?:\s(.*))?$/);
 222                 $config{$key} = $value;
 223         }
 224         close(CACHE);
 225         return %config;
 226 }
 227
 228 sub write_configure_cache(%) {
 229         unless (-e CONFIGURE_DIRECTORY) {
 230                 print_format "Creating <|GREEN ${\CONFIGURE_DIRECTORY}|> ...\n";
 231                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 232         }
 233
 234         print_format "Writing <|GREEN ${\CONFIGURE_CACHE_FILE}|> ...\n";
 235         my %config = @_;
 236         open(CACHE, '>', CONFIGURE_CACHE_FILE) or print_error "unable to write ${\CONFIGURE_CACHE_FILE}: $!";
 237         while (my ($key, $value) = each %config) {
 238                 $value //= '';
 239                 say CACHE "$key $value";
 240         }
 241         close(CACHE);
 242 }
 243
 244 sub get_compiler_info($) {
 245         my $binary = shift;
 246         my $version = `$binary -v 2>&1`;
 247         if ($version =~ /Apple\sLLVM\sversion\s(\d+\.\d+)/i) {
 248                 # Apple version their LLVM releases slightly differently to the mainline LLVM.
 249                 # See https://trac.macports.org/wiki/XcodeVersionInfo for more information.
 250                 return (NAME => 'AppleClang', VERSION => $1);
 251         } elsif ($version =~ /clang\sversion\s(\d+\.\d+)/i) {
 252                 return (NAME => 'Clang', VERSION => $1);
 253         } elsif ($version =~ /gcc\sversion\s(\d+\.\d+)/i) {
 254                 return (NAME => 'GCC', VERSION => $1);
 255         } elsif ($version =~ /(?:icc|icpc)\sversion\s(\d+\.\d+).\d+\s\(gcc\sversion\s(\d+\.\d+).\d+/i) {
 256                 return (NAME => 'ICC', VERSION => $1);
 257         }
 258         return (NAME => $binary, VERSION => '0.0');
 259 }
 260
 261 sub find_compiler {
 262         my @compilers = qw(c++ g++ clang++ icpc);
 263         foreach my $compiler (shift // @compilers) {
 264                 return $compiler if __test_compiler $compiler;
 265                 return "xcrun $compiler" if $^O eq 'darwin' && __test_compiler "xcrun $compiler";
 266         }
 267 }
 268
 269 sub parse_templates($$$) {
 270
 271         # These are actually hash references
 272         my ($config, $compiler, $version) = @_;
 273
 274         # Collect settings to be used when generating files
 275         my %settings = __get_template_settings($config, $compiler, $version);
 276
 277         # Iterate through files in make/template.
 278         foreach (<make/template/*>) {
 279                 print_format "Parsing <|GREEN $_|> ...\n";
 280                 open(TEMPLATE, $_) or print_error "unable to read $_: $!";
 281                 my (@lines, $mode, @platforms, %targets);
 282
 283                 # First pass: parse template variables and directives.
 284                 while (my $line = <TEMPLATE>) {
 285                         chomp $line;
 286
 287                         # Does this line match a variable?
 288                         while ($line =~ /(@(\w+?)@)/) {
 289                                 my ($variable, $name) = ($1, $2);
 290                                 if (defined $settings{$name}) {
 291                                         $line =~ s/\Q$variable\E/$settings{$name}/;
 292                                 } else {
 293                                         print_warning "unknown template variable '$name' in $_!";
 294                                         last;
 295                                 }
 296                         }
 297
 298                         # Does this line match a directive?
 299                         if ($line =~ /^\s*%(\w+)\s+(.+)$/) {
 300                                 if ($1 eq 'define') {
 301                                         if ($settings{$2}) {
 302                                                 push @lines, "#define $2";
 303                                         } else {
 304                                                 push @lines, "#undef $2";
 305                                         }
 306                                 } elsif ($1 eq 'mode') {
 307                                         $mode = oct $2;
 308                                 } elsif ($1 eq 'platform') {
 309                                         push @platforms, $2;
 310                                 } elsif ($1 eq 'target') {
 311                                         if ($2 =~ /(\w+)\s(.+)/) {
 312                                                 $targets{$1} = $2;
 313                                         } else {
 314                                                 $targets{DEFAULT} = $2;
 315                                         }
 316                                 } else {
 317                                         print_warning "unknown template command '$1' in $_!";
 318                                         push @lines, $line;
 319                                 }
 320                                 next;
 321                         }
 322                         push @lines, $line;
 323                 }
 324                 close(TEMPLATE);
 325
 326                 # Only proceed if this file should be templated on this platform.
 327                 if ($#platforms < 0 || grep { $_ eq $^O } @platforms) {
 328
 329                         # Add a default target if the template has not defined one.
 330                         unless (scalar keys %targets) {
 331                                 $targets{DEFAULT} = catfile(CONFIGURE_DIRECTORY, basename $_);
 332                         }
 333
 334                         # Second pass: parse makefile junk and write files.
 335                         while (my ($name, $target) = each %targets) {
 336
 337                                 # TODO: when buildtool is done this mess can be removed completely.
 338                                 my @final_lines;
 339                                 foreach my $line (@lines) {
 340
 341                                         # Are we parsing a makefile and does this line match a statement?
 342                                         if ($name =~ /(?:BSD|GNU)_MAKE/ && $line =~ /^\s*\@(\w+)(?:\s+(.+))?$/) {
 343                                                 my @tokens = split /\s/, $2 if defined $2;
 344                                                 if ($1 eq 'DO_EXPORT' && defined $2) {
 345                                                         if ($name eq 'BSD_MAKE') {
 346                                                                 foreach my $variable (@tokens) {
 347                                                                         push @final_lines, "MAKEENV += $variable='\${$variable}'";
 348                                                                 }
 349                                                         } elsif ($name eq 'GNU_MAKE') {
 350                                                                 push @final_lines, "export $2";
 351                                                         }
 352                                                 } elsif ($1 eq 'ELSE') {
 353                                                         if ($name eq 'BSD_MAKE') {
 354                                                                 push @final_lines, ".else";
 355                                                         } elsif ($name eq 'GNU_MAKE') {
 356                                                                 push @final_lines, "else";
 357                                                         }
 358                                                 } elsif ($1 eq 'ENDIF') {
 359                                                         if ($name eq 'BSD_MAKE') {
 360                                                                 push @final_lines, ".endif";
 361                                                         } elsif ($name eq 'GNU_MAKE') {
 362                                                                 push @final_lines, "endif";
 363                                                         }
 364                                                 } elsif ($1 eq 'ELSIFEQ' && defined $2) {
 365                                                         if ($name eq 'BSD_MAKE') {
 366                                                                 push @final_lines, ".elif $tokens[0] == $tokens[1]";
 367                                                         } elsif ($name eq 'GNU_MAKE') {
 368                                                                 push @final_lines, "else ifeq ($tokens[0], $tokens[1])";
 369                                                         }
 370                                                 } elsif ($1 eq 'IFDEF' && defined $2) {
 371                                                         if ($name eq 'BSD_MAKE') {
 372                                                                 push @final_lines, ".if defined($2)";
 373                                                         } elsif ($name eq 'GNU_MAKE') {
 374                                                                 push @final_lines, "ifdef $2";
 375                                                         }
 376                                                 } elsif ($1 eq 'IFEQ' && defined $2) {
 377                                                         if ($name eq 'BSD_MAKE') {
 378                                                                 push @final_lines, ".if $tokens[0] == $tokens[1]";
 379                                                         } elsif ($name eq 'GNU_MAKE') {
 380                                                                 push @final_lines, "ifeq ($tokens[0],$tokens[1])";
 381                                                         }
 382                                                 } elsif ($1 eq 'IFNEQ' && defined $2) {
 383                                                         if ($name eq 'BSD_MAKE') {
 384                                                                 push @final_lines, ".if $tokens[0] != $tokens[1]";
 385                                                         } elsif ($name eq 'GNU_MAKE') {
 386                                                                 push @final_lines, "ifneq ($tokens[0],$tokens[1])";
 387                                                         }
 388                                                 } elsif ($1 eq 'IFNDEF' && defined $2) {
 389                                                         if ($name eq 'BSD_MAKE') {
 390                                                                 push @final_lines, ".if !defined($2)";
 391                                                         } elsif ($name eq 'GNU_MAKE') {
 392                                                                 push @final_lines, "ifndef $2";
 393                                                         }
 394                                                 } elsif ($1 eq 'TARGET' && defined $2) {
 395                                                         if ($tokens[0] eq $name) {
 396                                                                 push @final_lines, substr($2, length($tokens[0]) + 1);
 397                                                         }
 398                                                 } elsif ($1 !~ /[A-Z]/) {
 399                                                         # HACK: silently ignore if lower case as these are probably make commands.
 400                                                         push @final_lines, $line;
 401                                                 } else {
 402                                                         print_warning "unknown template command '$1' in $_!";
 403                                                         push @final_lines, $line;
 404                                                 }
 405                                                 next;
 406                                         }
 407
 408                                         push @final_lines, $line;
 409                                 }
 410
 411                                 # Create the directory if it doesn't already exist.
 412                                 my $directory = dirname $target;
 413                                 unless (-e $directory) {
 414                                         print_format "Creating <|GREEN $directory|> ...\n";
 415                                         create_directory $directory, 0750 or print_error "unable to create $directory: $!";
 416                                 };
 417
 418                                 # Write the template file.
 419                                 print_format "Writing <|GREEN $target|> ...\n";
 420                                 open(TARGET, '>', $target) or print_error "unable to write $target: $!";
 421                                 foreach (@final_lines) {
 422                                         say TARGET $_;
 423                                 }
 424                                 close(TARGET);
 425
 426                                 # Set file permissions.
 427                                 if (defined $mode) {
 428                                         chmod $mode, $target;
 429                                 }
 430                         }
 431                 }
 432         }
 433 }
 434
 435 1;