win/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(InspIRCd CXX)
   4
   5 set(CONF_PATH "conf" CACHE PATH "Configuration file path")
   6 set(MODULE_PATH "modules" CACHE PATH "Module path")
   7 set(DATA_PATH "data" CACHE PATH "Data path")
   8 set(LOG_PATH "logs" CACHE PATH "Log file path")
   9
  10 set(EXTRA_INCLUDES "" CACHE PATH "Extra include paths")
  11 set(EXTRA_LIBS "" CACHE PATH "Extra library paths")
  12
  13 set(INSPIRCD_BASE "${CMAKE_CURRENT_SOURCE_DIR}/../")
  14
  15 # Use our own NSIS template
  16 set(CMAKE_MODULE_PATH "${INSPIRCD_BASE}/win")
  17
  18 # Grab version info from version.sh
  19 file(STRINGS "${INSPIRCD_BASE}/src/version.sh" VERSIONSH)
  20 string(REGEX REPLACE ".*InspIRCd-([0-9]*).*" "\\1" MAJOR_VERSION "${VERSIONSH}")
  21 string(REGEX REPLACE ".*InspIRCd-[0-9]*\\.([0-9]*).*" "\\1" MINOR_VERSION "${VERSIONSH}")
  22 string(REGEX REPLACE ".*InspIRCd-[0-9]*\\.[0-9]*\\.([0-9]*).*" "\\1" PATCH_VERSION "${VERSIONSH}")
  23 set(FULL_VERSION "${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}")
  24
  25 if(MSVC)
  26         # Without /SAFESEH:NO old libraries compiled with VS 2010 or older won't link correctly to VS2012 (eg, extra module libs)
  27         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
  28         set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL} /SAFESEH:NO")
  29         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /SAFESEH:NO")
  30         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /SAFESEH:NO")
  31         set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
  32         set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL} /SAFESEH:NO")
  33         set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /SAFESEH:NO")
  34         set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /SAFESEH:NO")
  35         set(CMAKE_MODULE_LINKER_FLAGS_DEBUG "${CMAKE_MODULE_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
  36         set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "${CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL} /SAFESEH:NO")
  37         set(CMAKE_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} /SAFESEH:NO")
  38         set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO} /SAFESEH:NO")
  39 endif(MSVC)
  40
  41 file(GLOB INSPIRCD_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  42 "${INSPIRCD_BASE}/win/inspircd_win32wrapper.cpp"
  43 "${INSPIRCD_BASE}/win/win32service.cpp" "${INSPIRCD_BASE}/src/*.cpp"
  44 "${INSPIRCD_BASE}/src/modes/*.cpp"
  45 "${INSPIRCD_BASE}/src/socketengines/socketengine_select.cpp"
  46 "${INSPIRCD_BASE}/src/threadengines/threadengine_win32.cpp")
  47 list(SORT INSPIRCD_SOURCES)
  48
  49 include_directories("${INSPIRCD_BASE}/win" "${INSPIRCD_BASE}/include")
  50
  51 include_directories(${EXTRA_INCLUDES})
  52 link_directories(${EXTRA_LIBS})
  53
  54 if(MSVC)
  55         add_library(win32_memory STATIC "${INSPIRCD_BASE}/win/inspircd_memory_functions.cpp")
  56 endif(MSVC)
  57
  58 configure_file("${INSPIRCD_BASE}/win/inspircd.rc.cmake" "${INSPIRCD_BASE}/win/inspircd.rc")
  59 configure_file("${INSPIRCD_BASE}/win/config.h.cmake" "${INSPIRCD_BASE}/win/config.h")
  60
  61 add_executable(inspircd ${INSPIRCD_SOURCES} "${INSPIRCD_BASE}/win/inspircd.rc")
  62 target_link_libraries(inspircd win32_memory)
  63 set_target_properties(inspircd PROPERTIES ENABLE_EXPORTS ON)
  64 install(TARGETS inspircd DESTINATION .)
  65
  66 add_subdirectory(modules)
  67
  68 # Package any DLLs in win/
  69 file(GLOB EXTRA_DLLS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "${INSPIRCD_BASE}/win/*.dll")
  70 install(FILES ${EXTRA_DLLS} DESTINATION .)
  71
  72 # Install example configs
  73 file(GLOB_RECURSE EXAMPLE_CONFIGS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "${INSPIRCD_BASE}/docs/conf/*.example")
  74 install(FILES ${EXAMPLE_CONFIGS} DESTINATION conf)
  75
  76 # Create an empty data and logs directory and install them
  77 file(MAKE_DIRECTORY ${DATA_PATH})
  78 install(DIRECTORY ${DATA_PATH} DESTINATION .)
  79 file(MAKE_DIRECTORY ${LOG_PATH})
  80 install(DIRECTORY ${LOG_PATH} DESTINATION .)
  81
  82 if(EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")
  83         include(InstallRequiredSystemLibraries)
  84
  85         set(CPACK_PACKAGE_NAME "InspIRCd IRC Daemon")
  86         set(CPACK_PACKAGE_VENDOR "InspIRCd Development Team")
  87         set(CPACK_PACKAGE_VERSION_MAJOR ${MAJOR_VERSION})
  88         set(CPACK_PACKAGE_VERSION_MINOR ${MINOR_VERSION})
  89         set(CPACK_PACKAGE_VERSION_PATCH ${PATCH_VERSION})
  90         set(CPACK_PACKAGE_FILE_NAME "InspIRCd-${FULL_VERSION}")
  91         set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/../docs/COPYING")
  92
  93         set(CPACK_GENERATOR "NSIS")
  94         set(CPACK_PACKAGE_INSTALL_DIRECTORY "InspIRCd")
  95         # NSIS has a bug with full nix paths, so this must contain at least one backslash
  96         set(CPACK_PACKAGE_ICON "${INSPIRCD_BASE}/win\\\\inspircd.ico")
  97         set(CPACK_NSIS_MUI_ICON "${INSPIRCD_BASE}/win\\\\inspircd.ico")
  98         set(CPACK_NSIS_MUI_UNIICON "${INSPIRCD_BASE}/win\\\\inspircd.ico")
  99         set(CPACK_NSIS_INSTALLED_ICON_NAME "inspircd.exe")
 100         set(CPACK_NSIS_URL_INFO_ABOUT "http://www.inspircd.org/")
 101         set(CPACK_NSIS_COMPRESSOR "/SOLID lzma")
 102
 103         include(CPack)
 104 endif(EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")