modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   7 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   8 #
   9 # This file is part of InspIRCd.  InspIRCd is free software: you can
  10 # redistribute it and/or modify it under the terms of the GNU General Public
  11 # License as published by the Free Software Foundation, version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  15 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  16 # details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 #
  21
  22
  23 BEGIN {
  24         require 5.10.0;
  25         unless (eval "use LWP::Simple; 1") {
  26                 die "Your system is missing the LWP::Simple Perl module!";
  27         }
  28         unless (eval "use Crypt::SSLeay; 1" || eval "use IO::Socket::SSL; 1") {
  29                 die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  30         }
  31 }
  32
  33 use feature ':5.10';
  34 use strict;
  35 use warnings FATAL => qw(all);
  36
  37 use File::Basename qw(basename);
  38 use FindBin        qw($RealDir);
  39
  40 use lib $RealDir;
  41 use make::common;
  42 use make::console;
  43
  44 my %installed;
  45 # $installed{name} = $version
  46
  47 my %modules;
  48 # $modules{$name}{$version} = {
  49 #       url => URL of this version
  50 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  51 #       conflicts => [ ]
  52 #       from => URL of source document
  53 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  54 #       description => some string
  55 # }
  56
  57 my %url_seen;
  58
  59 sub parse_url;
  60
  61 # retrieve and parse entries from sources.list
  62 sub parse_url {
  63         chomp(my $src = shift);
  64         return if $url_seen{$src};
  65         $url_seen{$src}++;
  66
  67         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
  68         my $response = $ua->get($src);
  69
  70         unless ($response->is_success) {
  71                 my $err = $response->message;
  72                 die "Could not retrieve $src: $err";
  73         }
  74
  75         my $mod;
  76         for (split /\n+/, $response->content) {
  77                 s/^\s+//; # ignore whitespace at start
  78                 next if /^#/;
  79                 if (/^module (\S+) (\S+) (\S+)/) {
  80                         my($name, $ver, $url) = ($1,$2,$3);
  81                         if ($modules{$name}{$ver}) {
  82                                 my $origsrc = $modules{$name}{$ver}{from};
  83                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  84                         }
  85                         $mod = {
  86                                 from => $src,
  87                                 url => $url,
  88                                 depends => [],
  89                                 conflicts => [],
  90                         };
  91                         $modules{$name}{$ver} = $mod;
  92                 } elsif (/^depends (.*)/) {
  93                         push @{$mod->{depends}}, $1;
  94                 } elsif (/^conflicts (.*)/) {
  95                         push @{$mod->{conflicts}}, $1;
  96                 } elsif (/^description (.*)/) {
  97                         $mod->{description} = $1;
  98                 } elsif (/^mask (.*)/) {
  99                         $mod->{mask} = $1;
 100                 } elsif (/^source (\S+)/) {
 101                         parse_url $1;
 102                 } else {
 103                         print "Unknown line in $src: $_\n";
 104                 }
 105         }
 106 }
 107
 108 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 109 my %mod_versions = read_config_file '.modulemanager';
 110
 111 # useless helper stub
 112 sub getmodversion {
 113         my ($file) = @_;
 114         return $mod_versions{$file};
 115 }
 116
 117 # read in external URL sources
 118 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 119 while (<SRC>) {
 120         next if /^\s*#/;
 121         parse_url($_);
 122 }
 123 close SRC;
 124
 125 # determine core version
 126 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 127 $installed{core} = $1;
 128 for my $mod (keys %modules) {
 129         MODVER: for my $mver (keys %{$modules{$mod}}) {
 130                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 131                         next unless $dep =~ /^core (.*)/;
 132                         if (!ver_in_range($installed{core}, $1)) {
 133                                 delete $modules{$mod}{$mver};
 134                                 next MODVER;
 135                         }
 136                 }
 137         }
 138         delete $modules{$mod} unless %{$modules{$mod}};
 139 }
 140 $modules{core}{$1} = {
 141         url => 'NONE',
 142         depends => [],
 143         conflicts => [],
 144         from => 'local file',
 145 };
 146
 147 # set up core module list
 148 for my $modname (<src/modules/m_*.cpp>) {
 149         my $mod = basename($modname, '.cpp');
 150         my $ver = getmodversion($mod) || '0.0';
 151         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 152         $installed{$mod} = $ver;
 153         next if $modules{$mod}{$ver};
 154         $modules{$mod}{$ver} = {
 155                 url => 'NONE',
 156                 depends => [],
 157                 conflicts => [],
 158                 from => 'local file',
 159         };
 160 }
 161
 162 my %todo = %installed;
 163
 164 sub ver_cmp {
 165         ($a,$b) = @_ if @_;
 166
 167         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 168         {
 169                 # not a valid version number, don't try to sort
 170                 return $a ne $b;
 171         }
 172
 173         # else it's probably a numerical type version.. i.e. 1.0
 174         my @a = split /\./, $a;
 175         my @b = split /\./, $b;
 176         push @a, 0 while $#a < $#b;
 177         push @b, ($_[2] || 0) while $#b < $#a;
 178         for my $i (0..$#a) {
 179                 my $d = $a[$i] <=> $b[$i];
 180                 return $d if $d;
 181         }
 182         return 0;
 183 }
 184
 185 sub ver_in_range {
 186         my($ver, $range) = @_;
 187         return 1 unless defined $range;
 188         my($l,$h) = ($range, $range);
 189         if ($range =~ /(.*)-(.*)/) {
 190                 ($l,$h) = ($1,$2);
 191         }
 192         return 0 if $l && ver_cmp($ver, $l) < 0;
 193         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 194         return 1;
 195 }
 196
 197 sub find_mod_in_range {
 198         my($mod, $vers, $force) = @_;
 199         my @versions = keys %{$modules{$mod}};
 200         @versions = sort { -ver_cmp() } @versions;
 201         for my $ver (@versions) {
 202                 next if $modules{$mod}{$ver}{mask} && !$force;
 203                 return $ver if ver_in_range($ver, $vers);
 204         }
 205         return undef;
 206 }
 207
 208 sub resolve_deps {
 209         my($trial) = @_;
 210         my $tries = 100;
 211         my $changes = 'INIT';
 212         my $fail = undef;
 213         while ($changes && $tries) {
 214                 $tries--;
 215                 $changes = '';
 216                 $fail = undef;
 217                 my @modsnow = sort keys %todo;
 218                 for my $mod (@modsnow) {
 219                         my $ver = $todo{$mod};
 220                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 221                         for my $dep (@{$info->{depends}}) {
 222                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 223                                 my($depmod, $depvers) = ($1,$2);
 224                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 225                                 # need to install a dependency
 226                                 my $depver = find_mod_in_range($depmod, $depvers);
 227                                 if (defined $depver) {
 228                                         $todo{$depmod} = $depver;
 229                                         $changes .= " $mod-$ver->$depmod-$depver";
 230                                 } else {
 231                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 232                                 }
 233                         }
 234                         for my $dep (@{$info->{conflicts}}) {
 235                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 236                                 my($depmod, $depvers) = ($1,$2);
 237                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 238                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 239                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 240                         }
 241                 }
 242         }
 243         if ($trial) {
 244                 return !($changes || $fail);
 245         }
 246         if ($changes) {
 247                 print "Infinite dependency loop:$changes\n";
 248                 exit 1;
 249         }
 250         if ($fail) {
 251                 print "$fail\n";
 252                 exit 1;
 253         }
 254 }
 255
 256 command 'install', 'Install a third-party module', sub {
 257         for my $mod (@_) {
 258                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 259                 $mod = lc $mod;
 260                 unless ($modules{$mod}) {
 261                         print "Cannot find module $mod\n";
 262                         exit 1;
 263                 }
 264                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 265                 unless ($ver) {
 266                         print "Cannot find suitable version of $mod\n";
 267                         exit 1;
 268                 }
 269                 $todo{$mod} = $ver;
 270         }
 271 };
 272
 273 command 'upgrade', 'Upgrade a third-party module', sub {
 274         my @installed = sort keys %installed;
 275         for my $mod (@installed) {
 276                 next unless $mod =~ /^m_/;
 277                 my %saved = %todo;
 278                 $todo{$mod} = find_mod_in_range($mod);
 279                 if (!resolve_deps(1)) {
 280                         %todo = %saved;
 281                 }
 282         }
 283 };
 284
 285 command 'list', 'List available third-party modules', sub {
 286         my @all = sort keys %modules;
 287         for my $mod (@all) {
 288                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 289                 my $desc = '';
 290                 for my $ver (@vers) {
 291                         # latest defined description wins
 292                         $desc = $modules{$mod}{$ver}{description} || $desc;
 293                 }
 294                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 295                 my $instver = $installed{$mod} || '';
 296                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 297                 print "$mod ($vers) - $desc\n";
 298         }
 299         exit 0;
 300 };
 301
 302 execute_command @ARGV;
 303
 304 resolve_deps(0);
 305
 306 $| = 1; # immediate print of lines without \n
 307
 308 print "Processing changes...\n";
 309 for my $mod (keys %installed) {
 310         next if $todo{$mod};
 311         print "Uninstalling $mod $installed{$mod}\n";
 312         unlink "src/modules/$mod.cpp";
 313 }
 314
 315 my $count = scalar keys %todo;
 316 print "Checking $count items...\n";
 317 for my $mod (sort keys %todo) {
 318         my $ver = $todo{$mod};
 319         my $oldver = $installed{$mod};
 320         if ($modules{$mod}{$ver}{mask}) {
 321                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 322         }
 323         next if $oldver && $oldver eq $ver;
 324         my $url = $modules{$mod}{$ver}{url};
 325         if ($oldver) {
 326                 print "Upgrading $mod from $oldver to $ver using $url"
 327         } else {
 328                 print "Installing $mod $ver from $url";
 329         }
 330         $mod_versions{$mod} = $ver;
 331
 332         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
 333         my $response = $ua->get($url);
 334
 335         if ($response->is_success) {
 336                 open(MF, ">src/modules/$mod.cpp") or die "\nFilesystem not writable: $!";
 337                 print MF $response->content;
 338                 close(MF);
 339                 print " - done\n";
 340         } else {
 341                 printf "\nHTTP %s: %s\n", $response->code, $response->message;
 342         }
 343 }
 344
 345 # write database of installed versions
 346 write_config_file '.modulemanager', %mod_versions;
 347
 348 print "Finished!\n";