modulemanager

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings FATAL => qw(all);
   4 use LWP::Simple;
   5
   6 use make::configure;
   7
   8 our @modlist;
   9
  10 my %installed;
  11 # $installed{name} = $version
  12
  13 my %modules;
  14 # $modules{$name}{$version} = {
  15 #       url => URL of this version
  16 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  17 #       conflicts => [ ]
  18 #       from => URL of source document
  19 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  20 #       description => some string
  21 # }
  22
  23 my %url_seen;
  24
  25 sub parse_url;
  26
  27 # retrieve and parse entries from sources.list
  28 sub parse_url {
  29         my $src = shift;
  30         return if $url_seen{$src};
  31         $url_seen{$src}++;
  32
  33         my $doc = get($src);
  34         die "Could not retrieve $_" unless defined $doc;
  35
  36         my $mod;
  37         for (split /\n+/, $doc) {
  38                 s/^\s+//; # ignore whitespace at start
  39                 next if /^#/;
  40                 if (/^module (\S+) (\S+) (\S+)/) {
  41                         my($name, $ver, $url) = ($1,$2,$3);
  42                         if ($modules{$name}{$ver}) {
  43                                 my $origsrc = $modules{$name}{$ver}{from};
  44                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  45                         }
  46                         $mod = {
  47                                 from => $src,
  48                                 url => $url,
  49                                 depends => [],
  50                                 conflicts => [],
  51                         };
  52                         $modules{$name}{$ver} = $mod;
  53                 } elsif (/^depends (.*)/) {
  54                         push @{$mod->{depends}}, $1;
  55                 } elsif (/^conflicts (.*)/) {
  56                         push @{$mod->{conflicts}}, $1;
  57                 } elsif (/^description (.*)/) {
  58                         $mod->{description} = $1;
  59                 } elsif (/^mask (.*)/) {
  60                         $mod->{mask} = $1;
  61                 } elsif (m#^source (http://\S+)#) {
  62                         parse_url $1;
  63                 } else {
  64                         print "Unknown line in $src: $_\n";
  65                 }
  66         }
  67 }
  68
  69 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
  70 my %mod_versions;
  71
  72 # useless helper stub
  73 sub getmodversion {
  74         my ($file) = @_;
  75         return $mod_versions{$file};
  76 }
  77
  78 # read in installed versions
  79 if (-e '.modulemanager')
  80 {
  81         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
  82         while (<SRC>)
  83         {
  84                 s/\n//;
  85                 (my $mod, my $ver) = split(/ /, $_);
  86                 $mod_versions{$mod} = $ver;
  87         }
  88         close SRC;
  89 }
  90
  91 # read in external URL sources
  92 open SRC, 'sources.list' or die "Could not open sources.list: $!";
  93 while (<SRC>) {
  94         next if /^\s*#/;
  95         parse_url($_);
  96 }
  97 close SRC;
  98
  99 getmodules(1);
 100
 101 # determine core version
 102 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 103 $installed{core} = $1;
 104 for my $mod (keys %modules) {
 105         MODVER: for my $mver (keys %{$modules{$mod}}) {
 106                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 107                         next unless $dep =~ /^core (.*)/;
 108                         if (!ver_in_range($installed{core}, $1)) {
 109                                 delete $modules{$mod}{$mver};
 110                                 next MODVER;
 111                         }
 112                 }
 113         }
 114         delete $modules{$mod} unless %{$modules{$mod}};
 115 }
 116 $modules{core}{$1} = {
 117         url => 'NONE',
 118         depends => [],
 119         conflicts => [],
 120         from => 'local file',
 121 };
 122
 123 # set up core module list
 124 for my $modname (@modlist) {
 125         my $mod = "m_$modname";
 126         my $modfile = "src/modules/$mod.cpp";
 127         my $ver = getmodversion($mod) || '0.0';
 128         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 129         $installed{$mod} = $ver;
 130         next if $modules{$mod}{$ver};
 131         $modules{$mod}{$ver} = {
 132                 url => 'NONE',
 133                 depends => [],
 134                 conflicts => [],
 135                 from => 'local file',
 136         };
 137 }
 138
 139 my %todo = %installed;
 140
 141 sub ver_cmp {
 142         ($a,$b) = @_ if @_;
 143
 144         # string versions first, git IDs
 145         if ($a =~ /[a-z0-9]{40}/ or $b =~ /[a-z0-9]{40}/)
 146         {
 147                 # it's a string version. compare them as such.
 148                 return $a ne $b;
 149         }
 150
 151         # else it's probably a numerical type version.. i.e. 1.0
 152         my @a = split /\./, $a;
 153         my @b = split /\./, $b;
 154         push @a, 0 while $#a < $#b;
 155         push @b, 0 while $#b < $#a;
 156         for my $i (0..$#a) {
 157                 my $d = $a[$i] <=> $b[$i];
 158                 return $d if $d;
 159         }
 160         return 0;
 161 }
 162
 163 sub ver_in_range {
 164         my($ver, $range) = @_;
 165         return 1 unless defined $range;
 166         if ($range =~ /(.*)-(.*)/) {
 167                 my($l,$h) = ($1,$2);
 168                 return 0 if $l && ver_cmp($ver, $l) < 0;
 169                 return 0 if $h && ver_cmp($ver, $h) > 0;
 170                 return 1;
 171         }
 172         return !ver_cmp($ver, $range);
 173 }
 174
 175 sub find_mod_in_range {
 176         my($mod, $vers, $force) = @_;
 177         my @versions = keys %{$modules{$mod}};
 178         @versions = sort { -ver_cmp() } @versions;
 179         for my $ver (@versions) {
 180                 next if $modules{$mod}{$ver}{mask} && !$force;
 181                 return $ver if ver_in_range($ver, $vers);
 182         }
 183         return undef;
 184 }
 185
 186 sub resolve_deps {
 187         my($trial) = @_;
 188         my $tries = 100;
 189         my $changes = 'INIT';
 190         my $fail = undef;
 191         while ($changes && $tries) {
 192                 $tries--;
 193                 $changes = '';
 194                 $fail = undef;
 195                 my @modsnow = sort keys %todo;
 196                 for my $mod (@modsnow) {
 197                         my $ver = $todo{$mod};
 198                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 199                         for my $dep (@{$info->{depends}}) {
 200                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 201                                 my($depmod, $depvers) = ($1,$2);
 202                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 203                                 # need to install a dependency
 204                                 my $depver = find_mod_in_range($depmod, $depvers);
 205                                 if (defined $depver) {
 206                                         $todo{$depmod} = $depver;
 207                                         $changes .= " $mod-$ver->$depmod-$depver";
 208                                 } else {
 209                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 210                                 }
 211                         }
 212                         for my $dep (@{$info->{conflicts}}) {
 213                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 214                                 my($depmod, $depvers) = ($1,$2);
 215                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 216                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 217                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 218                         }
 219                 }
 220         }
 221         if ($trial) {
 222                 return !($changes || $fail);
 223         }
 224         if ($changes) {
 225                 print "Infinite dependency loop:$changes\n";
 226                 exit 1;
 227         }
 228         if ($fail) {
 229                 print "$fail\n";
 230                 exit 1;
 231         }
 232 }
 233
 234 my $action = lc shift @ARGV;
 235
 236 if ($action eq 'install') {
 237         for my $mod (@ARGV) {
 238                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 239                 $mod = lc $mod;
 240                 unless ($modules{$mod}) {
 241                         print "Cannot find module $mod\n";
 242                         exit 1;
 243                 }
 244                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 245                 unless ($ver) {
 246                         print "Cannot find suitable version of $mod\n";
 247                         exit 1;
 248                 }
 249                 $todo{$mod} = $ver;
 250         }
 251 } elsif ($action eq 'upgrade') {
 252         my @installed = sort keys %installed;
 253         for my $mod (@installed) {
 254                 next unless $mod =~ /^m_/;
 255                 my %saved = %todo;
 256                 $todo{$mod} = find_mod_in_range($mod);
 257                 if (!resolve_deps(1)) {
 258                         %todo = %saved;
 259                 }
 260         }
 261 } elsif ($action eq 'list') {
 262         my @all = sort keys %modules;
 263         for my $mod (@all) {
 264                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 265                 my $desc = '';
 266                 for my $ver (@vers) {
 267                         # latest defined description wins
 268                         $desc = $modules{$mod}{$ver}{description} || $desc;
 269                 }
 270                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 271                 my $instver = $installed{$mod} || '';
 272                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 273                 print "$mod ($vers) - $desc\n";
 274         }
 275 } else {
 276         print <<ENDUSAGE
 277 Use: $0 <action> <args>
 278 Action is one of the following
 279  install   install new modules
 280  upgrade   upgrade installed modules
 281  list      lists available modules
 282
 283 For installing a package, specify its name or name=version to force the
 284 installation of a specific version.
 285 ENDUSAGE
 286 ;exit 1;
 287 }
 288
 289 resolve_deps(0);
 290
 291 $| = 1; # immediate print of lines without \n
 292
 293 print "Processing changes for $action...\n";
 294 for my $mod (keys %installed) {
 295         next if $todo{$mod};
 296         print "Uninstalling $mod $installed{$mod}\n";
 297         unlink "src/modules/$mod.cpp";
 298 }
 299
 300 my $count = scalar keys %todo;
 301 print "Checking $count items...\n";
 302 for my $mod (sort keys %todo) {
 303         my $ver = $todo{$mod};
 304         my $oldver = $installed{$mod};
 305         if ($modules{$mod}{$ver}{mask}) {
 306                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 307         }
 308         next if $oldver && $oldver eq $ver;
 309         my $url = $modules{$mod}{$ver}{url};
 310         if ($oldver) {
 311                 print "Upgrading $mod from $oldver to $ver using $url"
 312         } else {
 313                 print "Installing $mod $ver from $url";
 314         }
 315         $mod_versions{$mod} = $ver;
 316
 317         my $stat = getstore($url, "src/modules/$mod.cpp");
 318         if ($stat == 200) {
 319                 print " - done\n";
 320         } else {
 321                 print " - HTTP $stat\n";
 322         }
 323 }
 324
 325 # write database of installed versions
 326 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 327 foreach my $key (keys %mod_versions)
 328 {
 329         print SRC "$key $mod_versions{$key}\n";
 330 }
 331 close SRC;
 332
 333 print "Finished!\n";