make/configure.pm

   1 #
   2 # InspIRCd -- Internet Relay Chat Daemon
   3 #
   4 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   5 #   Copyright (C) 2008 Robin Burchell <robin+git@viroteck.net>
   6 #   Copyright (C) 2007-2008 Craig Edwards <craigedwards@brainbox.cc>
   7 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
   8 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
   9 #
  10 # This file is part of InspIRCd.  InspIRCd is free software: you can
  11 # redistribute it and/or modify it under the terms of the GNU General Public
  12 # License as published by the Free Software Foundation, version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but WITHOUT
  15 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  16 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  17 # details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22
  23
  24 BEGIN {
  25         require 5.10.0;
  26 }
  27
  28 package make::configure;
  29
  30 use feature ':5.10';
  31 use strict;
  32 use warnings FATAL => qw(all);
  33
  34 use Cwd                   qw(getcwd);
  35 use Exporter              qw(import);
  36 use File::Basename        qw(basename dirname);
  37 use File::Spec::Functions qw(catfile);
  38
  39 use make::common;
  40 use make::console;
  41
  42 use constant CONFIGURE_DIRECTORY     => '.configure';
  43 use constant CONFIGURE_CACHE_FILE    => catfile(CONFIGURE_DIRECTORY, 'cache.cfg');
  44 use constant CONFIGURE_CACHE_VERSION => '1';
  45 use constant CONFIGURE_ERROR_PIPE    => $ENV{INSPIRCD_VERBOSE} ? '' : '1>/dev/null 2>/dev/null';
  46
  47 our @EXPORT = qw(CONFIGURE_CACHE_FILE
  48                  CONFIGURE_CACHE_VERSION
  49                  cmd_clean
  50                  cmd_help
  51                  cmd_update
  52                  run_test
  53                  test_file
  54                  test_header
  55                  write_configure_cache
  56                  get_compiler_info
  57                  find_compiler
  58                  parse_templates);
  59
  60 sub __get_socketengines {
  61         my @socketengines;
  62         foreach (<src/socketengines/socketengine_*.cpp>) {
  63                 s/src\/socketengines\/socketengine_(\w+)\.cpp/$1/;
  64                 push @socketengines, $1;
  65         }
  66         return @socketengines;
  67 }
  68
  69 # TODO: when buildtool is done this can be mostly removed with
  70 #       the remainder being merged into parse_templates.
  71 sub __get_template_settings($$$) {
  72
  73         # These are actually hash references
  74         my ($config, $compiler, $version) = @_;
  75
  76         # Start off by populating with the config
  77         my %settings = %$config;
  78
  79         # Compiler information
  80         while (my ($key, $value) = each %{$compiler}) {
  81                 $settings{'COMPILER_' . $key} = $value;
  82         }
  83
  84         # Version information
  85         while (my ($key, $value) = each %{$version}) {
  86                 $settings{'VERSION_' . $key} = $value;
  87         }
  88
  89         # Miscellaneous information
  90         $settings{CONFIGURE_DIRECTORY} = CONFIGURE_DIRECTORY;
  91         $settings{CONFIGURE_CACHE_FILE} = CONFIGURE_CACHE_FILE;
  92         $settings{SYSTEM_NAME} = lc $^O;
  93
  94         return %settings;
  95 }
  96
  97 sub __test_compiler($) {
  98         my $compiler = shift;
  99         return 0 unless run_test("`$compiler`", !system "$compiler -v ${\CONFIGURE_ERROR_PIPE}");
 100         return 0 unless run_test("`$compiler`", test_file($compiler, 'compiler.cpp', '-fno-rtti'), 'compatible');
 101         return 1;
 102 }
 103
 104 sub cmd_clean {
 105         unlink CONFIGURE_CACHE_FILE;
 106 }
 107
 108 sub cmd_help {
 109         my $PWD = getcwd();
 110         my $SELIST = join ', ', __get_socketengines();
 111         print <<EOH;
 112 Usage: $0 [options]
 113
 114 When no options are specified, configure runs in interactive mode and you must
 115 specify any required values manually. If one or more options are specified,
 116 non-interactive configuration is started and any omitted values are defaulted.
 117
 118 PATH OPTIONS
 119
 120   --system                      Automatically set up the installation paths
 121                                 for system-wide installation.
 122   --prefix=[dir]                The root install directory. If this is set then
 123                                 all subdirectories will be adjusted accordingly.
 124                                 [$PWD/run]
 125   --binary-dir=[dir]            The location where the main server binary is
 126                                 stored.
 127                                 [$PWD/run/bin]
 128   --config-dir=[dir]            The location where the configuration files and
 129                                 SSL certificates are stored.
 130                                 [$PWD/run/conf]
 131   --data-dir=[dir]              The location where the data files, such as the
 132                                 pid file, are stored.
 133                                 [$PWD/run/data]
 134   --log-dir=[dir]               The location where the log files are stored.
 135                                 [$PWD/run/logs]
 136   --manual-dir=[dir]            The location where the manual files are stored.
 137                                 [$PWD/run/manuals]
 138   --module-dir=[dir]            The location where the loadable modules are
 139                                 stored.
 140                                 [$PWD/run/modules]
 141   --script-dir=[dir]            The location where the scripts, such as the
 142                                 init scripts, are stored.
 143                                 [$PWD/run]
 144
 145 EXTRA MODULE OPTIONS
 146
 147   --enable-extras=[extras]      Enables a comma separated list of extra modules.
 148   --disable-extras=[extras]     Disables a comma separated list of extra modules.
 149   --list-extras                 Shows the availability status of all extra
 150                                 modules.
 151
 152 MISC OPTIONS
 153
 154   --clean                       Remove the configuration cache file and start
 155                                 the interactive configuration wizard.
 156   --disable-interactive         Disables the interactive configuration wizard.
 157   --distribution-label=[text]   Sets a distribution specific version label in
 158                                 the build configuration.
 159   --gid=[id|name]               Sets the group to run InspIRCd as.
 160   --help                        Show this message and exit.
 161   --socketengine=[name]         Sets the socket engine to be used. Possible
 162                                 values are $SELIST.
 163   --uid=[id|name]               Sets the user to run InspIRCd as.
 164   --update                      Updates the build environment with the settings
 165                                 from the cache.
 166
 167
 168 FLAGS
 169
 170   CXX=[name]                    Sets the C++ compiler to use when building the
 171                                 server. If not specified then the build system
 172                                 will search for c++, g++, clang++ or icpc.
 173
 174 If you have any problems with configuring InspIRCd then visit our IRC channel
 175 at irc.inspircd.org #InspIRCd for support.
 176
 177 EOH
 178         exit 0;
 179 }
 180
 181 sub cmd_update {
 182         print_error "You have not run $0 before. Please do this before trying to update the generated files." unless -f CONFIGURE_CACHE_FILE;
 183         say 'Updating...';
 184         my %config = read_config_file(CONFIGURE_CACHE_FILE);
 185         my %compiler = get_compiler_info($config{CXX});
 186         my %version = get_version $config{DISTRIBUTION};
 187         parse_templates(\%config, \%compiler, \%version);
 188         say 'Update complete!';
 189         exit 0;
 190 }
 191
 192 sub run_test($$;$) {
 193         my ($what, $result, $adjective) = @_;
 194         $adjective //= 'available';
 195         print_format "Checking whether <|GREEN $what|> is $adjective ... ";
 196         print_format $result ? "<|GREEN yes|>\n" : "<|RED no|>\n";
 197         return $result;
 198 }
 199
 200 sub test_file($$;$) {
 201         my ($compiler, $file, $args) = @_;
 202         my $status = 0;
 203         $args //= '';
 204         $status ||= system "$compiler -o __test_$file make/test/$file $args ${\CONFIGURE_ERROR_PIPE}";
 205         $status ||= system "./__test_$file ${\CONFIGURE_ERROR_PIPE}";
 206         unlink "./__test_$file";
 207         return !$status;
 208 }
 209
 210 sub test_header($$;$) {
 211         my ($compiler, $header, $args) = @_;
 212         $args //= '';
 213         open(my $fh, "| $compiler -E - $args ${\CONFIGURE_ERROR_PIPE}") or return 0;
 214         print $fh "#include <$header>";
 215         close $fh;
 216         return !$?;
 217 }
 218
 219 sub write_configure_cache(%) {
 220         unless (-e CONFIGURE_DIRECTORY) {
 221                 print_format "Creating <|GREEN ${\CONFIGURE_DIRECTORY}|> ...\n";
 222                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 223         }
 224
 225         print_format "Writing <|GREEN ${\CONFIGURE_CACHE_FILE}|> ...\n";
 226         my %config = @_;
 227         write_config_file CONFIGURE_CACHE_FILE, %config;
 228 }
 229
 230 sub get_compiler_info($) {
 231         my $binary = shift;
 232         my %info = (NAME => 'Unknown', VERSION => '0.0');
 233         return %info if system "$binary -o __compiler_info make/test/compiler_info.cpp ${\CONFIGURE_ERROR_PIPE}";
 234         open(my $fh, '-|', './__compiler_info 2>/dev/null');
 235         while (my $line = <$fh>) {
 236                 $info{$1} = $2 if $line =~ /^([A-Z]+)\s(.+)$/;
 237         }
 238         close $fh;
 239         unlink './__compiler_info';
 240         return %info;
 241 }
 242
 243 sub find_compiler {
 244         my @compilers = qw(c++ g++ clang++ icpc);
 245         foreach my $compiler (shift // @compilers) {
 246                 return $compiler if __test_compiler $compiler;
 247                 return "xcrun $compiler" if $^O eq 'darwin' && __test_compiler "xcrun $compiler";
 248         }
 249 }
 250
 251 sub parse_templates($$$) {
 252
 253         # These are actually hash references
 254         my ($config, $compiler, $version) = @_;
 255
 256         # Collect settings to be used when generating files
 257         my %settings = __get_template_settings($config, $compiler, $version);
 258
 259         # Iterate through files in make/template.
 260         foreach (<make/template/*>) {
 261                 print_format "Parsing <|GREEN $_|> ...\n";
 262                 open(my $fh, $_) or print_error "unable to read $_: $!";
 263                 my (@lines, $mode, @platforms, @targets);
 264
 265                 # First pass: parse template variables and directives.
 266                 while (my $line = <$fh>) {
 267                         chomp $line;
 268
 269                         # Does this line match a variable?
 270                         while ($line =~ /(@(\w+?)@)/) {
 271                                 my ($variable, $name) = ($1, $2);
 272                                 if (defined $settings{$name}) {
 273                                         $line =~ s/\Q$variable\E/$settings{$name}/;
 274                                 } else {
 275                                         print_warning "unknown template variable '$name' in $_!";
 276                                         last;
 277                                 }
 278                         }
 279
 280                         # Does this line match a directive?
 281                         if ($line =~ /^\s*%(\w+)\s+(.+)$/) {
 282                                 if ($1 eq 'define') {
 283                                         if ($settings{$2}) {
 284                                                 push @lines, "#define $2";
 285                                         } else {
 286                                                 push @lines, "#undef $2";
 287                                         }
 288                                 } elsif ($1 eq 'mode') {
 289                                         $mode = oct $2;
 290                                 } elsif ($1 eq 'platform') {
 291                                         push @platforms, $2;
 292                                 } elsif ($1 eq 'target') {
 293                                         push @targets, $2
 294                                 } else {
 295                                         print_warning "unknown template command '$1' in $_!";
 296                                         push @lines, $line;
 297                                 }
 298                                 next;
 299                         }
 300                         push @lines, $line;
 301                 }
 302                 close $fh;
 303
 304                 # Only proceed if this file should be templated on this platform.
 305                 if ($#platforms < 0 || grep { $_ eq $^O } @platforms) {
 306
 307                         # Add a default target if the template has not defined one.
 308                         unless (@targets) {
 309                                 push @targets, catfile(CONFIGURE_DIRECTORY, basename $_);
 310                         }
 311
 312                         # Write the templated files to disk.
 313                         for my $target (@targets) {
 314
 315                                 # Create the directory if it doesn't already exist.
 316                                 my $directory = dirname $target;
 317                                 unless (-e $directory) {
 318                                         print_format "Creating <|GREEN $directory|> ...\n";
 319                                         create_directory $directory, 0750 or print_error "unable to create $directory: $!";
 320                                 };
 321
 322                                 # Write the template file.
 323                                 print_format "Writing <|GREEN $target|> ...\n";
 324                                 open(my $fh, '>', $target) or print_error "unable to write $target: $!";
 325                                 foreach (@lines) {
 326                                         say $fh $_;
 327                                 }
 328                                 close $fh;
 329
 330                                 # Set file permissions.
 331                                 if (defined $mode) {
 332                                         chmod $mode, $target;
 333                                 }
 334                         }
 335                 }
 336         }
 337 }
 338
 339 1;