modulemanager

   1 #!/usr/bin/perl
   2 use strict;
   3 use warnings FATAL => qw(all);
   4 use LWP::Simple;
   5
   6 use make::configure;
   7
   8 our @modlist;
   9
  10 my %installed;
  11 # $installed{name} = $version
  12
  13 my %modules;
  14 # $modules{$name}{$version} = {
  15 #       url => URL of this version
  16 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  17 #       conflicts => [ ]
  18 #       from => URL of source document
  19 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  20 #       description => some string
  21 # }
  22
  23 my %url_seen;
  24
  25 sub parse_url;
  26
  27 sub parse_url {
  28         my $src = shift;
  29         return if $url_seen{$src};
  30         $url_seen{$src}++;
  31
  32         my $doc = get($src);
  33         die "Could not retrieve $_" unless defined $doc;
  34
  35         my $mod;
  36         for (split /\n+/, $doc) {
  37                 s/^\s+//; # ignore whitespace at start
  38                 next if /^#/;
  39                 if (/^module (\S+) ([0-9.]+) (\S+)/) {
  40                         my($name, $ver, $url) = ($1,$2,$3);
  41                         if ($modules{$name}{$ver}) {
  42                                 my $origsrc = $modules{$name}{$ver}{from};
  43                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  44                         }
  45                         $mod = {
  46                                 from => $src,
  47                                 url => $url,
  48                                 depends => [],
  49                                 conflicts => [],
  50                         };
  51                         $modules{$name}{$ver} = $mod;
  52                 } elsif (/^depends (.*)/) {
  53                         push @{$mod->{depends}}, $1;
  54                 } elsif (/^conflicts (.*)/) {
  55                         push @{$mod->{conflicts}}, $1;
  56                 } elsif (/^description (.*)/) {
  57                         $mod->{description} = $1;
  58                 } elsif (/^mask (.*)/) {
  59                         $mod->{mask} = $1;
  60                 } elsif (m#^source (http://\S+)#) {
  61                         parse_url $1;
  62                 } else {
  63                         print "Unknown line in $src: $_\n";
  64                 }
  65         }
  66 }
  67
  68 open SRC, 'sources.list' or die "Could not open sources.list: $!";
  69 while (<SRC>) {
  70         next if /^\s*#/;
  71         parse_url($_);
  72 }
  73 close SRC;
  74
  75 getmodules();
  76
  77 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
  78 $installed{core} = $1;
  79 $modules{core}{$1} = {
  80         url => 'NONE',
  81         depends => [],
  82         conflicts => [],
  83         from => 'local file',
  84 };
  85
  86 for my $modname (@modlist) {
  87         my $mod = "m_$modname";
  88         my $modfile = "src/modules/$mod.cpp";
  89         my $ver = getmodversion($modfile) || '0.0';
  90         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
  91         $installed{$mod} = $ver;
  92         next if $modules{$mod}{$ver};
  93         $modules{$mod}{$ver} = {
  94                 url => 'NONE',
  95                 depends => [],
  96                 conflicts => [],
  97                 from => 'local file',
  98         };
  99 }
 100
 101 my %todo = %installed;
 102
 103 sub ver_cmp {
 104         ($a,$b) = @_ if @_;
 105         my @a = split /\./, $a;
 106         my @b = split /\./, $b;
 107         push @a, 0 while $#a < $#b;
 108         push @b, 0 while $#b < $#a;
 109         for my $i (0..$#a) {
 110                 my $d = $a[$i] <=> $b[$i];
 111                 return $d if $d;
 112         }
 113         return 0;
 114 }
 115
 116 sub ver_in_range {
 117         my($ver, $range) = @_;
 118         return 1 unless defined $range;
 119         if ($range =~ /(.*)-(.*)/) {
 120                 my($l,$h) = ($1,$2);
 121                 return 0 unless ver_cmp($ver, $l) >= 0;
 122                 return 0 unless ver_cmp($ver, $h) <= 0;
 123                 return 1;
 124         }
 125         return !ver_cmp($ver, $range);
 126 }
 127
 128 sub find_mod_in_range {
 129         my($mod, $vers, $force) = @_;
 130         my @versions = keys %{$modules{$mod}};
 131         @versions = sort { -ver_cmp() } @versions;
 132         for my $ver (@versions) {
 133                 next if $modules{$mod}{$ver}{mask} && !$force;
 134                 return $ver if ver_in_range($ver, $vers);
 135         }
 136         return undef;
 137 }
 138
 139 sub resolve_deps {
 140         my($trial) = @_;
 141         my $tries = 100;
 142         my $changes = 'INIT';
 143         my $fail = undef;
 144         while ($changes && $tries) {
 145                 $tries--;
 146                 $changes = '';
 147                 $fail = undef;
 148                 my @modsnow = sort keys %todo;
 149                 for my $mod (@modsnow) {
 150                         my $ver = $todo{$mod};
 151                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 152                         for my $dep (@{$info->{depends}}) {
 153                                 $dep =~ /^(\S+)(?: ([-0-9.]+))?/ or die "Bad dependency $dep from $info->{from}";
 154                                 my($depmod, $depvers) = ($1,$2);
 155                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 156                                 # need to install a dependency
 157                                 my $depver = find_mod_in_range($depmod, $depvers);
 158                                 if (defined $depver) {
 159                                         $todo{$depmod} = $depver;
 160                                         $changes .= " $mod-$ver->$depmod-$depver";
 161                                 } else {
 162                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 163                                 }
 164                         }
 165                         for my $dep (@{$info->{conflicts}}) {
 166                                 $dep =~ /^(\S+)(?: ([-0-9.]+))?/ or die "Bad dependency $dep from $info->{from}";
 167                                 my($depmod, $depvers) = ($1,$2);
 168                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 169                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 170                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with versions $depmod version $todo{depmod}";
 171                         }
 172                 }
 173         }
 174         if ($trial) {
 175                 return !($changes || $fail);
 176         }
 177         if ($changes) {
 178                 print "Infinite dependency loop:$changes\n";
 179                 exit 1;
 180         }
 181         if ($fail) {
 182                 print "$fail\n";
 183                 exit 1;
 184         }
 185 }
 186
 187 my $action = lc shift @ARGV;
 188
 189 if ($action eq 'install') {
 190         for my $mod (@ARGV) {
 191                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 192                 $mod = lc $mod;
 193                 unless ($modules{$mod}) {
 194                         print "Cannot find module $mod\n";
 195                         exit 1;
 196                 }
 197                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 198                 unless ($ver) {
 199                         print "Cannot find suitable version of $mod\n";
 200                         exit 1;
 201                 }
 202                 $todo{$mod} = $ver;
 203         }
 204 } elsif ($action eq 'upgrade') {
 205         my @installed = sort keys %installed;
 206         for my $mod (@installed) {
 207                 next unless $mod =~ /^m_/;
 208                 my %saved = %todo;
 209                 $todo{$mod} = find_mod_in_range($mod);
 210                 if (!resolve_deps(1)) {
 211                         %todo = %saved;
 212                 }
 213         }
 214 } else {
 215         die "Unknown action $action"
 216 }
 217
 218 resolve_deps(0);
 219
 220 $| = 1; # immediate print of lines without \n
 221
 222 for my $mod (keys %installed) {
 223         next if $todo{$mod};
 224         print "Uninstalling $mod $installed{$mod}\n";
 225         unlink "src/modules/$mod.cpp";
 226 }
 227 for my $mod (sort keys %todo) {
 228         my $ver = $todo{$mod};
 229         my $oldver = $installed{$mod};
 230         if ($modules{$mod}{$ver}{mask}) {
 231                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 232         }
 233         next if $oldver && $oldver eq $ver;
 234         my $url = $modules{$mod}{$ver}{url};
 235         if ($oldver) {
 236                 print "Upgrading $mod from $oldver to $ver using $url"
 237         } else {
 238                 print "Installing $mod $ver from $url";
 239         }
 240         my $stat = getstore($url, "src/modules/$mod.cpp");
 241         if ($stat == 200) {
 242                 print " - done\n";
 243         } else {
 244                 print " - HTTP $stat\n";
 245         }
 246 }