modulemanager

   1 #!/usr/bin/env perl
   2
   3 #
   4 # InspIRCd -- Internet Relay Chat Daemon
   5 #
   6 #   Copyright (C) 2008-2009 Robin Burchell <robin+git@viroteck.net>
   7 #
   8 # This file is part of InspIRCd.  InspIRCd is free software: you can
   9 # redistribute it and/or modify it under the terms of the GNU General Public
  10 # License as published by the Free Software Foundation, version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21
  22 use strict;
  23 use warnings FATAL => qw(all);
  24
  25 BEGIN {
  26         require 5.8.0;
  27         push @INC, '.';
  28 }
  29
  30 BEGIN {
  31         # HACK: for some reason this needs to be in a second BEGIN block
  32         # or it doesn't receive the updated @INC from above.
  33         use make::configure;
  34         unless (module_installed("LWP::Simple")) {
  35                 die "Your system is missing the LWP::Simple Perl module!";
  36         }
  37         unless (module_installed("Crypt::SSLeay") || module_installed("IO::Socket::SSL")) {
  38                 die "Your system is missing the Crypt::SSLeay or IO::Socket::SSL Perl modules!";
  39         }
  40 }
  41
  42 use LWP::Simple;
  43
  44 our @modlist;
  45
  46 my %installed;
  47 # $installed{name} = $version
  48
  49 my %modules;
  50 # $modules{$name}{$version} = {
  51 #       url => URL of this version
  52 #       depends => [ 'm_foo 1.2.0-1.3.0', ... ]
  53 #       conflicts => [ ]
  54 #       from => URL of source document
  55 #       mask => Reason for not installing (INSECURE/DEPRECATED)
  56 #       description => some string
  57 # }
  58
  59 my %url_seen;
  60
  61 sub parse_url;
  62
  63 # retrieve and parse entries from sources.list
  64 sub parse_url {
  65         chomp(my $src = shift);
  66         return if $url_seen{$src};
  67         $url_seen{$src}++;
  68
  69         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
  70         my $response = $ua->get($src);
  71
  72         unless ($response->is_success) {
  73                 my $err = $response->message;
  74                 die "Could not retrieve $src: $err";
  75         }
  76
  77         my $mod;
  78         for (split /\n+/, $response->decoded_content) {
  79                 s/^\s+//; # ignore whitespace at start
  80                 next if /^#/;
  81                 if (/^module (\S+) (\S+) (\S+)/) {
  82                         my($name, $ver, $url) = ($1,$2,$3);
  83                         if ($modules{$name}{$ver}) {
  84                                 my $origsrc = $modules{$name}{$ver}{from};
  85                                 warn "Overriding module $name $ver defined from $origsrc with one from $src";
  86                         }
  87                         $mod = {
  88                                 from => $src,
  89                                 url => $url,
  90                                 depends => [],
  91                                 conflicts => [],
  92                         };
  93                         $modules{$name}{$ver} = $mod;
  94                 } elsif (/^depends (.*)/) {
  95                         push @{$mod->{depends}}, $1;
  96                 } elsif (/^conflicts (.*)/) {
  97                         push @{$mod->{conflicts}}, $1;
  98                 } elsif (/^description (.*)/) {
  99                         $mod->{description} = $1;
 100                 } elsif (/^mask (.*)/) {
 101                         $mod->{mask} = $1;
 102                 } elsif (m#^source (http://\S+)#) {
 103                         parse_url $1;
 104                 } else {
 105                         print "Unknown line in $src: $_\n";
 106                 }
 107         }
 108 }
 109
 110 # hash of installed module versions from our mini-database, key (m_foobar) to version (00abacca..).
 111 my %mod_versions;
 112
 113 # useless helper stub
 114 sub getmodversion {
 115         my ($file) = @_;
 116         return $mod_versions{$file};
 117 }
 118
 119 # read in installed versions
 120 if (-e '.modulemanager')
 121 {
 122         open SRC, '.modulemanager' or die ".modulemanager exists but i can't read it: $!";
 123         while (<SRC>)
 124         {
 125                 s/\n//;
 126                 (my $mod, my $ver) = split(/ /, $_);
 127                 $mod_versions{$mod} = $ver;
 128         }
 129         close SRC;
 130 }
 131
 132 # read in external URL sources
 133 open SRC, 'sources.list' or die "Could not open sources.list: $!";
 134 while (<SRC>) {
 135         next if /^\s*#/;
 136         parse_url($_);
 137 }
 138 close SRC;
 139
 140 getmodules(1);
 141
 142 # determine core version
 143 `./src/version.sh` =~ /InspIRCd-([0-9.]+)/ or die "Cannot determine inspircd version";
 144 $installed{core} = $1;
 145 for my $mod (keys %modules) {
 146         MODVER: for my $mver (keys %{$modules{$mod}}) {
 147                 for my $dep (@{$modules{$mod}{$mver}{depends}}) {
 148                         next unless $dep =~ /^core (.*)/;
 149                         if (!ver_in_range($installed{core}, $1)) {
 150                                 delete $modules{$mod}{$mver};
 151                                 next MODVER;
 152                         }
 153                 }
 154         }
 155         delete $modules{$mod} unless %{$modules{$mod}};
 156 }
 157 $modules{core}{$1} = {
 158         url => 'NONE',
 159         depends => [],
 160         conflicts => [],
 161         from => 'local file',
 162 };
 163
 164 # set up core module list
 165 for my $modname (@modlist) {
 166         my $mod = "m_$modname";
 167         my $modfile = "src/modules/$mod.cpp";
 168         my $ver = getmodversion($mod) || '0.0';
 169         $ver =~ s/\$Rev: (.*) \$/$1/; # for storing revision in SVN
 170         $installed{$mod} = $ver;
 171         next if $modules{$mod}{$ver};
 172         $modules{$mod}{$ver} = {
 173                 url => 'NONE',
 174                 depends => [],
 175                 conflicts => [],
 176                 from => 'local file',
 177         };
 178 }
 179
 180 my %todo = %installed;
 181
 182 sub ver_cmp {
 183         ($a,$b) = @_ if @_;
 184
 185         if ($a !~ /^[0-9.]+$/ or $b !~ /^[0-9.]+$/)
 186         {
 187                 # not a valid version number, don't try to sort
 188                 return $a ne $b;
 189         }
 190
 191         # else it's probably a numerical type version.. i.e. 1.0
 192         my @a = split /\./, $a;
 193         my @b = split /\./, $b;
 194         push @a, 0 while $#a < $#b;
 195         push @b, ($_[2] || 0) while $#b < $#a;
 196         for my $i (0..$#a) {
 197                 my $d = $a[$i] <=> $b[$i];
 198                 return $d if $d;
 199         }
 200         return 0;
 201 }
 202
 203 sub ver_in_range {
 204         my($ver, $range) = @_;
 205         return 1 unless defined $range;
 206         my($l,$h) = ($range, $range);
 207         if ($range =~ /(.*)-(.*)/) {
 208                 ($l,$h) = ($1,$2);
 209         }
 210         return 0 if $l && ver_cmp($ver, $l) < 0;
 211         return 0 if $h && ver_cmp($ver, $h, 9999) > 0;
 212         return 1;
 213 }
 214
 215 sub find_mod_in_range {
 216         my($mod, $vers, $force) = @_;
 217         my @versions = keys %{$modules{$mod}};
 218         @versions = sort { -ver_cmp() } @versions;
 219         for my $ver (@versions) {
 220                 next if $modules{$mod}{$ver}{mask} && !$force;
 221                 return $ver if ver_in_range($ver, $vers);
 222         }
 223         return undef;
 224 }
 225
 226 sub resolve_deps {
 227         my($trial) = @_;
 228         my $tries = 100;
 229         my $changes = 'INIT';
 230         my $fail = undef;
 231         while ($changes && $tries) {
 232                 $tries--;
 233                 $changes = '';
 234                 $fail = undef;
 235                 my @modsnow = sort keys %todo;
 236                 for my $mod (@modsnow) {
 237                         my $ver = $todo{$mod};
 238                         my $info = $modules{$mod}{$ver} or die "no dependency information on $mod $ver";
 239                         for my $dep (@{$info->{depends}}) {
 240                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 241                                 my($depmod, $depvers) = ($1,$2);
 242                                 next if $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 243                                 # need to install a dependency
 244                                 my $depver = find_mod_in_range($depmod, $depvers);
 245                                 if (defined $depver) {
 246                                         $todo{$depmod} = $depver;
 247                                         $changes .= " $mod-$ver->$depmod-$depver";
 248                                 } else {
 249                                         $fail ||= "Could not find module $depmod $depvers required by $mod $ver";
 250                                 }
 251                         }
 252                         for my $dep (@{$info->{conflicts}}) {
 253                                 $dep =~ /^(\S+)(?: (\S+))?/ or die "Bad dependency $dep from $info->{from}";
 254                                 my($depmod, $depvers) = ($1,$2);
 255                                 next unless $todo{$depmod} && ver_in_range($todo{$depmod}, $depvers);
 256                                 # if there are changes this round, maybe the conflict won't come up after they are resolved.
 257                                 $fail ||= "Cannot install: module $mod ($ver) conflicts with $depmod version $todo{$depmod}";
 258                         }
 259                 }
 260         }
 261         if ($trial) {
 262                 return !($changes || $fail);
 263         }
 264         if ($changes) {
 265                 print "Infinite dependency loop:$changes\n";
 266                 exit 1;
 267         }
 268         if ($fail) {
 269                 print "$fail\n";
 270                 exit 1;
 271         }
 272 }
 273
 274 my $action = $#ARGV >= 0 ? lc shift @ARGV : 'help';
 275
 276 if ($action eq 'install') {
 277         for my $mod (@ARGV) {
 278                 my $vers = $mod =~ s/=([-0-9.]+)// ? $1 : undef;
 279                 $mod = lc $mod;
 280                 unless ($modules{$mod}) {
 281                         print "Cannot find module $mod\n";
 282                         exit 1;
 283                 }
 284                 my $ver = find_mod_in_range($mod, $vers, $vers ? 1 : 0);
 285                 unless ($ver) {
 286                         print "Cannot find suitable version of $mod\n";
 287                         exit 1;
 288                 }
 289                 $todo{$mod} = $ver;
 290         }
 291 } elsif ($action eq 'upgrade') {
 292         my @installed = sort keys %installed;
 293         for my $mod (@installed) {
 294                 next unless $mod =~ /^m_/;
 295                 my %saved = %todo;
 296                 $todo{$mod} = find_mod_in_range($mod);
 297                 if (!resolve_deps(1)) {
 298                         %todo = %saved;
 299                 }
 300         }
 301 } elsif ($action eq 'list') {
 302         my @all = sort keys %modules;
 303         for my $mod (@all) {
 304                 my @vers = sort { ver_cmp() } keys %{$modules{$mod}};
 305                 my $desc = '';
 306                 for my $ver (@vers) {
 307                         # latest defined description wins
 308                         $desc = $modules{$mod}{$ver}{description} || $desc;
 309                 }
 310                 next if @vers == 1 && $modules{$mod}{$vers[0]}{url} eq 'NONE';
 311                 my $instver = $installed{$mod} || '';
 312                 my $vers = join ' ', map { $_ eq $instver ? "\e[1m$_\e[m" : $_ } @vers;
 313                 print "$mod ($vers) - $desc\n";
 314         }
 315 } else {
 316         print <<ENDUSAGE
 317 Use: $0 <action> <args>
 318 Action is one of the following
 319  install   install new modules
 320  upgrade   upgrade installed modules
 321  list      lists available modules
 322
 323 For installing a package, specify its name or name=version to force the
 324 installation of a specific version.
 325 ENDUSAGE
 326 ;exit 1;
 327 }
 328
 329 resolve_deps(0);
 330
 331 $| = 1; # immediate print of lines without \n
 332
 333 print "Processing changes for $action...\n";
 334 for my $mod (keys %installed) {
 335         next if $todo{$mod};
 336         print "Uninstalling $mod $installed{$mod}\n";
 337         unlink "src/modules/$mod.cpp";
 338 }
 339
 340 my $count = scalar keys %todo;
 341 print "Checking $count items...\n";
 342 for my $mod (sort keys %todo) {
 343         my $ver = $todo{$mod};
 344         my $oldver = $installed{$mod};
 345         if ($modules{$mod}{$ver}{mask}) {
 346                 print "Module $mod $ver is masked: $modules{$mod}{$ver}{mask}\n";
 347         }
 348         next if $oldver && $oldver eq $ver;
 349         my $url = $modules{$mod}{$ver}{url};
 350         if ($oldver) {
 351                 print "Upgrading $mod from $oldver to $ver using $url"
 352         } else {
 353                 print "Installing $mod $ver from $url";
 354         }
 355         $mod_versions{$mod} = $ver;
 356
 357         my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });
 358         my $response = $ua->get($url);
 359
 360         if ($response->is_success) {
 361                 open(MF, ">src/modules/$mod.cpp") or die "\nFilesystem not writable: $!";
 362                 print MF $response->decoded_content;
 363                 close(MF);
 364                 print " - done\n";
 365         } else {
 366                 printf "\nHTTP %s: %s\n", $response->code, $response->message;
 367         }
 368 }
 369
 370 # write database of installed versions
 371 open SRC, '>.modulemanager' or die "can't write installed versions to .modulemanager, won't be able to track upgrades properly: $!";
 372 foreach my $key (keys %mod_versions)
 373 {
 374         print SRC "$key $mod_versions{$key}\n";
 375 }
 376 close SRC;
 377
 378 print "Finished!\n";