modulemanager

   1 #!/usr/bin/perl
   2 use strict;
   3 use warnings FATAL => qw(all);
   4 use LWP::Simple;
   5
   6 use make::configure;
   7
   8 our @modlist;
   9
  10 my %installed;
  11 # $installed{name} = $version
  12
  13 my %modules;
  14 # $modules{$name}{$version} = {
  15 #       url => URL of this version
  16 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  17 #       conflicts => [ ]
  18 #       from => URL of source document
  19 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  20 #       description => some string
  21 # }
  22
  23 my %url_seen;
  24
  25 sub parse_url;
  26
  27 # retrieve and parse entries from sources.list
  28 sub parse_url {
  29         my $src = shift;
  30         return if $url_seen{$src};
  31         $url_seen{$src}++;
  32
  33         my $doc = get($src);
  34         die "Could not retrieve $_" unless defined $doc;
  35
  36         my $mod;
  37         for (split /\n+/, $doc) {
  38                 s/^\s+//; # ignore whitespace at start
  39                 next if /^#/;
  40                 if (/^module (\S+) (\S+) (\S+)/) {
  41                         my($name, $ver, $url) = ($1,$2,$3);
  42                         if ($modules{$name}{$ver}) {
  43                                 my $origsrc = $modules{$name}{$ver}{from};
  44                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  45                         }
  46                         $mod = {
  47                                 from => $src,
  48                                 url => $url,
  49                                 depends => [],
  50                                 conflicts => [],
  51                         };
  52                         $modules{$name}{$ver} = $mod;
  53                 } elsif (/^depends (.*)/) {
  54                         push @{$mod->{depends}}, $1;
  55                 } elsif (/^conflicts (.*)/) {
  56                         push @{$mod->{conflicts}}, $1;
  57                 } elsif (/^description (.*)/) {
  58                         $mod->{description} = $1;
  59                 } elsif (/^mask (.*)/) {
  60                         $mod->{mask} = $1;
  61                 } elsif (m#^source (http://\S+)#) {
  62                         parse_url $1;
  63                 } else {
  64                         print "Unknown line in $src: $_\n";
  65                 }
  66         }
  67 }
  68
  69 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
  70 my %mod_versions;
  71
  72 # useless helper stub
  73 sub getmodversion {
  74         my ($file) = @_;
  75         return $mod_versions{$file};
  76 }
  77
  78 # read in installed versions
  79 if (-e '.modulemanager')
  80 {
  81         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
  82         while (<SRC>)
  83         {
  84                 s/\n//;
  85                 (my $mod, my $ver) = split(/ /, $_);
  86                 $mod_versions{$mod} = $ver;
  87         }
  88         close SRC;
  89 }
  90
  91 # read in external URL sources
  92 open SRC, 'sources.list' or die "Could not open sources.list: $!";
  93 while (<SRC>) {
  94         next if /^\s*#/;
  95         parse_url($_);
  96 }
  97 close SRC;
  98
  99 getmodules(1);
 100
 101 # determine core version
 102 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 103 $installed{core} = $1;
 104 $modules{core}{$1} = {
 105         url => 'NONE',
 106         depends => [],
 107         conflicts => [],
 108         from => 'local file',
 109 };
 110
 111 # set up core module list
 112 for my $modname (@modlist) {
 113         my $mod = "m_$modname";
 114         my $modfile = "src/modules/$mod.cpp";
 115         my $ver = getmodversion($mod) || '0.0';
 116         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 117         $installed{$mod} = $ver;
 118         next if $modules{$mod}{$ver};
 119         $modules{$mod}{$ver} = {
 120                 url => 'NONE',
 121                 depends => [],
 122                 conflicts => [],
 123                 from => 'local file',
 124         };
 125 }
 126
 127 my %todo = %installed;
 128
 129 sub ver_cmp {
 130         ($a,$b) = @_ if @_;
 131
 132         # string versions first, git IDs
 133         if ($a =~ /[a-z0-9]{40}/ or $b =~ /[a-z0-9]{40}/)
 134         {
 135                 # it's a string version. compare them as such.
 136                 return $a ne $b;
 137         }
 138
 139         # else it's probably a numerical type version.. i.e. 1.0
 140         my @a = split /\./, $a;
 141         my @b = split /\./, $b;
 142         push @a, 0 while $#a < $#b;
 143         push @b, 0 while $#b < $#a;
 144         for my $i (0..$#a) {
 145                 my $d = $a[$i] <=> $b[$i];
 146                 return $d if $d;
 147         }
 148         return 0;
 149 }
 150
 151 sub ver_in_range {
 152         my($ver, $range) = @_;
 153         return 1 unless defined $range;
 154         if ($range =~ /(.*)-(.*)/) {
 155                 my($l,$h) = ($1,$2);
 156                 return 0 if $l && ver_cmp($ver, $l) < 0;
 157                 return 0 if $h && ver_cmp($ver, $h) > 0;
 158                 return 1;
 159         }
 160         return !ver_cmp($ver, $range);
 161 }
 162
 163 sub find_mod_in_range {
 164         my($mod, $vers, $force) = @_;
 165         my @versions = keys %{$modules{$mod}};
 166         @versions = sort { -ver_cmp() } @versions;
 167         for my $ver (@versions) {
 168                 next if $modules{$mod}{$ver}{mask} && !$force;
 169                 return $ver if ver_in_range($ver, $vers);
 170         }
 171         return undef;
 172 }
 173
 174 sub resolve_deps {
 175         my($trial) = @_;
 176         my $tries = 100;
 177         my $changes = 'INIT';
 178         my $fail = undef;
 179         while ($changes && $tries) {
 180                 $tries--;
 181                 $changes = '';
 182                 $fail = undef;
 183                 my @modsnow = sort keys %todo;
 184                 for my $mod (@modsnow) {
 185                         my $ver = $todo{$mod};
 186                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 187                         for my $dep (@{$info->{depends}}) {
 188                                 $dep =~ /^(\S+)(?: \S+)?/ or die "Bad dependency $dep from $info->{from}";
 189                                 my($depmod, $depvers) = ($1,$2);
 190                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 191                                 # need to install a dependency
 192                                 my $depver = find_mod_in_range($depmod, $depvers);
 193                                 if (defined $depver) {
 194                                         $todo{$depmod} = $depver;
 195                                         $changes .= " $mod-$ver->$depmod-$depver";
 196                                 } else {
 197                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 198                                 }
 199                         }
 200                         for my $dep (@{$info->{conflicts}}) {
 201                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 202                                 my($depmod, $depvers) = ($1,$2);
 203                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 204                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 205                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 206                         }
 207                 }
 208         }
 209         if ($trial) {
 210                 return !($changes || $fail);
 211         }
 212         if ($changes) {
 213                 print "Infinite dependency loop:$changes\n";
 214                 exit 1;
 215         }
 216         if ($fail) {
 217                 print "$fail\n";
 218                 exit 1;
 219         }
 220 }
 221
 222 my $action = lc shift @ARGV;
 223
 224 if ($action eq 'install') {
 225         for my $mod (@ARGV) {
 226                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 227                 $mod = lc $mod;
 228                 unless ($modules{$mod}) {
 229                         print "Cannot find module $mod\n";
 230                         exit 1;
 231                 }
 232                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 233                 unless ($ver) {
 234                         print "Cannot find suitable version of $mod\n";
 235                         exit 1;
 236                 }
 237                 $todo{$mod} = $ver;
 238         }
 239 } elsif ($action eq 'upgrade') {
 240         my @installed = sort keys %installed;
 241         for my $mod (@installed) {
 242                 next unless $mod =~ /^m_/;
 243                 my %saved = %todo;
 244                 $todo{$mod} = find_mod_in_range($mod);
 245                 if (!resolve_deps(1)) {
 246                         %todo = %saved;
 247                 }
 248         }
 249 } elsif ($action eq 'list') {
 250         my @all = sort keys %modules;
 251         for my $mod (@all) {
 252                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 253                 my $desc = '';
 254                 for my $ver (@vers) {
 255                         # latest defined description wins
 256                         $desc = $modules{$mod}{$ver}{description} || $desc;
 257                 }
 258                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 259                 my $instver = $installed{$mod} || '';
 260                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 261                 print "$mod ($vers) - $desc\n";
 262         }
 263 } else {
 264         print <<ENDUSAGE
 265 Use: $0 <action> <args>
 266 Action is one of the following
 267  install   install new modules
 268  upgrade   upgrade installed modules
 269  list      lists available modules
 270
 271 For installing a package, specify its name or name=version to force the
 272 installation of a specific version.
 273 ENDUSAGE
 274 ;exit 1;
 275 }
 276
 277 resolve_deps(0);
 278
 279 $| = 1; # immediate print of lines without \n
 280
 281 print "Processing changes for $action...\n";
 282 for my $mod (keys %installed) {
 283         next if $todo{$mod};
 284         print "Uninstalling $mod $installed{$mod}\n";
 285         unlink "src/modules/$mod.cpp";
 286 }
 287
 288 my $count = scalar keys %todo;
 289 print "Checking $count items...\n";
 290 for my $mod (sort keys %todo) {
 291         my $ver = $todo{$mod};
 292         my $oldver = $installed{$mod};
 293         if ($modules{$mod}{$ver}{mask}) {
 294                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 295         }
 296         next if $oldver && $oldver eq $ver;
 297         my $url = $modules{$mod}{$ver}{url};
 298         if ($oldver) {
 299                 print "Upgrading $mod from $oldver to $ver using $url"
 300         } else {
 301                 print "Installing $mod $ver from $url";
 302         }
 303         $mod_versions{$mod} = $ver;
 304
 305         my $stat = getstore($url, "src/modules/$mod.cpp");
 306         if ($stat == 200) {
 307                 print " - done\n";
 308         } else {
 309                 print " - HTTP $stat\n";
 310         }
 311 }
 312
 313 # write database of installed versions
 314 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 315 foreach my $key (keys %mod_versions)
 316 {
 317         print SRC "$key $mod_versions{$key}\n";
 318 }
 319 close SRC;
 320 print "Done!\n";