modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   7 #
   8 # This file is part of InspIRCd.  InspIRCd is free software: you can
   9 # redistribute it and/or modify it under the terms of the GNU General Public
  10 # License as published by the Free Software Foundation, version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21
  22 use strict;
  23 use warnings FATAL => qw(all);
  24
  25 use make::configure;
  26
  27 BEGIN {
  28         unless (module_installed("LWP::Simple")) {
  29                 die "Your system is missing the LWP::Simple Perl module!";
  30         }
  31         unless (module_installed("Crypt::SSLeay") || module_installed("IO::Socket::SSL")) {
  32                 die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  33         }
  34 }
  35
  36 use LWP::Simple;
  37
  38 our @modlist;
  39
  40 my %installed;
  41 # $installed{name} = $version
  42
  43 my %modules;
  44 # $modules{$name}{$version} = {
  45 #       url => URL of this version
  46 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  47 #       conflicts => [ ]
  48 #       from => URL of source document
  49 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  50 #       description => some string
  51 # }
  52
  53 my %url_seen;
  54
  55 sub parse_url;
  56
  57 # retrieve and parse entries from sources.list
  58 sub parse_url {
  59         chomp(my $src = shift);
  60         return if $url_seen{$src};
  61         $url_seen{$src}++;
  62
  63         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
  64         my $response = $ua->get($src);
  65
  66         unless ($response->is_success) {
  67                 my $err = $response->message;
  68                 die "Could not retrieve $src: $err";
  69         }
  70
  71         my $mod;
  72         for (split /\n+/, $response->decoded_content) {
  73                 s/^\s+//; # ignore whitespace at start
  74                 next if /^#/;
  75                 if (/^module (\S+) (\S+) (\S+)/) {
  76                         my($name, $ver, $url) = ($1,$2,$3);
  77                         if ($modules{$name}{$ver}) {
  78                                 my $origsrc = $modules{$name}{$ver}{from};
  79                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  80                         }
  81                         $mod = {
  82                                 from => $src,
  83                                 url => $url,
  84                                 depends => [],
  85                                 conflicts => [],
  86                         };
  87                         $modules{$name}{$ver} = $mod;
  88                 } elsif (/^depends (.*)/) {
  89                         push @{$mod->{depends}}, $1;
  90                 } elsif (/^conflicts (.*)/) {
  91                         push @{$mod->{conflicts}}, $1;
  92                 } elsif (/^description (.*)/) {
  93                         $mod->{description} = $1;
  94                 } elsif (/^mask (.*)/) {
  95                         $mod->{mask} = $1;
  96                 } elsif (m#^source (http://\S+)#) {
  97                         parse_url $1;
  98                 } else {
  99                         print "Unknown line in $src: $_\n";
 100                 }
 101         }
 102 }
 103
 104 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 105 my %mod_versions;
 106
 107 # useless helper stub
 108 sub getmodversion {
 109         my ($file) = @_;
 110         return $mod_versions{$file};
 111 }
 112
 113 # read in installed versions
 114 if (-e '.modulemanager')
 115 {
 116         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
 117         while (<SRC>)
 118         {
 119                 s/\n//;
 120                 (my $mod, my $ver) = split(/ /, $_);
 121                 $mod_versions{$mod} = $ver;
 122         }
 123         close SRC;
 124 }
 125
 126 # read in external URL sources
 127 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 128 while (<SRC>) {
 129         next if /^\s*#/;
 130         parse_url($_);
 131 }
 132 close SRC;
 133
 134 getmodules(1);
 135
 136 # determine core version
 137 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 138 $installed{core} = $1;
 139 for my $mod (keys %modules) {
 140         MODVER: for my $mver (keys %{$modules{$mod}}) {
 141                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 142                         next unless $dep =~ /^core (.*)/;
 143                         if (!ver_in_range($installed{core}, $1)) {
 144                                 delete $modules{$mod}{$mver};
 145                                 next MODVER;
 146                         }
 147                 }
 148         }
 149         delete $modules{$mod} unless %{$modules{$mod}};
 150 }
 151 $modules{core}{$1} = {
 152         url => 'NONE',
 153         depends => [],
 154         conflicts => [],
 155         from => 'local file',
 156 };
 157
 158 # set up core module list
 159 for my $modname (@modlist) {
 160         my $mod = "m_$modname";
 161         my $modfile = "src/modules/$mod.cpp";
 162         my $ver = getmodversion($mod) || '0.0';
 163         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 164         $installed{$mod} = $ver;
 165         next if $modules{$mod}{$ver};
 166         $modules{$mod}{$ver} = {
 167                 url => 'NONE',
 168                 depends => [],
 169                 conflicts => [],
 170                 from => 'local file',
 171         };
 172 }
 173
 174 my %todo = %installed;
 175
 176 sub ver_cmp {
 177         ($a,$b) = @_ if @_;
 178
 179         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 180         {
 181                 # not a valid version number, don't try to sort
 182                 return $a ne $b;
 183         }
 184
 185         # else it's probably a numerical type version.. i.e. 1.0
 186         my @a = split /\./, $a;
 187         my @b = split /\./, $b;
 188         push @a, 0 while $#a < $#b;
 189         push @b, ($_[2] || 0) while $#b < $#a;
 190         for my $i (0..$#a) {
 191                 my $d = $a[$i] <=> $b[$i];
 192                 return $d if $d;
 193         }
 194         return 0;
 195 }
 196
 197 sub ver_in_range {
 198         my($ver, $range) = @_;
 199         return 1 unless defined $range;
 200         my($l,$h) = ($range, $range);
 201         if ($range =~ /(.*)-(.*)/) {
 202                 ($l,$h) = ($1,$2);
 203         }
 204         return 0 if $l && ver_cmp($ver, $l) < 0;
 205         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 206         return 1;
 207 }
 208
 209 sub find_mod_in_range {
 210         my($mod, $vers, $force) = @_;
 211         my @versions = keys %{$modules{$mod}};
 212         @versions = sort { -ver_cmp() } @versions;
 213         for my $ver (@versions) {
 214                 next if $modules{$mod}{$ver}{mask} && !$force;
 215                 return $ver if ver_in_range($ver, $vers);
 216         }
 217         return undef;
 218 }
 219
 220 sub resolve_deps {
 221         my($trial) = @_;
 222         my $tries = 100;
 223         my $changes = 'INIT';
 224         my $fail = undef;
 225         while ($changes && $tries) {
 226                 $tries--;
 227                 $changes = '';
 228                 $fail = undef;
 229                 my @modsnow = sort keys %todo;
 230                 for my $mod (@modsnow) {
 231                         my $ver = $todo{$mod};
 232                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 233                         for my $dep (@{$info->{depends}}) {
 234                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 235                                 my($depmod, $depvers) = ($1,$2);
 236                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 237                                 # need to install a dependency
 238                                 my $depver = find_mod_in_range($depmod, $depvers);
 239                                 if (defined $depver) {
 240                                         $todo{$depmod} = $depver;
 241                                         $changes .= " $mod-$ver->$depmod-$depver";
 242                                 } else {
 243                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 244                                 }
 245                         }
 246                         for my $dep (@{$info->{conflicts}}) {
 247                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 248                                 my($depmod, $depvers) = ($1,$2);
 249                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 250                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 251                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 252                         }
 253                 }
 254         }
 255         if ($trial) {
 256                 return !($changes || $fail);
 257         }
 258         if ($changes) {
 259                 print "Infinite dependency loop:$changes\n";
 260                 exit 1;
 261         }
 262         if ($fail) {
 263                 print "$fail\n";
 264                 exit 1;
 265         }
 266 }
 267
 268 my $action = $#ARGV >= 0 ? lc shift @ARGV : 'help';
 269
 270 if ($action eq 'install') {
 271         for my $mod (@ARGV) {
 272                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 273                 $mod = lc $mod;
 274                 unless ($modules{$mod}) {
 275                         print "Cannot find module $mod\n";
 276                         exit 1;
 277                 }
 278                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 279                 unless ($ver) {
 280                         print "Cannot find suitable version of $mod\n";
 281                         exit 1;
 282                 }
 283                 $todo{$mod} = $ver;
 284         }
 285 } elsif ($action eq 'upgrade') {
 286         my @installed = sort keys %installed;
 287         for my $mod (@installed) {
 288                 next unless $mod =~ /^m_/;
 289                 my %saved = %todo;
 290                 $todo{$mod} = find_mod_in_range($mod);
 291                 if (!resolve_deps(1)) {
 292                         %todo = %saved;
 293                 }
 294         }
 295 } elsif ($action eq 'list') {
 296         my @all = sort keys %modules;
 297         for my $mod (@all) {
 298                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 299                 my $desc = '';
 300                 for my $ver (@vers) {
 301                         # latest defined description wins
 302                         $desc = $modules{$mod}{$ver}{description} || $desc;
 303                 }
 304                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 305                 my $instver = $installed{$mod} || '';
 306                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 307                 print "$mod ($vers) - $desc\n";
 308         }
 309 } else {
 310         print <<ENDUSAGE
 311 Use: $0 <action> <args>
 312 Action is one of the following
 313  install   install new modules
 314  upgrade   upgrade installed modules
 315  list      lists available modules
 316
 317 For installing a package, specify its name or name=version to force the
 318 installation of a specific version.
 319 ENDUSAGE
 320 ;exit 1;
 321 }
 322
 323 resolve_deps(0);
 324
 325 $| = 1; # immediate print of lines without \n
 326
 327 print "Processing changes for $action...\n";
 328 for my $mod (keys %installed) {
 329         next if $todo{$mod};
 330         print "Uninstalling $mod $installed{$mod}\n";
 331         unlink "src/modules/$mod.cpp";
 332 }
 333
 334 my $count = scalar keys %todo;
 335 print "Checking $count items...\n";
 336 for my $mod (sort keys %todo) {
 337         my $ver = $todo{$mod};
 338         my $oldver = $installed{$mod};
 339         if ($modules{$mod}{$ver}{mask}) {
 340                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 341         }
 342         next if $oldver && $oldver eq $ver;
 343         my $url = $modules{$mod}{$ver}{url};
 344         if ($oldver) {
 345                 print "Upgrading $mod from $oldver to $ver using $url"
 346         } else {
 347                 print "Installing $mod $ver from $url";
 348         }
 349         $mod_versions{$mod} = $ver;
 350
 351         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
 352         my $response = $ua->get($url);
 353
 354         if ($response->is_success) {
 355                 open(MF, ">src/modules/$mod.cpp") or die "\nFilesystem not writable: $!";
 356                 print MF $response->decoded_content;
 357                 close(MF);
 358                 print " - done\n";
 359         } else {
 360                 printf "\nHTTP %s: %s\n", $response->code, $response->message;
 361         }
 362 }
 363
 364 # write database of installed versions
 365 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 366 foreach my $key (keys %mod_versions)
 367 {
 368         print SRC "$key $mod_versions{$key}\n";
 369 }
 370 close SRC;
 371
 372 print "Finished!\n";