modulemanager

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings FATAL => qw(all);
   4 use LWP::Simple;
   5
   6 use make::configure;
   7
   8 our @modlist;
   9
  10 my %installed;
  11 # $installed{name} = $version
  12
  13 my %modules;
  14 # $modules{$name}{$version} = {
  15 #       url => URL of this version
  16 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  17 #       conflicts => [ ]
  18 #       from => URL of source document
  19 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  20 #       description => some string
  21 # }
  22
  23 my %url_seen;
  24
  25 sub parse_url;
  26
  27 # retrieve and parse entries from sources.list
  28 sub parse_url {
  29         my $src = shift;
  30         return if $url_seen{$src};
  31         $url_seen{$src}++;
  32
  33         my $doc = get($src);
  34         die "Could not retrieve $_" unless defined $doc;
  35
  36         my $mod;
  37         for (split /\n+/, $doc) {
  38                 s/^\s+//; # ignore whitespace at start
  39                 next if /^#/;
  40                 if (/^module (\S+) (\S+) (\S+)/) {
  41                         my($name, $ver, $url) = ($1,$2,$3);
  42                         if ($modules{$name}{$ver}) {
  43                                 my $origsrc = $modules{$name}{$ver}{from};
  44                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  45                         }
  46                         $mod = {
  47                                 from => $src,
  48                                 url => $url,
  49                                 depends => [],
  50                                 conflicts => [],
  51                         };
  52                         $modules{$name}{$ver} = $mod;
  53                 } elsif (/^depends (.*)/) {
  54                         push @{$mod->{depends}}, $1;
  55                 } elsif (/^conflicts (.*)/) {
  56                         push @{$mod->{conflicts}}, $1;
  57                 } elsif (/^description (.*)/) {
  58                         $mod->{description} = $1;
  59                 } elsif (/^mask (.*)/) {
  60                         $mod->{mask} = $1;
  61                 } elsif (m#^source (http://\S+)#) {
  62                         parse_url $1;
  63                 } else {
  64                         print "Unknown line in $src: $_\n";
  65                 }
  66         }
  67 }
  68
  69 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
  70 my %mod_versions;
  71
  72 # useless helper stub
  73 sub getmodversion {
  74         my ($file) = @_;
  75         return $mod_versions{$file};
  76 }
  77
  78 # read in installed versions
  79 if (-e '.modulemanager')
  80 {
  81         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
  82         while (<SRC>)
  83         {
  84                 s/\n//;
  85                 (my $mod, my $ver) = split(/ /, $_);
  86                 $mod_versions{$mod} = $ver;
  87         }
  88         close SRC;
  89 }
  90
  91 # read in external URL sources
  92 open SRC, 'sources.list' or die "Could not open sources.list: $!";
  93 while (<SRC>) {
  94         next if /^\s*#/;
  95         parse_url($_);
  96 }
  97 close SRC;
  98
  99 getmodules(1);
 100
 101 # determine core version
 102 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 103 $installed{core} = $1;
 104 for my $mod (keys %modules) {
 105         MODVER: for my $mver (keys %{$modules{$mod}}) {
 106                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 107                         next unless $dep =~ /^core (.*)/;
 108                         if (!ver_in_range($installed{core}, $1)) {
 109                                 delete $modules{$mod}{$mver};
 110                                 next MODVER;
 111                         }
 112                 }
 113         }
 114         delete $modules{$mod} unless %{$modules{$mod}};
 115 }
 116 $modules{core}{$1} = {
 117         url => 'NONE',
 118         depends => [],
 119         conflicts => [],
 120         from => 'local file',
 121 };
 122
 123 # set up core module list
 124 for my $modname (@modlist) {
 125         my $mod = "m_$modname";
 126         my $modfile = "src/modules/$mod.cpp";
 127         my $ver = getmodversion($mod) || '0.0';
 128         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 129         $installed{$mod} = $ver;
 130         next if $modules{$mod}{$ver};
 131         $modules{$mod}{$ver} = {
 132                 url => 'NONE',
 133                 depends => [],
 134                 conflicts => [],
 135                 from => 'local file',
 136         };
 137 }
 138
 139 my %todo = %installed;
 140
 141 sub ver_cmp {
 142         ($a,$b) = @_ if @_;
 143
 144         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 145         {
 146                 # not a valid version number, don't try to sort
 147                 return $a ne $b;
 148         }
 149
 150         # else it's probably a numerical type version.. i.e. 1.0
 151         my @a = split /\./, $a;
 152         my @b = split /\./, $b;
 153         push @a, 0 while $#a < $#b;
 154         push @b, ($_[2] || 0) while $#b < $#a;
 155         for my $i (0..$#a) {
 156                 my $d = $a[$i] <=> $b[$i];
 157                 return $d if $d;
 158         }
 159         return 0;
 160 }
 161
 162 sub ver_in_range {
 163         my($ver, $range) = @_;
 164         return 1 unless defined $range;
 165         my($l,$h) = ($range, $range);
 166         if ($range =~ /(.*)-(.*)/) {
 167                 ($l,$h) = ($1,$2);
 168         }
 169         return 0 if $l && ver_cmp($ver, $l) < 0;
 170         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 171         return 1;
 172 }
 173
 174 sub find_mod_in_range {
 175         my($mod, $vers, $force) = @_;
 176         my @versions = keys %{$modules{$mod}};
 177         @versions = sort { -ver_cmp() } @versions;
 178         for my $ver (@versions) {
 179                 next if $modules{$mod}{$ver}{mask} && !$force;
 180                 return $ver if ver_in_range($ver, $vers);
 181         }
 182         return undef;
 183 }
 184
 185 sub resolve_deps {
 186         my($trial) = @_;
 187         my $tries = 100;
 188         my $changes = 'INIT';
 189         my $fail = undef;
 190         while ($changes && $tries) {
 191                 $tries--;
 192                 $changes = '';
 193                 $fail = undef;
 194                 my @modsnow = sort keys %todo;
 195                 for my $mod (@modsnow) {
 196                         my $ver = $todo{$mod};
 197                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 198                         for my $dep (@{$info->{depends}}) {
 199                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 200                                 my($depmod, $depvers) = ($1,$2);
 201                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 202                                 # need to install a dependency
 203                                 my $depver = find_mod_in_range($depmod, $depvers);
 204                                 if (defined $depver) {
 205                                         $todo{$depmod} = $depver;
 206                                         $changes .= " $mod-$ver->$depmod-$depver";
 207                                 } else {
 208                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 209                                 }
 210                         }
 211                         for my $dep (@{$info->{conflicts}}) {
 212                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 213                                 my($depmod, $depvers) = ($1,$2);
 214                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 215                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 216                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 217                         }
 218                 }
 219         }
 220         if ($trial) {
 221                 return !($changes || $fail);
 222         }
 223         if ($changes) {
 224                 print "Infinite dependency loop:$changes\n";
 225                 exit 1;
 226         }
 227         if ($fail) {
 228                 print "$fail\n";
 229                 exit 1;
 230         }
 231 }
 232
 233 my $action = lc shift @ARGV;
 234
 235 if ($action eq 'install') {
 236         for my $mod (@ARGV) {
 237                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 238                 $mod = lc $mod;
 239                 unless ($modules{$mod}) {
 240                         print "Cannot find module $mod\n";
 241                         exit 1;
 242                 }
 243                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 244                 unless ($ver) {
 245                         print "Cannot find suitable version of $mod\n";
 246                         exit 1;
 247                 }
 248                 $todo{$mod} = $ver;
 249         }
 250 } elsif ($action eq 'upgrade') {
 251         my @installed = sort keys %installed;
 252         for my $mod (@installed) {
 253                 next unless $mod =~ /^m_/;
 254                 my %saved = %todo;
 255                 $todo{$mod} = find_mod_in_range($mod);
 256                 if (!resolve_deps(1)) {
 257                         %todo = %saved;
 258                 }
 259         }
 260 } elsif ($action eq 'list') {
 261         my @all = sort keys %modules;
 262         for my $mod (@all) {
 263                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 264                 my $desc = '';
 265                 for my $ver (@vers) {
 266                         # latest defined description wins
 267                         $desc = $modules{$mod}{$ver}{description} || $desc;
 268                 }
 269                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 270                 my $instver = $installed{$mod} || '';
 271                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 272                 print "$mod ($vers) - $desc\n";
 273         }
 274 } else {
 275         print <<ENDUSAGE
 276 Use: $0 <action> <args>
 277 Action is one of the following
 278  install   install new modules
 279  upgrade   upgrade installed modules
 280  list      lists available modules
 281
 282 For installing a package, specify its name or name=version to force the
 283 installation of a specific version.
 284 ENDUSAGE
 285 ;exit 1;
 286 }
 287
 288 resolve_deps(0);
 289
 290 $| = 1; # immediate print of lines without \n
 291
 292 print "Processing changes for $action...\n";
 293 for my $mod (keys %installed) {
 294         next if $todo{$mod};
 295         print "Uninstalling $mod $installed{$mod}\n";
 296         unlink "src/modules/$mod.cpp";
 297 }
 298
 299 my $count = scalar keys %todo;
 300 print "Checking $count items...\n";
 301 for my $mod (sort keys %todo) {
 302         my $ver = $todo{$mod};
 303         my $oldver = $installed{$mod};
 304         if ($modules{$mod}{$ver}{mask}) {
 305                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 306         }
 307         next if $oldver && $oldver eq $ver;
 308         my $url = $modules{$mod}{$ver}{url};
 309         if ($oldver) {
 310                 print "Upgrading $mod from $oldver to $ver using $url"
 311         } else {
 312                 print "Installing $mod $ver from $url";
 313         }
 314         $mod_versions{$mod} = $ver;
 315
 316         my $stat = getstore($url, "src/modules/$mod.cpp");
 317         if ($stat == 200) {
 318                 print " - done\n";
 319         } else {
 320                 print " - HTTP $stat\n";
 321         }
 322 }
 323
 324 # write database of installed versions
 325 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 326 foreach my $key (keys %mod_versions)
 327 {
 328         print SRC "$key $mod_versions{$key}\n";
 329 }
 330 close SRC;
 331
 332 print "Finished!\n";