modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2012-2017 Peter Powell <petpow@saberuk.com>
   7 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   8 #
   9 # This file is part of InspIRCd.  InspIRCd is free software: you can
  10 # redistribute it and/or modify it under the terms of the GNU General Public
  11 # License as published by the Free Software Foundation, version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  15 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  16 # details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 #
  21
  22
  23 BEGIN {
  24         require 5.10.0;
  25         unless (eval "use LWP::Simple; 1") {
  26                 die "Your system is missing the LWP::Simple Perl module!";
  27         }
  28         unless (eval "use Crypt::SSLeay; 1" || eval "use IO::Socket::SSL; 1") {
  29                 die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  30         }
  31 }
  32
  33 use feature ':5.10';
  34 use strict;
  35 use warnings FATAL => qw(all);
  36
  37 use File::Basename qw(basename);
  38 use FindBin        qw($RealDir);
  39
  40 use lib $RealDir;
  41 use make::common;
  42
  43 my %installed;
  44 # $installed{name} = $version
  45
  46 my %modules;
  47 # $modules{$name}{$version} = {
  48 #       url => URL of this version
  49 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  50 #       conflicts => [ ]
  51 #       from => URL of source document
  52 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  53 #       description => some string
  54 # }
  55
  56 my %url_seen;
  57
  58 sub parse_url;
  59
  60 # retrieve and parse entries from sources.list
  61 sub parse_url {
  62         chomp(my $src = shift);
  63         return if $url_seen{$src};
  64         $url_seen{$src}++;
  65
  66         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
  67         my $response = $ua->get($src);
  68
  69         unless ($response->is_success) {
  70                 my $err = $response->message;
  71                 die "Could not retrieve $src: $err";
  72         }
  73
  74         my $mod;
  75         for (split /\n+/, $response->decoded_content) {
  76                 s/^\s+//; # ignore whitespace at start
  77                 next if /^#/;
  78                 if (/^module (\S+) (\S+) (\S+)/) {
  79                         my($name, $ver, $url) = ($1,$2,$3);
  80                         if ($modules{$name}{$ver}) {
  81                                 my $origsrc = $modules{$name}{$ver}{from};
  82                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  83                         }
  84                         $mod = {
  85                                 from => $src,
  86                                 url => $url,
  87                                 depends => [],
  88                                 conflicts => [],
  89                         };
  90                         $modules{$name}{$ver} = $mod;
  91                 } elsif (/^depends (.*)/) {
  92                         push @{$mod->{depends}}, $1;
  93                 } elsif (/^conflicts (.*)/) {
  94                         push @{$mod->{conflicts}}, $1;
  95                 } elsif (/^description (.*)/) {
  96                         $mod->{description} = $1;
  97                 } elsif (/^mask (.*)/) {
  98                         $mod->{mask} = $1;
  99                 } elsif (m#^source (http://\S+)#) {
 100                         parse_url $1;
 101                 } else {
 102                         print "Unknown line in $src: $_\n";
 103                 }
 104         }
 105 }
 106
 107 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 108 my %mod_versions = read_config_file '.modulemanager';
 109
 110 # useless helper stub
 111 sub getmodversion {
 112         my ($file) = @_;
 113         return $mod_versions{$file};
 114 }
 115
 116 # read in external URL sources
 117 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 118 while (<SRC>) {
 119         next if /^\s*#/;
 120         parse_url($_);
 121 }
 122 close SRC;
 123
 124 # determine core version
 125 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 126 $installed{core} = $1;
 127 for my $mod (keys %modules) {
 128         MODVER: for my $mver (keys %{$modules{$mod}}) {
 129                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 130                         next unless $dep =~ /^core (.*)/;
 131                         if (!ver_in_range($installed{core}, $1)) {
 132                                 delete $modules{$mod}{$mver};
 133                                 next MODVER;
 134                         }
 135                 }
 136         }
 137         delete $modules{$mod} unless %{$modules{$mod}};
 138 }
 139 $modules{core}{$1} = {
 140         url => 'NONE',
 141         depends => [],
 142         conflicts => [],
 143         from => 'local file',
 144 };
 145
 146 # set up core module list
 147 for my $modname (<src/modules/m_*.cpp>) {
 148         my $mod = basename($modname, '.cpp');
 149         my $ver = getmodversion($mod) || '0.0';
 150         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 151         $installed{$mod} = $ver;
 152         next if $modules{$mod}{$ver};
 153         $modules{$mod}{$ver} = {
 154                 url => 'NONE',
 155                 depends => [],
 156                 conflicts => [],
 157                 from => 'local file',
 158         };
 159 }
 160
 161 my %todo = %installed;
 162
 163 sub ver_cmp {
 164         ($a,$b) = @_ if @_;
 165
 166         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 167         {
 168                 # not a valid version number, don't try to sort
 169                 return $a ne $b;
 170         }
 171
 172         # else it's probably a numerical type version.. i.e. 1.0
 173         my @a = split /\./, $a;
 174         my @b = split /\./, $b;
 175         push @a, 0 while $#a < $#b;
 176         push @b, ($_[2] || 0) while $#b < $#a;
 177         for my $i (0..$#a) {
 178                 my $d = $a[$i] <=> $b[$i];
 179                 return $d if $d;
 180         }
 181         return 0;
 182 }
 183
 184 sub ver_in_range {
 185         my($ver, $range) = @_;
 186         return 1 unless defined $range;
 187         my($l,$h) = ($range, $range);
 188         if ($range =~ /(.*)-(.*)/) {
 189                 ($l,$h) = ($1,$2);
 190         }
 191         return 0 if $l && ver_cmp($ver, $l) < 0;
 192         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 193         return 1;
 194 }
 195
 196 sub find_mod_in_range {
 197         my($mod, $vers, $force) = @_;
 198         my @versions = keys %{$modules{$mod}};
 199         @versions = sort { -ver_cmp() } @versions;
 200         for my $ver (@versions) {
 201                 next if $modules{$mod}{$ver}{mask} && !$force;
 202                 return $ver if ver_in_range($ver, $vers);
 203         }
 204         return undef;
 205 }
 206
 207 sub resolve_deps {
 208         my($trial) = @_;
 209         my $tries = 100;
 210         my $changes = 'INIT';
 211         my $fail = undef;
 212         while ($changes && $tries) {
 213                 $tries--;
 214                 $changes = '';
 215                 $fail = undef;
 216                 my @modsnow = sort keys %todo;
 217                 for my $mod (@modsnow) {
 218                         my $ver = $todo{$mod};
 219                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 220                         for my $dep (@{$info->{depends}}) {
 221                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 222                                 my($depmod, $depvers) = ($1,$2);
 223                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 224                                 # need to install a dependency
 225                                 my $depver = find_mod_in_range($depmod, $depvers);
 226                                 if (defined $depver) {
 227                                         $todo{$depmod} = $depver;
 228                                         $changes .= " $mod-$ver->$depmod-$depver";
 229                                 } else {
 230                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 231                                 }
 232                         }
 233                         for my $dep (@{$info->{conflicts}}) {
 234                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 235                                 my($depmod, $depvers) = ($1,$2);
 236                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 237                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 238                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 239                         }
 240                 }
 241         }
 242         if ($trial) {
 243                 return !($changes || $fail);
 244         }
 245         if ($changes) {
 246                 print "Infinite dependency loop:$changes\n";
 247                 exit 1;
 248         }
 249         if ($fail) {
 250                 print "$fail\n";
 251                 exit 1;
 252         }
 253 }
 254
 255 my $action = $#ARGV >= 0 ? lc shift @ARGV : 'help';
 256
 257 if ($action eq 'install') {
 258         for my $mod (@ARGV) {
 259                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 260                 $mod = lc $mod;
 261                 unless ($modules{$mod}) {
 262                         print "Cannot find module $mod\n";
 263                         exit 1;
 264                 }
 265                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 266                 unless ($ver) {
 267                         print "Cannot find suitable version of $mod\n";
 268                         exit 1;
 269                 }
 270                 $todo{$mod} = $ver;
 271         }
 272 } elsif ($action eq 'upgrade') {
 273         my @installed = sort keys %installed;
 274         for my $mod (@installed) {
 275                 next unless $mod =~ /^m_/;
 276                 my %saved = %todo;
 277                 $todo{$mod} = find_mod_in_range($mod);
 278                 if (!resolve_deps(1)) {
 279                         %todo = %saved;
 280                 }
 281         }
 282 } elsif ($action eq 'list') {
 283         my @all = sort keys %modules;
 284         for my $mod (@all) {
 285                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 286                 my $desc = '';
 287                 for my $ver (@vers) {
 288                         # latest defined description wins
 289                         $desc = $modules{$mod}{$ver}{description} || $desc;
 290                 }
 291                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 292                 my $instver = $installed{$mod} || '';
 293                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 294                 print "$mod ($vers) - $desc\n";
 295         }
 296 } else {
 297         print <<ENDUSAGE
 298 Use: $0 <action> <args>
 299 Action is one of the following
 300  install   install new modules
 301  upgrade   upgrade installed modules
 302  list      lists available modules
 303
 304 For installing a package, specify its name or name=version to force the
 305 installation of a specific version.
 306 ENDUSAGE
 307 ;exit 1;
 308 }
 309
 310 resolve_deps(0);
 311
 312 $| = 1; # immediate print of lines without \n
 313
 314 print "Processing changes for $action...\n";
 315 for my $mod (keys %installed) {
 316         next if $todo{$mod};
 317         print "Uninstalling $mod $installed{$mod}\n";
 318         unlink "src/modules/$mod.cpp";
 319 }
 320
 321 my $count = scalar keys %todo;
 322 print "Checking $count items...\n";
 323 for my $mod (sort keys %todo) {
 324         my $ver = $todo{$mod};
 325         my $oldver = $installed{$mod};
 326         if ($modules{$mod}{$ver}{mask}) {
 327                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 328         }
 329         next if $oldver && $oldver eq $ver;
 330         my $url = $modules{$mod}{$ver}{url};
 331         if ($oldver) {
 332                 print "Upgrading $mod from $oldver to $ver using $url"
 333         } else {
 334                 print "Installing $mod $ver from $url";
 335         }
 336         $mod_versions{$mod} = $ver;
 337
 338         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
 339         my $response = $ua->get($url);
 340
 341         if ($response->is_success) {
 342                 open(MF, ">src/modules/$mod.cpp") or die "\nFilesystem not writable: $!";
 343                 print MF $response->decoded_content;
 344                 close(MF);
 345                 print " - done\n";
 346         } else {
 347                 printf "\nHTTP %s: %s\n", $response->code, $response->message;
 348         }
 349 }
 350
 351 # write database of installed versions
 352 write_config_file '.modulemanager', %mod_versions;
 353
 354 print "Finished!\n";