modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   7 #
   8 # This file is part of InspIRCd.  InspIRCd is free software: you can
   9 # redistribute it and/or modify it under the terms of the GNU General Public
  10 # License as published by the Free Software Foundation, version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21
  22 use strict;
  23 use warnings FATAL => qw(all);
  24
  25 use make::configure;
  26
  27 BEGIN {
  28         push @INC, '.';
  29         unless (module_installed("LWP::Simple")) {
  30                 die "Your system is missing the LWP::Simple Perl module!";
  31         }
  32         unless (module_installed("Crypt::SSLeay") || module_installed("IO::Socket::SSL")) {
  33                 die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  34         }
  35 }
  36
  37 use LWP::Simple;
  38
  39 our @modlist;
  40
  41 my %installed;
  42 # $installed{name} = $version
  43
  44 my %modules;
  45 # $modules{$name}{$version} = {
  46 #       url => URL of this version
  47 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  48 #       conflicts => [ ]
  49 #       from => URL of source document
  50 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  51 #       description => some string
  52 # }
  53
  54 my %url_seen;
  55
  56 sub parse_url;
  57
  58 # retrieve and parse entries from sources.list
  59 sub parse_url {
  60         chomp(my $src = shift);
  61         return if $url_seen{$src};
  62         $url_seen{$src}++;
  63
  64         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
  65         my $response = $ua->get($src);
  66
  67         unless ($response->is_success) {
  68                 my $err = $response->message;
  69                 die "Could not retrieve $src: $err";
  70         }
  71
  72         my $mod;
  73         for (split /\n+/, $response->decoded_content) {
  74                 s/^\s+//; # ignore whitespace at start
  75                 next if /^#/;
  76                 if (/^module (\S+) (\S+) (\S+)/) {
  77                         my($name, $ver, $url) = ($1,$2,$3);
  78                         if ($modules{$name}{$ver}) {
  79                                 my $origsrc = $modules{$name}{$ver}{from};
  80                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  81                         }
  82                         $mod = {
  83                                 from => $src,
  84                                 url => $url,
  85                                 depends => [],
  86                                 conflicts => [],
  87                         };
  88                         $modules{$name}{$ver} = $mod;
  89                 } elsif (/^depends (.*)/) {
  90                         push @{$mod->{depends}}, $1;
  91                 } elsif (/^conflicts (.*)/) {
  92                         push @{$mod->{conflicts}}, $1;
  93                 } elsif (/^description (.*)/) {
  94                         $mod->{description} = $1;
  95                 } elsif (/^mask (.*)/) {
  96                         $mod->{mask} = $1;
  97                 } elsif (m#^source (http://\S+)#) {
  98                         parse_url $1;
  99                 } else {
 100                         print "Unknown line in $src: $_\n";
 101                 }
 102         }
 103 }
 104
 105 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 106 my %mod_versions;
 107
 108 # useless helper stub
 109 sub getmodversion {
 110         my ($file) = @_;
 111         return $mod_versions{$file};
 112 }
 113
 114 # read in installed versions
 115 if (-e '.modulemanager')
 116 {
 117         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
 118         while (<SRC>)
 119         {
 120                 s/\n//;
 121                 (my $mod, my $ver) = split(/ /, $_);
 122                 $mod_versions{$mod} = $ver;
 123         }
 124         close SRC;
 125 }
 126
 127 # read in external URL sources
 128 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 129 while (<SRC>) {
 130         next if /^\s*#/;
 131         parse_url($_);
 132 }
 133 close SRC;
 134
 135 getmodules(1);
 136
 137 # determine core version
 138 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 139 $installed{core} = $1;
 140 for my $mod (keys %modules) {
 141         MODVER: for my $mver (keys %{$modules{$mod}}) {
 142                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 143                         next unless $dep =~ /^core (.*)/;
 144                         if (!ver_in_range($installed{core}, $1)) {
 145                                 delete $modules{$mod}{$mver};
 146                                 next MODVER;
 147                         }
 148                 }
 149         }
 150         delete $modules{$mod} unless %{$modules{$mod}};
 151 }
 152 $modules{core}{$1} = {
 153         url => 'NONE',
 154         depends => [],
 155         conflicts => [],
 156         from => 'local file',
 157 };
 158
 159 # set up core module list
 160 for my $modname (@modlist) {
 161         my $mod = "m_$modname";
 162         my $modfile = "src/modules/$mod.cpp";
 163         my $ver = getmodversion($mod) || '0.0';
 164         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 165         $installed{$mod} = $ver;
 166         next if $modules{$mod}{$ver};
 167         $modules{$mod}{$ver} = {
 168                 url => 'NONE',
 169                 depends => [],
 170                 conflicts => [],
 171                 from => 'local file',
 172         };
 173 }
 174
 175 my %todo = %installed;
 176
 177 sub ver_cmp {
 178         ($a,$b) = @_ if @_;
 179
 180         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 181         {
 182                 # not a valid version number, don't try to sort
 183                 return $a ne $b;
 184         }
 185
 186         # else it's probably a numerical type version.. i.e. 1.0
 187         my @a = split /\./, $a;
 188         my @b = split /\./, $b;
 189         push @a, 0 while $#a < $#b;
 190         push @b, ($_[2] || 0) while $#b < $#a;
 191         for my $i (0..$#a) {
 192                 my $d = $a[$i] <=> $b[$i];
 193                 return $d if $d;
 194         }
 195         return 0;
 196 }
 197
 198 sub ver_in_range {
 199         my($ver, $range) = @_;
 200         return 1 unless defined $range;
 201         my($l,$h) = ($range, $range);
 202         if ($range =~ /(.*)-(.*)/) {
 203                 ($l,$h) = ($1,$2);
 204         }
 205         return 0 if $l && ver_cmp($ver, $l) < 0;
 206         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 207         return 1;
 208 }
 209
 210 sub find_mod_in_range {
 211         my($mod, $vers, $force) = @_;
 212         my @versions = keys %{$modules{$mod}};
 213         @versions = sort { -ver_cmp() } @versions;
 214         for my $ver (@versions) {
 215                 next if $modules{$mod}{$ver}{mask} && !$force;
 216                 return $ver if ver_in_range($ver, $vers);
 217         }
 218         return undef;
 219 }
 220
 221 sub resolve_deps {
 222         my($trial) = @_;
 223         my $tries = 100;
 224         my $changes = 'INIT';
 225         my $fail = undef;
 226         while ($changes && $tries) {
 227                 $tries--;
 228                 $changes = '';
 229                 $fail = undef;
 230                 my @modsnow = sort keys %todo;
 231                 for my $mod (@modsnow) {
 232                         my $ver = $todo{$mod};
 233                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 234                         for my $dep (@{$info->{depends}}) {
 235                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 236                                 my($depmod, $depvers) = ($1,$2);
 237                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 238                                 # need to install a dependency
 239                                 my $depver = find_mod_in_range($depmod, $depvers);
 240                                 if (defined $depver) {
 241                                         $todo{$depmod} = $depver;
 242                                         $changes .= " $mod-$ver->$depmod-$depver";
 243                                 } else {
 244                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 245                                 }
 246                         }
 247                         for my $dep (@{$info->{conflicts}}) {
 248                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 249                                 my($depmod, $depvers) = ($1,$2);
 250                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 251                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 252                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 253                         }
 254                 }
 255         }
 256         if ($trial) {
 257                 return !($changes || $fail);
 258         }
 259         if ($changes) {
 260                 print "Infinite dependency loop:$changes\n";
 261                 exit 1;
 262         }
 263         if ($fail) {
 264                 print "$fail\n";
 265                 exit 1;
 266         }
 267 }
 268
 269 my $action = $#ARGV >= 0 ? lc shift @ARGV : 'help';
 270
 271 if ($action eq 'install') {
 272         for my $mod (@ARGV) {
 273                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 274                 $mod = lc $mod;
 275                 unless ($modules{$mod}) {
 276                         print "Cannot find module $mod\n";
 277                         exit 1;
 278                 }
 279                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 280                 unless ($ver) {
 281                         print "Cannot find suitable version of $mod\n";
 282                         exit 1;
 283                 }
 284                 $todo{$mod} = $ver;
 285         }
 286 } elsif ($action eq 'upgrade') {
 287         my @installed = sort keys %installed;
 288         for my $mod (@installed) {
 289                 next unless $mod =~ /^m_/;
 290                 my %saved = %todo;
 291                 $todo{$mod} = find_mod_in_range($mod);
 292                 if (!resolve_deps(1)) {
 293                         %todo = %saved;
 294                 }
 295         }
 296 } elsif ($action eq 'list') {
 297         my @all = sort keys %modules;
 298         for my $mod (@all) {
 299                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 300                 my $desc = '';
 301                 for my $ver (@vers) {
 302                         # latest defined description wins
 303                         $desc = $modules{$mod}{$ver}{description} || $desc;
 304                 }
 305                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 306                 my $instver = $installed{$mod} || '';
 307                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 308                 print "$mod ($vers) - $desc\n";
 309         }
 310 } else {
 311         print <<ENDUSAGE
 312 Use: $0 <action> <args>
 313 Action is one of the following
 314  install   install new modules
 315  upgrade   upgrade installed modules
 316  list      lists available modules
 317
 318 For installing a package, specify its name or name=version to force the
 319 installation of a specific version.
 320 ENDUSAGE
 321 ;exit 1;
 322 }
 323
 324 resolve_deps(0);
 325
 326 $| = 1; # immediate print of lines without \n
 327
 328 print "Processing changes for $action...\n";
 329 for my $mod (keys %installed) {
 330         next if $todo{$mod};
 331         print "Uninstalling $mod $installed{$mod}\n";
 332         unlink "src/modules/$mod.cpp";
 333 }
 334
 335 my $count = scalar keys %todo;
 336 print "Checking $count items...\n";
 337 for my $mod (sort keys %todo) {
 338         my $ver = $todo{$mod};
 339         my $oldver = $installed{$mod};
 340         if ($modules{$mod}{$ver}{mask}) {
 341                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 342         }
 343         next if $oldver && $oldver eq $ver;
 344         my $url = $modules{$mod}{$ver}{url};
 345         if ($oldver) {
 346                 print "Upgrading $mod from $oldver to $ver using $url"
 347         } else {
 348                 print "Installing $mod $ver from $url";
 349         }
 350         $mod_versions{$mod} = $ver;
 351
 352         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
 353         my $response = $ua->get($url);
 354
 355         if ($response->is_success) {
 356                 open(MF, ">src/modules/$mod.cpp") or die "\nFilesystem not writable: $!";
 357                 print MF $response->decoded_content;
 358                 close(MF);
 359                 print " - done\n";
 360         } else {
 361                 printf "\nHTTP %s: %s\n", $response->code, $response->message;
 362         }
 363 }
 364
 365 # write database of installed versions
 366 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 367 foreach my $key (keys %mod_versions)
 368 {
 369         print SRC "$key $mod_versions{$key}\n";
 370 }
 371 close SRC;
 372
 373 print "Finished!\n";