tools/genssl

   1 #!/usr/bin/env perl
   2 #
   3 # InspIRCd -- Internet Relay Chat Daemon
   4 #
   5 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
   6 #   Copyright (C) 2007 Craig Edwards <craigedwards@brainbox.cc>
   7 #   Copyright (C) 2013 Peter Powell <petpow@saberuk.com>
   8 #
   9 # This file is part of InspIRCd.  InspIRCd is free software: you can
  10 # redistribute it and/or modify it under the terms of the GNU General Public
  11 # License as published by the Free Software Foundation, version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  15 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  16 # details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 #
  21
  22
  23 BEGIN {
  24         require 5.8.0;
  25 }
  26
  27 use strict;
  28 use warnings FATAL => qw(all);
  29
  30 use File::Temp();
  31
  32 # IMPORTANT: This script has to be able to run by itself so that it can be used
  33 #            by binary distributions where the make/utilities.pm module will not
  34 #            be available!
  35
  36 sub prompt($$) {
  37         my ($question, $default) = @_;
  38         print "$question\n";
  39         print "[$default] => ";
  40         chomp(my $answer = <STDIN>);
  41         print "\n";
  42         return $answer ? $answer : $default;
  43 }
  44
  45 if ($#ARGV != 0 || $ARGV[0] !~ /^(?:auto|gnutls|openssl)$/i) {
  46         print "Syntax: genssl <auto|gnutls|openssl>\n";
  47         exit 1;
  48 }
  49
  50 # On OS X the GnuTLS certtool is prefixed to avoid collision with the system certtool.
  51 my $certtool = $^O eq 'darwin' ? 'gnutls-certtool' : 'certtool';
  52
  53 # Check whether the user has the required tools installed.
  54 my $has_gnutls = `$certtool --version v 2>/dev/null`;
  55 my $has_openssl = !system 'openssl version >/dev/null 2>&1';
  56
  57 # The framework the user has specified.
  58 my $tool = lc $ARGV[0];
  59
  60 # If the user has not explicitly specified a framework then detect one.
  61 if ($tool eq 'auto') {
  62         if ($has_gnutls) {
  63                 $tool = 'gnutls';
  64         } elsif ($has_openssl) {
  65                 $tool = 'openssl';
  66         } else {
  67                 print STDERR "SSL generation failed: could not find $certtool or openssl in the PATH!\n";
  68                 exit 1;
  69         }
  70 } elsif ($tool eq 'gnutls' && !$has_gnutls) {
  71         print STDERR "SSL generation failed: could not find '$certtool' in the PATH!\n";
  72         exit 1;
  73 } elsif ($tool eq 'openssl' && !$has_openssl) {
  74         print STDERR "SSL generation failed: could not find 'openssl' in the PATH!\n";
  75         exit 1;
  76 }
  77
  78 # Harvest information needed to generate the certificate.
  79 my $common_name = prompt('What is the hostname of your server?', 'irc.example.com');
  80 my $email = prompt('What email address can you be contacted at?', 'example@example.com');
  81 my $unit = prompt('What is the name of your unit?', 'Server Admins');
  82 my $organization = prompt('What is the name of your organization?', 'Example IRC Network');
  83 my $city = prompt('What city are you located in?', 'Example City');
  84 my $state = prompt('What state are you located in?', 'Example State');
  85 my $country = prompt('What is the ISO 3166-1 code for the country you are located in?', 'XZ');
  86 my $days = prompt('How many days do you want your certificate to be valid for?', '365');
  87
  88 # Contains the SSL certificate in DER form.
  89 my $dercert;
  90
  91 # Contains the exit code of openssl/gnutls-certtool.
  92 my $status = 0;
  93
  94 if ($tool eq 'gnutls') {
  95         $has_gnutls =~ /certtool.+?(\d+\.\d+)/;
  96         my $sec_param = $1 lt '2.10' ? '--bits 2048' : '--sec-param normal';
  97         my $tmp = new File::Temp();
  98         print $tmp <<__GNUTLS_END__;
  99 cn              = "$common_name"
 100 email           = "$email"
 101 unit            = "$unit"
 102 organization    = "$organization"
 103 locality        = "$city"
 104 state           = "$state"
 105 country         = "$country"
 106 expiration_days = $days
 107 tls_www_client
 108 tls_www_server
 109 signing_key
 110 encryption_key
 111 cert_signing_key
 112 crl_signing_key
 113 code_signing_key
 114 ocsp_signing_key
 115 time_stamping_key
 116 __GNUTLS_END__
 117         close($tmp);
 118         $status ||= system "$certtool --generate-privkey $sec_param --outfile key.pem";
 119         $status ||= system "$certtool --generate-self-signed --load-privkey key.pem --outfile cert.pem --template $tmp";
 120         $status ||= system "$certtool --generate-dh-params $sec_param --outfile dhparams.pem";
 121         $dercert = `$certtool --certificate-info --infile cert.pem --outder` unless $status;
 122 } elsif ($tool eq 'openssl') {
 123         my $tmp = new File::Temp();
 124         print $tmp <<__OPENSSL_END__;
 125 $country
 126 $state
 127 $city
 128 $organization
 129 $unit
 130 $common_name
 131 $email
 132 __OPENSSL_END__
 133         close($tmp);
 134         $status ||= system "cat $tmp | openssl req -x509 -nodes -newkey rsa:2048 -keyout key.pem -out cert.pem -days $days 2>/dev/null";
 135         $status ||= system 'openssl dhparam -out dhparams.pem 2048';
 136         $dercert = `openssl x509 -in cert.pem -outform DER` unless $status;
 137 }
 138
 139 if ($status) {
 140         print STDERR "SSL generation failed: $tool exited with a non-zero status!\n";
 141         exit 1;
 142 }
 143
 144 if (defined $dercert && eval 'use Digest::SHA; 1') {
 145         my $hash = Digest::SHA->new(256);
 146         $hash->add($dercert);
 147         print "\nAdd this TLSA record to your domain for DANE support:\n";
 148         print "_6697._tcp." . $common_name . " TLSA 3 0 1 " . $hash->hexdigest . "\n";
 149 }