modulemanager

   1 #!/usr/bin/perl
   2 use strict;
   3 use warnings FATAL => qw(all);
   4 use LWP::Simple;
   5
   6 use make::configure;
   7
   8 our @modlist;
   9
  10 my %installed;
  11 # $installed{name} = $version
  12
  13 my %modules;
  14 # $modules{$name}{$version} = {
  15 #       url => URL of this version (or INSECURE/DEPRECATED)
  16 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  17 #       conflicts => [ ]
  18 #       from => URL of source document
  19 # }
  20
  21 my %url_seen;
  22
  23 sub parse_url;
  24
  25 sub parse_url {
  26         my $src = shift;
  27         return if $url_seen{$src};
  28         $url_seen{$src}++;
  29
  30         my $doc = get($src);
  31         die "Could not retrieve $_" unless defined $doc;
  32
  33         my $mod;
  34         for (split /\n+/, $doc) {
  35                 s/^\s+//; # ignore whitespace at start
  36                 next if /^#/;
  37                 if (/^module (\S+) ([0-9.]+) (\S+)/) {
  38                         my($name, $ver, $url) = ($1,$2,$3);
  39                         if ($modules{$name}{$ver}) {
  40                                 my $origsrc = $modules{$name}{$ver}{from};
  41                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  42                         }
  43                         $mod = {
  44                                 from => $src,
  45                                 url => $url,
  46                                 depends => [],
  47                                 conflicts => [],
  48                         };
  49                         $modules{$name}{$ver} = $mod;
  50                 } elsif (/^depends (.*)/) {
  51                         push @{$mod->{depends}}, $1;
  52                 } elsif (/^conflicts (.*)/) {
  53                         push @{$mod->{conflicts}}, $1;
  54                 } elsif (m#^source (http://\S+)#) {
  55                         parse_url $1;
  56                 } else {
  57                         print "Unknown line in $src: $_\n";
  58                 }
  59         }
  60 }
  61
  62 open SRC, 'sources.list' or die "Could not open sources.list: $!";
  63 while (<SRC>) {
  64         next if /^\s*#/;
  65         parse_url($_);
  66 }
  67 close SRC;
  68
  69 getmodules();
  70
  71 open my $verfile, 'src/version.sh' or die "Cannot determine inspircd version: $!";
  72 $_ = join '', <$verfile>;
  73 die "Cannot determine inspircd version" unless /InspIRCd-([0-9.]+)/;
  74 $installed{core} = $1;
  75 $modules{core}{$1} = {
  76         url => 'NONE',
  77         depends => [],
  78         conflicts => [],
  79         from => 'local file',
  80 };
  81 close $verfile;
  82
  83 for my $modname (@modlist) {
  84         my $mod = "m_$modname";
  85         my $modfile = "src/modules/$mod.cpp";
  86         my $ver = getmodversion($modfile) || '0.0';
  87         $installed{$mod} = $ver;
  88         next if $modules{$mod}{$ver};
  89         $modules{$mod}{$ver} = {
  90                 url => 'NONE',
  91                 depends => [],
  92                 conflicts => [],
  93                 from => 'local file',
  94         };
  95 }
  96
  97 my %todo = %installed;
  98
  99 sub ver_cmp {
 100         ($a,$b) = @_ if @_;
 101         my @a = split /\./, $a;
 102         my @b = split /\./, $b;
 103         push @a, 0 while $#a < $#b;
 104         push @b, 0 while $#b < $#a;
 105         for my $i (0..$#a) {
 106                 my $d = $a[$i] <=> $b[$i];
 107                 return $d if $d;
 108         }
 109         return 0;
 110 }
 111
 112 sub ver_in_range {
 113         my($ver, $range) = @_;
 114         return 1 unless defined $range;
 115         if ($range =~ /(.*)-(.*)/) {
 116                 my($l,$h) = ($1,$2);
 117                 return 0 unless ver_cmp($ver, $l) >= 0;
 118                 return 0 unless ver_cmp($ver, $h) <= 0;
 119                 return 1;
 120         }
 121         return !ver_cmp($ver, $range);
 122 }
 123
 124 sub find_mod_in_range {
 125         my($mod,$vers) = @_;
 126         my @versions = keys %{$modules{$mod}};
 127         @versions = sort { ver_cmp() } @versions;
 128         for my $ver (reverse @versions) {
 129                 return $ver if ver_in_range($ver, $vers);
 130         }
 131         return undef;
 132 }
 133
 134 sub resolve_deps {
 135         my $tries = 100;
 136         my $changes = 'INIT';
 137         my $fail = undef;
 138         while ($changes && $tries) {
 139                 $tries--;
 140                 $changes = '';
 141                 $fail = undef;
 142                 my @modsnow = sort keys %todo;
 143                 for my $mod (@modsnow) {
 144                         my $ver = $todo{$mod};
 145                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 146                         for my $dep (@{$info->{depends}}) {
 147                                 $dep =~ /^(\S+)(?: ([-0-9.]+))?/ or die "Bad dependency $dep from $info->{from}";
 148                                 my($depmod, $depvers) = ($1,$2);
 149                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 150                                 # need to install a dependency
 151                                 my $depver = find_mod_in_range($depmod, $depvers);
 152                                 if (defined $depver) {
 153                                         $todo{$depmod} = $depver;
 154                                         $changes .= " $mod-$ver->$depmod-$depver";
 155                                 } else {
 156                                         $fail ||= "Could not find module $depmod $depver required by $mod $ver";
 157                                 }
 158                         }
 159                         for my $dep (@{$info->{conflicts}}) {
 160                                 $dep =~ /^(\S+)(?: ([-0-9.]+))?/ or die "Bad dependency $dep from $info->{from}";
 161                                 my($depmod, $depvers) = ($1,$2);
 162                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 163                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 164                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with versions $depmod version $todo{depmod}";
 165                         }
 166                 }
 167         }
 168         if ($changes) {
 169                 print "Infinite dependency loop:$changes\n";
 170                 exit 1;
 171         }
 172         if ($fail) {
 173                 print "$fail\n";
 174                 exit 1;
 175         }
 176 }
 177
 178 my $action = lc shift @ARGV;
 179
 180 if ($action eq 'install') {
 181         for my $mod (@ARGV) {
 182                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 183                 $mod = lc $mod;
 184                 unless ($modules{$mod}) {
 185                         print "Cannot find module $mod\n";
 186                         exit 1;
 187                 }
 188                 my $ver = find_mod_in_range($mod, $vers);
 189                 unless ($ver) {
 190                         print "Cannot find suitable version of $mod\n";
 191                         exit 1;
 192                 }
 193                 $todo{$mod} = $ver;
 194         }
 195 } elsif ($action eq 'upgrade') {
 196         for my $mod (keys %installed) {
 197                 next unless $mod =~ /^m_/;
 198                 $todo{$mod} = find_mod_in_range($mod);
 199         }
 200 } else {
 201         die "Unknown action $action"
 202 }
 203
 204 resolve_deps();
 205
 206 $| = 1; # immediate print of lines without \n
 207
 208 for my $mod (keys %installed) {
 209         next if $todo{$mod};
 210         print "Uninstalling $mod $installed{$mod}\n";
 211         unlink "src/modules/$mod.cpp";
 212 }
 213 for my $mod (sort keys %todo) {
 214         my $ver = $todo{$mod};
 215         my $oldver = $installed{$mod};
 216         my $url = $modules{$mod}{$ver}{url};
 217         if ($url eq 'INSECURE') {
 218                 print "WARNING: Version $ver of $mod is insecure!\n";
 219                 next;
 220         } elsif ($url eq 'DEPRECATED') {
 221                 print "Note: version $ver of $mod is deprecated\n";
 222                 next;
 223         }
 224         next if $oldver && $oldver eq $ver;
 225         if ($oldver) {
 226                 print "Upgrading $mod from $oldver to $ver using $url"
 227         } else {
 228                 print "Installing $mod $ver from $url";
 229         }
 230         my $stat = getstore($url, "src/modules/$mod.cpp");
 231         if ($stat == 200) {
 232                 print " - done\n";
 233         } else {
 234                 print " - HTTP $stat\n";
 235         }
 236 }