modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   7 #
   8 # This file is part of InspIRCd.  InspIRCd is free software: you can
   9 # redistribute it and/or modify it under the terms of the GNU General Public
  10 # License as published by the Free Software Foundation, version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21
  22 use strict;
  23 use warnings FATAL => qw(all);
  24
  25 use make::utilities;
  26
  27 if (!module_installed("LWP::Simple"))
  28 {
  29         die "Your system is missing the LWP::Simple Perl module!";
  30 }
  31
  32 if (!module_installed("Crypt::SSLeay") && !module_installed("IO::Socket::SSL"))
  33 {
  34         die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  35 }
  36
  37 use File::Basename;
  38 use LWP::Simple;
  39
  40 my %installed;
  41 # $installed{name} = $version
  42
  43 my %modules;
  44 # $modules{$name}{$version} = {
  45 #       url => URL of this version
  46 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  47 #       conflicts => [ ]
  48 #       from => URL of source document
  49 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  50 #       description => some string
  51 # }
  52
  53 my %url_seen;
  54
  55 sub parse_url;
  56
  57 # retrieve and parse entries from sources.list
  58 sub parse_url {
  59         my $src = shift;
  60         return if $url_seen{$src};
  61         $url_seen{$src}++;
  62
  63         my $doc = get($src);
  64         die "Could not retrieve $_" unless defined $doc;
  65
  66         my $mod;
  67         for (split /\n+/, $doc) {
  68                 s/^\s+//; # ignore whitespace at start
  69                 next if /^#/;
  70                 if (/^module (\S+) (\S+) (\S+)/) {
  71                         my($name, $ver, $url) = ($1,$2,$3);
  72                         if ($modules{$name}{$ver}) {
  73                                 my $origsrc = $modules{$name}{$ver}{from};
  74                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  75                         }
  76                         $mod = {
  77                                 from => $src,
  78                                 url => $url,
  79                                 depends => [],
  80                                 conflicts => [],
  81                         };
  82                         $modules{$name}{$ver} = $mod;
  83                 } elsif (/^depends (.*)/) {
  84                         push @{$mod->{depends}}, $1;
  85                 } elsif (/^conflicts (.*)/) {
  86                         push @{$mod->{conflicts}}, $1;
  87                 } elsif (/^description (.*)/) {
  88                         $mod->{description} = $1;
  89                 } elsif (/^mask (.*)/) {
  90                         $mod->{mask} = $1;
  91                 } elsif (m#^source (http://\S+)#) {
  92                         parse_url $1;
  93                 } else {
  94                         print "Unknown line in $src: $_\n";
  95                 }
  96         }
  97 }
  98
  99 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 100 my %mod_versions;
 101
 102 # useless helper stub
 103 sub getmodversion {
 104         my ($file) = @_;
 105         return $mod_versions{$file};
 106 }
 107
 108 # read in installed versions
 109 if (-e '.modulemanager')
 110 {
 111         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
 112         while (<SRC>)
 113         {
 114                 s/\n//;
 115                 (my $mod, my $ver) = split(/ /, $_);
 116                 $mod_versions{$mod} = $ver;
 117         }
 118         close SRC;
 119 }
 120
 121 # read in external URL sources
 122 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 123 while (<SRC>) {
 124         next if /^\s*#/;
 125         parse_url($_);
 126 }
 127 close SRC;
 128
 129 # determine core version
 130 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 131 $installed{core} = $1;
 132 for my $mod (keys %modules) {
 133         MODVER: for my $mver (keys %{$modules{$mod}}) {
 134                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 135                         next unless $dep =~ /^core (.*)/;
 136                         if (!ver_in_range($installed{core}, $1)) {
 137                                 delete $modules{$mod}{$mver};
 138                                 next MODVER;
 139                         }
 140                 }
 141         }
 142         delete $modules{$mod} unless %{$modules{$mod}};
 143 }
 144 $modules{core}{$1} = {
 145         url => 'NONE',
 146         depends => [],
 147         conflicts => [],
 148         from => 'local file',
 149 };
 150
 151 # set up core module list
 152 for my $modname (<src/modules/m_*.cpp>) {
 153         my $mod = basename($modname, '.cpp');
 154         my $ver = getmodversion($mod) || '0.0';
 155         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 156         $installed{$mod} = $ver;
 157         next if $modules{$mod}{$ver};
 158         $modules{$mod}{$ver} = {
 159                 url => 'NONE',
 160                 depends => [],
 161                 conflicts => [],
 162                 from => 'local file',
 163         };
 164 }
 165
 166 my %todo = %installed;
 167
 168 sub ver_cmp {
 169         ($a,$b) = @_ if @_;
 170
 171         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 172         {
 173                 # not a valid version number, don't try to sort
 174                 return $a ne $b;
 175         }
 176
 177         # else it's probably a numerical type version.. i.e. 1.0
 178         my @a = split /\./, $a;
 179         my @b = split /\./, $b;
 180         push @a, 0 while $#a < $#b;
 181         push @b, ($_[2] || 0) while $#b < $#a;
 182         for my $i (0..$#a) {
 183                 my $d = $a[$i] <=> $b[$i];
 184                 return $d if $d;
 185         }
 186         return 0;
 187 }
 188
 189 sub ver_in_range {
 190         my($ver, $range) = @_;
 191         return 1 unless defined $range;
 192         my($l,$h) = ($range, $range);
 193         if ($range =~ /(.*)-(.*)/) {
 194                 ($l,$h) = ($1,$2);
 195         }
 196         return 0 if $l && ver_cmp($ver, $l) < 0;
 197         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 198         return 1;
 199 }
 200
 201 sub find_mod_in_range {
 202         my($mod, $vers, $force) = @_;
 203         my @versions = keys %{$modules{$mod}};
 204         @versions = sort { -ver_cmp() } @versions;
 205         for my $ver (@versions) {
 206                 next if $modules{$mod}{$ver}{mask} && !$force;
 207                 return $ver if ver_in_range($ver, $vers);
 208         }
 209         return undef;
 210 }
 211
 212 sub resolve_deps {
 213         my($trial) = @_;
 214         my $tries = 100;
 215         my $changes = 'INIT';
 216         my $fail = undef;
 217         while ($changes && $tries) {
 218                 $tries--;
 219                 $changes = '';
 220                 $fail = undef;
 221                 my @modsnow = sort keys %todo;
 222                 for my $mod (@modsnow) {
 223                         my $ver = $todo{$mod};
 224                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 225                         for my $dep (@{$info->{depends}}) {
 226                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 227                                 my($depmod, $depvers) = ($1,$2);
 228                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 229                                 # need to install a dependency
 230                                 my $depver = find_mod_in_range($depmod, $depvers);
 231                                 if (defined $depver) {
 232                                         $todo{$depmod} = $depver;
 233                                         $changes .= " $mod-$ver->$depmod-$depver";
 234                                 } else {
 235                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 236                                 }
 237                         }
 238                         for my $dep (@{$info->{conflicts}}) {
 239                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 240                                 my($depmod, $depvers) = ($1,$2);
 241                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 242                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 243                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 244                         }
 245                 }
 246         }
 247         if ($trial) {
 248                 return !($changes || $fail);
 249         }
 250         if ($changes) {
 251                 print "Infinite dependency loop:$changes\n";
 252                 exit 1;
 253         }
 254         if ($fail) {
 255                 print "$fail\n";
 256                 exit 1;
 257         }
 258 }
 259
 260 my $action = $#ARGV > 0 ? lc shift @ARGV : 'help';
 261
 262 if ($action eq 'install') {
 263         for my $mod (@ARGV) {
 264                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 265                 $mod = lc $mod;
 266                 unless ($modules{$mod}) {
 267                         print "Cannot find module $mod\n";
 268                         exit 1;
 269                 }
 270                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 271                 unless ($ver) {
 272                         print "Cannot find suitable version of $mod\n";
 273                         exit 1;
 274                 }
 275                 $todo{$mod} = $ver;
 276         }
 277 } elsif ($action eq 'upgrade') {
 278         my @installed = sort keys %installed;
 279         for my $mod (@installed) {
 280                 next unless $mod =~ /^m_/;
 281                 my %saved = %todo;
 282                 $todo{$mod} = find_mod_in_range($mod);
 283                 if (!resolve_deps(1)) {
 284                         %todo = %saved;
 285                 }
 286         }
 287 } elsif ($action eq 'list') {
 288         my @all = sort keys %modules;
 289         for my $mod (@all) {
 290                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 291                 my $desc = '';
 292                 for my $ver (@vers) {
 293                         # latest defined description wins
 294                         $desc = $modules{$mod}{$ver}{description} || $desc;
 295                 }
 296                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 297                 my $instver = $installed{$mod} || '';
 298                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 299                 print "$mod ($vers) - $desc\n";
 300         }
 301 } else {
 302         print <<ENDUSAGE
 303 Use: $0 <action> <args>
 304 Action is one of the following
 305  install   install new modules
 306  upgrade   upgrade installed modules
 307  list      lists available modules
 308
 309 For installing a package, specify its name or name=version to force the
 310 installation of a specific version.
 311 ENDUSAGE
 312 ;exit 1;
 313 }
 314
 315 resolve_deps(0);
 316
 317 $| = 1; # immediate print of lines without \n
 318
 319 print "Processing changes for $action...\n";
 320 for my $mod (keys %installed) {
 321         next if $todo{$mod};
 322         print "Uninstalling $mod $installed{$mod}\n";
 323         unlink "src/modules/$mod.cpp";
 324 }
 325
 326 my $count = scalar keys %todo;
 327 print "Checking $count items...\n";
 328 for my $mod (sort keys %todo) {
 329         my $ver = $todo{$mod};
 330         my $oldver = $installed{$mod};
 331         if ($modules{$mod}{$ver}{mask}) {
 332                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 333         }
 334         next if $oldver && $oldver eq $ver;
 335         my $url = $modules{$mod}{$ver}{url};
 336         if ($oldver) {
 337                 print "Upgrading $mod from $oldver to $ver using $url"
 338         } else {
 339                 print "Installing $mod $ver from $url";
 340         }
 341         $mod_versions{$mod} = $ver;
 342
 343         my $stat = getstore($url, "src/modules/$mod.cpp");
 344         if ($stat == 200) {
 345                 print " - done\n";
 346         } else {
 347                 print " - HTTP $stat\n";
 348         }
 349 }
 350
 351 # write database of installed versions
 352 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 353 foreach my $key (keys %mod_versions)
 354 {
 355         print SRC "$key $mod_versions{$key}\n";
 356 }
 357 close SRC;
 358
 359 print "Finished!\n";