tools/mkheaders

   1 #!/usr/bin/env perl
   2 #
   3 # InspIRCd -- Internet Relay Chat Daemon
   4 #
   5 #   Copyright (C) 2020 Sadie Powell <sadie@witchery.services>
   6 #
   7 # This file is part of InspIRCd.  InspIRCd is free software: you can
   8 # redistribute it and/or modify it under the terms of the GNU General Public
   9 # License as published by the Free Software Foundation, version 2.
  10 #
  11 # This program is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  14 # details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19
  20
  21 BEGIN {
  22         require 5.10.0;
  23         unless (-f 'configure') {
  24                 print "Error: $0 must be run from the main source directory!\n";
  25                 exit 1;
  26         }
  27 }
  28
  29 use feature ':5.10';
  30 use strict;
  31 use warnings FATAL => qw(all);
  32
  33 use File::Basename qw(dirname);
  34 use File::Util     ();
  35 use FindBin        qw($RealDir);
  36 use List::Util     qw(uniq);
  37 use POSIX          qw(strftime);
  38
  39 use lib dirname $RealDir;
  40 use make::common;
  41 use make::console;
  42
  43 my @ignored_revisions = (
  44         '0b4285abd12323920d92fee51e199edd7527dbec', # adding copyright headers
  45         '46a39046196f55b52336e19662bb7bac85b731ac', # adding copyright headers
  46         '56375392ba94f2552bbeeeab4fd39e1e50295525', # sadie's name change
  47         'bab14f0dd2345c9d7dcbc47c918563709e1ac094', # peavey breaking line endings
  48         'f2acdbc3820f0f4f5ef76a0a64e73d2a320df91f', # peavey fixing line endings
  49 );
  50
  51 my @paths = File::Util->new->list_dir('.' => { recurse => 1 });
  52 my @updated;
  53 for my $path (@paths) {
  54         next unless -f $path;
  55         next if $path =~ /\/\./;
  56         next if $path =~ /\/vendor\//;
  57
  58         if (system "git ls-files --error-unmatch -- $path 1>/dev/null 2>/dev/null") {
  59                 print_format "Skipping <|YELLOW $path|> as it has not been committed.\n" if defined $ENV{MKHEADERS_VERBOSE};
  60                 next;
  61         }
  62
  63         open(my $fh, $path) or print_error "unable to read from $path: $!";
  64         my ($copyright, $indent, @lines);
  65         for my $line (<$fh>) {
  66                 chomp $line;
  67                 if ($line =~ /^([^0-9A-Za-z]+\s)Copyright\s+\(C\)\s+[^<]+\s+<[^>]+>$/) {
  68                         $copyright = scalar @lines;
  69                         $indent = $1;
  70                 } else {
  71                         push @lines, $line;
  72                 }
  73         }
  74         close $fh;
  75
  76         if (defined $copyright) {
  77                 print_format "Updating copyright headers in <|GREEN $path|>.\n" if defined $ENV{MKHEADERS_VERBOSE};
  78                 my (%author, %authors);
  79                 my $ignored_args = join ' ', map { "--ignore-rev $_" } @ignored_revisions;
  80                 for my $line (split /\n+/, `git blame $ignored_args --incremental -w HEAD -- $path`) {
  81                         if ($line =~ /^([0-9a-f]{40})(?:\s\d+){3}$/) {
  82                                 $author{COMMITS} //= [];
  83                                 push @{$author{COMMITS}}, $1;
  84                         } elsif ($line =~ /^author (.+)/) {
  85                                 $author{NAME} = $1;
  86                         } elsif ($line =~ /^author-mail <(.+)>/) {
  87                                 $author{EMAIL} = $1;
  88                         } elsif ($line =~ /^author-time (.+)/) {
  89                                 $author{YEAR} = strftime '%Y', gmtime $1;
  90                         } elsif ($line =~ /^filename /) {
  91                                 next unless scalar keys %author > 1;
  92                                 my $display = sprintf "%s <%s>", $author{NAME}, $author{EMAIL};
  93                                 $authors{$display} //= [];
  94                                 push $authors{$display}, $author{YEAR};
  95                                 for my $commit (uniq @{$author{COMMITS}}) {
  96                                         my $details = `git rev-list --format=%B --max-count=1 $commit`;
  97                                         while ($details =~ /co-authored-by: ([^<]+<[^>]+>)/gi) {
  98                                                 $authors{$1} //= [];
  99                                                 push $authors{$1}, $author{YEAR};
 100                                         }
 101                                 }
 102                                 undef %author;
 103                         }
 104                 }
 105
 106                 my @copyrights;
 107                 while (my ($display, $years) = each %authors) {
 108                         next if $display eq 'InspIRCd Robot <noreply@inspircd.org>';
 109                         my ($last_year, $start_year, @year_ranges);
 110                         for my $year (uniq sort @$years) {
 111                                 if (!defined $last_year) {
 112                                         $start_year = $last_year = $year
 113                                 } elsif ($year == $last_year + 1) {
 114                                         $last_year = $year;
 115                                 } else {
 116                                         if ($last_year == $start_year) {
 117                                                 push @year_ranges, $last_year;
 118                                         } else {
 119                                                 push @year_ranges, "$start_year-$last_year";
 120                                         }
 121                                         $start_year = $last_year = $year;
 122                                 }
 123                         }
 124                         if (defined $last_year) {
 125                                 if ($last_year == $start_year) {
 126                                         push @year_ranges, $last_year;
 127                                 } else {
 128                                         push @year_ranges, "$start_year-$last_year";
 129                                 }
 130                         }
 131
 132                         my $joined_years = join ', ', @year_ranges;
 133                         push @copyrights, "${\$indent}Copyright (C) $joined_years $display";
 134                 }
 135
 136                 splice @lines, $copyright, 0, reverse sort @copyrights;
 137                 open(my $fh, '>', $path) or print_error "unable to write to $path: $!";
 138                 for my $line (@lines) {
 139                         say $fh $line;
 140                 }
 141                 close $fh;
 142                 push @updated, $path;
 143         } else {
 144                 print_format "Skipping <|YELLOW $path|> as it contains no copyright headers.\n" if defined $ENV{MKHEADERS_VERBOSE};
 145         }
 146 }
 147
 148 execute 'git', 'commit',
 149         '--author', 'InspIRCd Robot <noreply@inspircd.org>',
 150         '--message', 'Update copyright headers.',
 151         '--', @updated;