tools/mkheaders

   1 #!/usr/bin/env perl
   2 #
   3 # InspIRCd -- Internet Relay Chat Daemon
   4 #
   5 #   Copyright (C) 2020-2021 Sadie Powell <sadie@witchery.services>
   6 #
   7 # This file is part of InspIRCd.  InspIRCd is free software: you can
   8 # redistribute it and/or modify it under the terms of the GNU General Public
   9 # License as published by the Free Software Foundation, version 2.
  10 #
  11 # This program is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  14 # details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19
  20
  21 use v5.10.0;
  22 use strict;
  23 use warnings FATAL => qw(all);
  24
  25 use File::Basename qw(dirname);
  26 use File::Util     ();
  27 use FindBin        qw($RealDir);
  28 use List::Util     qw(uniq);
  29 use POSIX          qw(strftime);
  30
  31 use lib dirname $RealDir;
  32 use make::common;
  33 use make::console;
  34
  35 my @ignored_revisions = (
  36         '0b4285abd12323920d92fee51e199edd7527dbec', # adding copyright headers
  37         '46a39046196f55b52336e19662bb7bac85b731ac', # adding copyright headers
  38         '4a6fedd9324d87349a806c9c1d0ae6e7d3c1fd38', # mass-updating descriptions
  39         '56375392ba94f2552bbeeeab4fd39e1e50295525', # sadie's name change
  40         'bab14f0dd2345c9d7dcbc47c918563709e1ac094', # peavey breaking line endings
  41         'f2acdbc3820f0f4f5ef76a0a64e73d2a320df91f', # peavey fixing line endings
  42 );
  43
  44 my @paths = File::Util->new->list_dir(dirname($RealDir) => { recurse => 1 });
  45 my @updated;
  46 for my $path (@paths) {
  47         next unless -f $path;
  48         next if $path =~ /\/\./;
  49         next if $path =~ /\/build\//;
  50         next if $path =~ /\/vendor\//;
  51
  52         if (system "git ls-files --error-unmatch -- $path 1>/dev/null 2>/dev/null") {
  53                 say STDERR console_format "Skipping <|YELLOW $path|> as it has not been committed." if defined $ENV{MKHEADERS_VERBOSE};
  54                 next;
  55         }
  56
  57         open(my $fh, $path) or print_error "unable to read from $path: $!";
  58         my ($copyright, $indent, @lines);
  59         for my $line (<$fh>) {
  60                 chomp $line;
  61                 if ($line =~ /^([^0-9A-Za-z]+\s)Copyright\s+\(C\)\s+[^<]+\s+<[^>]+>$/) {
  62                         $copyright = scalar @lines;
  63                         $indent = $1;
  64                 } else {
  65                         push @lines, $line;
  66                 }
  67         }
  68         close $fh;
  69
  70         if (defined $copyright) {
  71                 say console_format "Updating copyright headers in <|GREEN $path|>." if defined $ENV{MKHEADERS_VERBOSE};
  72                 my (%authors, $commit, %commits);
  73                 my $ignored_args = join ' ', map { "--ignore-rev $_" } @ignored_revisions;
  74                 for my $line (split /\n+/, `git blame $ignored_args --incremental -M -w HEAD -- $path`) {
  75                         if ($line =~ /^([0-9a-f]{40})(?:\s\d+){3}$/) {
  76                                 $commit = $1;
  77                                 $commits{$commit} //= {};
  78                         } elsif ($line =~ /^author (.+)/) {
  79                                 $commits{$commit}->{NAME} = $1;
  80                         } elsif ($line =~ /^author-mail <(.+)>/) {
  81                                 $commits{$commit}->{EMAIL} = $1;
  82                         } elsif ($line =~ /^author-time (.+)/) {
  83                                 $commits{$commit}->{YEAR} = strftime '%Y', gmtime $1;
  84                         } elsif ($line =~ /^filename /) {
  85                                 my $display = sprintf "%s <%s>", $commits{$commit}->{NAME}, $commits{$commit}->{EMAIL};
  86                                 $authors{$display} //= [];
  87                                 push @{$authors{$display}}, $commits{$commit}->{YEAR};
  88                                 my $details = `git rev-list --format=%B --max-count=1 $commit`;
  89                                 while ($details =~ /co-authored-by: ([^<]+<[^>]+>)/gi) {
  90                                         $authors{$1} //= [];
  91                                         push @{$authors{$1}}, $commits{$commit}->{YEAR};
  92                                 }
  93                                 undef $commit;
  94                         }
  95                 }
  96
  97                 my @copyrights;
  98                 while (my ($display, $years) = each %authors) {
  99                         next if $display eq 'InspIRCd Robot <noreply@inspircd.org>';
 100                         my ($last_year, $start_year, @year_ranges);
 101                         for my $year (uniq sort @$years) {
 102                                 if (!defined $last_year) {
 103                                         $start_year = $last_year = $year
 104                                 } elsif ($year == $last_year + 1) {
 105                                         $last_year = $year;
 106                                 } else {
 107                                         if ($last_year == $start_year) {
 108                                                 push @year_ranges, $last_year;
 109                                         } else {
 110                                                 push @year_ranges, "$start_year-$last_year";
 111                                         }
 112                                         $start_year = $last_year = $year;
 113                                 }
 114                         }
 115                         if (defined $last_year) {
 116                                 if ($last_year == $start_year) {
 117                                         push @year_ranges, $last_year;
 118                                 } else {
 119                                         push @year_ranges, "$start_year-$last_year";
 120                                 }
 121                         }
 122
 123                         my $joined_years = join ', ', @year_ranges;
 124                         push @copyrights, "${\$indent}Copyright (C) $joined_years $display";
 125                 }
 126
 127                 splice @lines, $copyright, 0, reverse sort @copyrights;
 128                 open(my $fh, '>', $path) or print_error "unable to write to $path: $!";
 129                 for my $line (@lines) {
 130                         say $fh $line;
 131                 }
 132                 close $fh;
 133                 push @updated, $path;
 134         } else {
 135                 say STDERR console_format "Skipping <|YELLOW $path|> as it contains no copyright headers." if defined $ENV{MKHEADERS_VERBOSE};
 136         }
 137 }
 138
 139 execute 'git', 'commit',
 140         '--author', 'InspIRCd Robot <noreply@inspircd.org>',
 141         '--message', 'Update copyright headers.',
 142         '--', @updated;