modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   7 #
   8 # This file is part of InspIRCd.  InspIRCd is free software: you can
   9 # redistribute it and/or modify it under the terms of the GNU General Public
  10 # License as published by the Free Software Foundation, version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21
  22 use strict;
  23 use warnings FATAL => qw(all);
  24
  25 use make::configure;
  26
  27
  28 if (!module_installed("LWP::Simple"))
  29 {
  30         die "Your system is missing the LWP::Simple Perl module!";
  31 }
  32
  33 if (!module_installed("Crypt::SSLeay") && !module_installed("IO::Socket::SSL"))
  34 {
  35         die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  36 }
  37
  38 use LWP::Simple;
  39
  40 our @modlist;
  41
  42 my %installed;
  43 # $installed{name} = $version
  44
  45 my %modules;
  46 # $modules{$name}{$version} = {
  47 #       url => URL of this version
  48 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  49 #       conflicts => [ ]
  50 #       from => URL of source document
  51 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  52 #       description => some string
  53 # }
  54
  55 my %url_seen;
  56
  57 sub parse_url;
  58
  59 # retrieve and parse entries from sources.list
  60 sub parse_url {
  61         my $src = shift;
  62         return if $url_seen{$src};
  63         $url_seen{$src}++;
  64
  65         my $doc = get($src);
  66         die "Could not retrieve $_" unless defined $doc;
  67
  68         my $mod;
  69         for (split /\n+/, $doc) {
  70                 s/^\s+//; # ignore whitespace at start
  71                 next if /^#/;
  72                 if (/^module (\S+) (\S+) (\S+)/) {
  73                         my($name, $ver, $url) = ($1,$2,$3);
  74                         if ($modules{$name}{$ver}) {
  75                                 my $origsrc = $modules{$name}{$ver}{from};
  76                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  77                         }
  78                         $mod = {
  79                                 from => $src,
  80                                 url => $url,
  81                                 depends => [],
  82                                 conflicts => [],
  83                         };
  84                         $modules{$name}{$ver} = $mod;
  85                 } elsif (/^depends (.*)/) {
  86                         push @{$mod->{depends}}, $1;
  87                 } elsif (/^conflicts (.*)/) {
  88                         push @{$mod->{conflicts}}, $1;
  89                 } elsif (/^description (.*)/) {
  90                         $mod->{description} = $1;
  91                 } elsif (/^mask (.*)/) {
  92                         $mod->{mask} = $1;
  93                 } elsif (m#^source (http://\S+)#) {
  94                         parse_url $1;
  95                 } else {
  96                         print "Unknown line in $src: $_\n";
  97                 }
  98         }
  99 }
 100
 101 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 102 my %mod_versions;
 103
 104 # useless helper stub
 105 sub getmodversion {
 106         my ($file) = @_;
 107         return $mod_versions{$file};
 108 }
 109
 110 # read in installed versions
 111 if (-e '.modulemanager')
 112 {
 113         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
 114         while (<SRC>)
 115         {
 116                 s/\n//;
 117                 (my $mod, my $ver) = split(/ /, $_);
 118                 $mod_versions{$mod} = $ver;
 119         }
 120         close SRC;
 121 }
 122
 123 # read in external URL sources
 124 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 125 while (<SRC>) {
 126         next if /^\s*#/;
 127         parse_url($_);
 128 }
 129 close SRC;
 130
 131 getmodules(1);
 132
 133 # determine core version
 134 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 135 $installed{core} = $1;
 136 for my $mod (keys %modules) {
 137         MODVER: for my $mver (keys %{$modules{$mod}}) {
 138                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 139                         next unless $dep =~ /^core (.*)/;
 140                         if (!ver_in_range($installed{core}, $1)) {
 141                                 delete $modules{$mod}{$mver};
 142                                 next MODVER;
 143                         }
 144                 }
 145         }
 146         delete $modules{$mod} unless %{$modules{$mod}};
 147 }
 148 $modules{core}{$1} = {
 149         url => 'NONE',
 150         depends => [],
 151         conflicts => [],
 152         from => 'local file',
 153 };
 154
 155 # set up core module list
 156 for my $modname (@modlist) {
 157         my $mod = "m_$modname";
 158         my $modfile = "src/modules/$mod.cpp";
 159         my $ver = getmodversion($mod) || '0.0';
 160         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 161         $installed{$mod} = $ver;
 162         next if $modules{$mod}{$ver};
 163         $modules{$mod}{$ver} = {
 164                 url => 'NONE',
 165                 depends => [],
 166                 conflicts => [],
 167                 from => 'local file',
 168         };
 169 }
 170
 171 my %todo = %installed;
 172
 173 sub ver_cmp {
 174         ($a,$b) = @_ if @_;
 175
 176         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 177         {
 178                 # not a valid version number, don't try to sort
 179                 return $a ne $b;
 180         }
 181
 182         # else it's probably a numerical type version.. i.e. 1.0
 183         my @a = split /\./, $a;
 184         my @b = split /\./, $b;
 185         push @a, 0 while $#a < $#b;
 186         push @b, ($_[2] || 0) while $#b < $#a;
 187         for my $i (0..$#a) {
 188                 my $d = $a[$i] <=> $b[$i];
 189                 return $d if $d;
 190         }
 191         return 0;
 192 }
 193
 194 sub ver_in_range {
 195         my($ver, $range) = @_;
 196         return 1 unless defined $range;
 197         my($l,$h) = ($range, $range);
 198         if ($range =~ /(.*)-(.*)/) {
 199                 ($l,$h) = ($1,$2);
 200         }
 201         return 0 if $l && ver_cmp($ver, $l) < 0;
 202         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 203         return 1;
 204 }
 205
 206 sub find_mod_in_range {
 207         my($mod, $vers, $force) = @_;
 208         my @versions = keys %{$modules{$mod}};
 209         @versions = sort { -ver_cmp() } @versions;
 210         for my $ver (@versions) {
 211                 next if $modules{$mod}{$ver}{mask} && !$force;
 212                 return $ver if ver_in_range($ver, $vers);
 213         }
 214         return undef;
 215 }
 216
 217 sub resolve_deps {
 218         my($trial) = @_;
 219         my $tries = 100;
 220         my $changes = 'INIT';
 221         my $fail = undef;
 222         while ($changes && $tries) {
 223                 $tries--;
 224                 $changes = '';
 225                 $fail = undef;
 226                 my @modsnow = sort keys %todo;
 227                 for my $mod (@modsnow) {
 228                         my $ver = $todo{$mod};
 229                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 230                         for my $dep (@{$info->{depends}}) {
 231                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 232                                 my($depmod, $depvers) = ($1,$2);
 233                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 234                                 # need to install a dependency
 235                                 my $depver = find_mod_in_range($depmod, $depvers);
 236                                 if (defined $depver) {
 237                                         $todo{$depmod} = $depver;
 238                                         $changes .= " $mod-$ver->$depmod-$depver";
 239                                 } else {
 240                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 241                                 }
 242                         }
 243                         for my $dep (@{$info->{conflicts}}) {
 244                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 245                                 my($depmod, $depvers) = ($1,$2);
 246                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 247                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 248                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 249                         }
 250                 }
 251         }
 252         if ($trial) {
 253                 return !($changes || $fail);
 254         }
 255         if ($changes) {
 256                 print "Infinite dependency loop:$changes\n";
 257                 exit 1;
 258         }
 259         if ($fail) {
 260                 print "$fail\n";
 261                 exit 1;
 262         }
 263 }
 264
 265 my $action = lc shift @ARGV;
 266
 267 if ($action eq 'install') {
 268         for my $mod (@ARGV) {
 269                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 270                 $mod = lc $mod;
 271                 unless ($modules{$mod}) {
 272                         print "Cannot find module $mod\n";
 273                         exit 1;
 274                 }
 275                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 276                 unless ($ver) {
 277                         print "Cannot find suitable version of $mod\n";
 278                         exit 1;
 279                 }
 280                 $todo{$mod} = $ver;
 281         }
 282 } elsif ($action eq 'upgrade') {
 283         my @installed = sort keys %installed;
 284         for my $mod (@installed) {
 285                 next unless $mod =~ /^m_/;
 286                 my %saved = %todo;
 287                 $todo{$mod} = find_mod_in_range($mod);
 288                 if (!resolve_deps(1)) {
 289                         %todo = %saved;
 290                 }
 291         }
 292 } elsif ($action eq 'list') {
 293         my @all = sort keys %modules;
 294         for my $mod (@all) {
 295                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 296                 my $desc = '';
 297                 for my $ver (@vers) {
 298                         # latest defined description wins
 299                         $desc = $modules{$mod}{$ver}{description} || $desc;
 300                 }
 301                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 302                 my $instver = $installed{$mod} || '';
 303                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 304                 print "$mod ($vers) - $desc\n";
 305         }
 306 } else {
 307         print <<ENDUSAGE
 308 Use: $0 <action> <args>
 309 Action is one of the following
 310  install   install new modules
 311  upgrade   upgrade installed modules
 312  list      lists available modules
 313
 314 For installing a package, specify its name or name=version to force the
 315 installation of a specific version.
 316 ENDUSAGE
 317 ;exit 1;
 318 }
 319
 320 resolve_deps(0);
 321
 322 $| = 1; # immediate print of lines without \n
 323
 324 print "Processing changes for $action...\n";
 325 for my $mod (keys %installed) {
 326         next if $todo{$mod};
 327         print "Uninstalling $mod $installed{$mod}\n";
 328         unlink "src/modules/$mod.cpp";
 329 }
 330
 331 my $count = scalar keys %todo;
 332 print "Checking $count items...\n";
 333 for my $mod (sort keys %todo) {
 334         my $ver = $todo{$mod};
 335         my $oldver = $installed{$mod};
 336         if ($modules{$mod}{$ver}{mask}) {
 337                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 338         }
 339         next if $oldver && $oldver eq $ver;
 340         my $url = $modules{$mod}{$ver}{url};
 341         if ($oldver) {
 342                 print "Upgrading $mod from $oldver to $ver using $url"
 343         } else {
 344                 print "Installing $mod $ver from $url";
 345         }
 346         $mod_versions{$mod} = $ver;
 347
 348         my $stat = getstore($url, "src/modules/$mod.cpp");
 349         if ($stat == 200) {
 350                 print " - done\n";
 351         } else {
 352                 print " - HTTP $stat\n";
 353         }
 354 }
 355
 356 # write database of installed versions
 357 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 358 foreach my $key (keys %mod_versions)
 359 {
 360         print SRC "$key $mod_versions{$key}\n";
 361 }
 362 close SRC;
 363
 364 print "Finished!\n";