win/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(InspIRCd CXX)
   4
   5 set(CONFIG_DIR "conf" CACHE PATH "Configuration file path")
   6 set(MODULE_DIR "modules" CACHE PATH "Module path")
   7 set(DATA_DIR "data" CACHE PATH "Data path")
   8 set(LOG_DIR "logs" CACHE PATH "Log file path")
   9
  10 set(EXTRA_INCLUDES "" CACHE PATH "Extra include paths")
  11 set(EXTRA_LIBS "" CACHE PATH "Extra library paths")
  12
  13 set(INSPIRCD_BASE "${CMAKE_CURRENT_SOURCE_DIR}/../")
  14
  15 # Build with multiple processes
  16 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
  17
  18 # Use our own NSIS template
  19 set(CMAKE_MODULE_PATH "${INSPIRCD_BASE}/win")
  20
  21 # Grab version info from version.sh
  22 file(STRINGS "${INSPIRCD_BASE}/src/version.sh" VERSIONSH)
  23 string(REGEX REPLACE ".*InspIRCd-([0-9]*).*" "\\1" VERSION_MAJOR "${VERSIONSH}")
  24 string(REGEX REPLACE ".*InspIRCd-[0-9]*\\.([0-9]*).*" "\\1" VERSION_MINOR "${VERSIONSH}")
  25 string(REGEX REPLACE ".*InspIRCd-[0-9]*\\.[0-9]*\\.([0-9]*).*" "\\1" VERSION_PATCH "${VERSIONSH}")
  26
  27 if(MSVC)
  28         # Without /SAFESEH:NO old libraries compiled with VS 2010 or older won't link correctly to VS2012 (eg, extra module libs)
  29         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
  30         set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL} /SAFESEH:NO")
  31         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /SAFESEH:NO")
  32         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /SAFESEH:NO")
  33         set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
  34         set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "${CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL} /SAFESEH:NO")
  35         set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /SAFESEH:NO")
  36         set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /SAFESEH:NO")
  37         set(CMAKE_MODULE_LINKER_FLAGS_DEBUG "${CMAKE_MODULE_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
  38         set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "${CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL} /SAFESEH:NO")
  39         set(CMAKE_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} /SAFESEH:NO")
  40         set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO} /SAFESEH:NO")
  41 endif(MSVC)
  42
  43 file(GLOB INSPIRCD_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  44 "${INSPIRCD_BASE}/win/inspircd_win32wrapper.cpp"
  45 "${INSPIRCD_BASE}/win/win32service.cpp" "${INSPIRCD_BASE}/src/*.cpp"
  46 "${INSPIRCD_BASE}/src/modes/*.cpp"
  47 "${INSPIRCD_BASE}/src/socketengines/socketengine_select.cpp"
  48 "${INSPIRCD_BASE}/src/threadengines/threadengine_win32.cpp")
  49 list(SORT INSPIRCD_SOURCES)
  50
  51 include_directories("${INSPIRCD_BASE}/win" "${INSPIRCD_BASE}/include")
  52
  53 include_directories(${EXTRA_INCLUDES})
  54 link_directories(${EXTRA_LIBS})
  55
  56 if(MSVC)
  57         add_library(win32_memory STATIC "${INSPIRCD_BASE}/win/inspircd_memory_functions.cpp")
  58 endif(MSVC)
  59
  60 configure_file("${INSPIRCD_BASE}/win/inspircd.rc.cmake" "${INSPIRCD_BASE}/win/inspircd.rc")
  61 configure_file("${INSPIRCD_BASE}/make/template/config.h" "${INSPIRCD_BASE}/include/config.h")
  62
  63 add_executable(inspircd ${INSPIRCD_SOURCES} "${INSPIRCD_BASE}/win/inspircd.rc")
  64 target_link_libraries(inspircd win32_memory)
  65 set_target_properties(inspircd PROPERTIES ENABLE_EXPORTS ON)
  66 install(TARGETS inspircd DESTINATION .)
  67
  68 add_subdirectory(modules)
  69
  70 # Package any DLLs in win/
  71 file(GLOB EXTRA_DLLS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "${INSPIRCD_BASE}/win/*.dll")
  72 install(FILES ${EXTRA_DLLS} DESTINATION .)
  73
  74 # Install example configs
  75 file(GLOB_RECURSE EXAMPLE_CONFIGS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "${INSPIRCD_BASE}/docs/conf/*.example")
  76 install(FILES ${EXAMPLE_CONFIGS} DESTINATION conf)
  77
  78 # Install nationalchars files
  79 file(GLOB_RECURSE EXAMPLE_LOCALES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "${INSPIRCD_BASE}/locales/*")
  80 install(FILES ${EXAMPLE_LOCALES} DESTINATION locales)
  81
  82 # Create an empty data and logs directory and install them
  83 file(MAKE_DIRECTORY ${DATA_DIR})
  84 install(DIRECTORY ${DATA_DIR} DESTINATION .)
  85 file(MAKE_DIRECTORY ${LOG_DIR})
  86 install(DIRECTORY ${LOG_DIR} DESTINATION .)
  87
  88 if(EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")
  89         set(CMAKE_INSTALL_SYSTEM_RUNTIME_DESTINATION ".") # place runtime libraries next to InspIRCd binary
  90         include(InstallRequiredSystemLibraries)
  91
  92         set(CPACK_PACKAGE_NAME "InspIRCd IRC Daemon")
  93         set(CPACK_PACKAGE_VENDOR "InspIRCd Development Team")
  94         set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
  95         set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
  96         set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
  97         set(CPACK_PACKAGE_FILE_NAME "InspIRCd-${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  98         set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/../docs/COPYING")
  99
 100         set(CPACK_GENERATOR "NSIS")
 101         set(CPACK_PACKAGE_INSTALL_DIRECTORY "InspIRCd")
 102         # NSIS has a bug with full nix paths, so this must contain at least one backslash
 103         set(CPACK_PACKAGE_ICON "${INSPIRCD_BASE}/win\\\\inspircd.ico")
 104         set(CPACK_NSIS_MUI_ICON "${INSPIRCD_BASE}/win\\\\inspircd.ico")
 105         set(CPACK_NSIS_MUI_UNIICON "${INSPIRCD_BASE}/win\\\\inspircd.ico")
 106         set(CPACK_NSIS_INSTALLED_ICON_NAME "inspircd.exe")
 107         set(CPACK_NSIS_URL_INFO_ABOUT "http://www.inspircd.org/")
 108         set(CPACK_NSIS_COMPRESSOR "/SOLID zlib")
 109
 110         include(CPack)
 111 endif(EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")