win/inspircd.nsi

   1 ; *       +------------------------------------+
   2 ; *       | Inspire Internet Relay Chat Daemon |
   3 ; *       +------------------------------------+
   4 ; *
   5 ; *  InspIRCd: (C) 2002-2007 InspIRCd Development Team
   6 ; * See: http://www.inspircd.org/wiki/index.php/Credits
   7 ; *
   8 ; * This program is free but copyrighted software; see
   9 ; *            the file COPYING for details.
  10 ; *
  11 ; * ---------------------------------------------------
  12
  13 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  14
  15                        ;;;; SET THE BUILD TO BE PACKAGED HERE ;;;;
  16
  17 !define BUILD "release"
  18
  19 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  20
  21 ; HM NIS Edit Wizard helper defines
  22 !define PRODUCT_NAME "InspIRCd"
  23 !define PRODUCT_VERSION "1.2"
  24 !define PRODUCT_PUBLISHER "InspIRCd Development Team"
  25 !define PRODUCT_WEB_SITE "http://www.inspircd.org/"
  26 !define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\inspircd.exe"
  27 !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  28 !define PRODUCT_UNINST_ROOT_KEY "HKLM"
  29 !define DOT_MAJOR "2"
  30 !define DOT_MINOR "0"
  31
  32 SetCompressor bzip2
  33
  34 ; MUI 1.67 compatible ------
  35 !include "MUI.nsh"
  36
  37 ; MUI Settings
  38 !define MUI_ABORTWARNING
  39 !define MUI_ICON "inspircd.ico"
  40 !define MUI_UNICON "inspircd.ico"
  41
  42 ; Welcome page
  43 !insertmacro MUI_PAGE_WELCOME
  44 ; License page
  45 !define MUI_LICENSEPAGE_CHECKBOX
  46 !insertmacro MUI_PAGE_LICENSE "..\docs\COPYING"
  47 ; directory page
  48 Page directory
  49 ; Components page
  50 !insertmacro MUI_PAGE_COMPONENTS
  51 ; Instfiles page
  52 !insertmacro MUI_PAGE_INSTFILES
  53 ; Finish page
  54 !define MUI_FINISHPAGE_RUN "$INSTDIR\InspGUI.exe"
  55 !insertmacro MUI_PAGE_FINISH
  56
  57 ; Uninstaller pages
  58 !insertmacro MUI_UNPAGE_INSTFILES
  59
  60 ; Language files
  61 !insertmacro MUI_LANGUAGE "English"
  62
  63 ; Reserve files
  64 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
  65
  66 ; MUI end ------
  67
  68 Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  69 OutFile "Setup.exe"
  70 InstallDir "$PROGRAMFILES\InspIRCd"
  71 InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
  72 ShowInstDetails show
  73 ShowUnInstDetails show
  74
  75 Function IsDotNetInstalled
  76
  77   StrCpy $0 "0"
  78   StrCpy $1 "SOFTWARE\Microsoft\.NETFramework" ;registry entry to look in.
  79   StrCpy $2 0
  80
  81   StartEnum:
  82     ;Enumerate the versions installed.
  83     EnumRegKey $3 HKLM "$1\policy" $2
  84
  85     ;If we don't find any versions installed, it's not here.
  86     StrCmp $3 "" noDotNet notEmpty
  87
  88     ;We found something.
  89     notEmpty:
  90       ;Find out if the RegKey starts with 'v'.
  91       ;If it doesn't, goto the next key.
  92       StrCpy $4 $3 1 0
  93       StrCmp $4 "v" +1 goNext
  94       StrCpy $4 $3 1 1
  95
  96       ;It starts with 'v'.  Now check to see how the installed major version
  97       ;relates to our required major version.
  98       ;If it's equal check the minor version, if it's greater,
  99       ;we found a good RegKey.
 100       IntCmp $4 ${DOT_MAJOR} +1 goNext yesDotNetReg
 101       ;Check the minor version.  If it's equal or greater to our requested
 102       ;version then we're good.
 103       StrCpy $4 $3 1 3
 104       IntCmp $4 ${DOT_MINOR} yesDotNetReg goNext yesDotNetReg
 105
 106     goNext:
 107       ;Go to the next RegKey.
 108       IntOp $2 $2 + 1
 109       goto StartEnum
 110
 111   yesDotNetReg:
 112     ;Now that we've found a good RegKey, let's make sure it's actually
 113     ;installed by getting the install path and checking to see if the
 114     ;mscorlib.dll exists.
 115     EnumRegValue $2 HKLM "$1\policy\$3" 0
 116     ;$2 should equal whatever comes after the major and minor versions
 117     ;(ie, v1.1.4322)
 118     StrCmp $2 "" noDotNet
 119     ReadRegStr $4 HKLM $1 "InstallRoot"
 120     ;Hopefully the install root isn't empty.
 121     StrCmp $4 "" noDotNet
 122     ;build the actuall directory path to mscorlib.dll.
 123     StrCpy $4 "$4$3.$2\mscorlib.dll"
 124     IfFileExists $4 yesDotNet noDotNet
 125
 126   noDotNet:
 127     MessageBox MB_OK "You do not have have v${DOT_MAJOR}.${DOT_MINOR} or greater of the .NET framework installed. This is required for the InspIRCd Monitor, however you can still launch the IRCd manually."
 128
 129   yesDotNet:
 130     ;Everything checks out.  Go on with the rest of the installation.
 131
 132 FunctionEnd
 133
 134 Section "Binary Executable" SEC01
 135   Call IsDotNetInstalled
 136   SetOutPath "$TEMP"
 137   SetOverwrite ifnewer
 138   File "vcredist_x86.exe"
 139   ExecWait "$TEMP\vcredist_x86.exe"
 140   SetOutPath "$INSTDIR"
 141   SetOverwrite ifnewer
 142   File "..\bin\${BUILD}\InspGUI.exe"
 143   CreateDirectory "$SMPROGRAMS\InspIRCd"
 144   CreateShortCut "$SMPROGRAMS\InspIRCd\InspIRCd.lnk" "$INSTDIR\InspGUI.exe"
 145   SetOutPath "$INSTDIR\bin"
 146   SetOverwrite ifnewer
 147   File "..\bin\${BUILD}\bin\inspircd.exe"
 148 SectionEnd
 149
 150 Section "Config Files" SEC02
 151   SetOutPath "$INSTDIR\conf"
 152   File "..\conf\inspircd.motd.example"
 153   File "..\conf\inspircd.helpop-full.example"
 154   File "..\conf\inspircd.helpop.example"
 155   File "..\conf\inspircd.filter.example"
 156   File "..\docs\inspircd.conf.example"
 157   File "..\conf\inspircd.censor.example"
 158   File "..\conf\inspircd.rules.example"
 159   File "..\conf\inspircd.quotes.example"
 160 SectionEnd
 161
 162 Section "Command Handlers" SEC03
 163   SetOutPath "$INSTDIR\lib"
 164   File "..\bin\${BUILD}\lib\cmd_*.so"
 165 SectionEnd
 166
 167 Section "Modules" SEC04
 168   SetOutPath "$INSTDIR\modules"
 169   File "..\bin\${BUILD}\modules\m_*.so"
 170 SectionEnd
 171
 172 Section  "SSL Modules" SEC05
 173   SetOutPath "$INSTDIR\bin"
 174   SetOverwrite ifnewer
 175   File "..\bin\${BUILD}\bin\libgcrypt-11.dll"
 176   File "..\bin\${BUILD}\bin\libgnutls-13.dll"
 177   File "..\bin\${BUILD}\bin\libgnutls-extra-13.dll"
 178   File "..\bin\${BUILD}\bin\libgnutls-openssl-13.dll"
 179   File "..\bin\${BUILD}\bin\libgpg-error-0.dll"
 180   File "..\bin\${BUILD}\bin\libopencdk-8.dll"
 181   File "..\bin\${BUILD}\bin\libtasn1-3.dll"
 182   SetOutPath "$INSTDIR\modules"
 183   File "c:\temp\m_ssl_gnutls.so"
 184   File "c:\temp\m_sslinfo.so"
 185   File "c:\temp\m_ssl_oper_cert.so"
 186   SetOutPath "$INSTDIR\conf"
 187   SetOverwrite off
 188   File "key.pem"
 189   File "cert.pem"
 190 SectionEnd
 191
 192 Section  "Regexp Modules" SEC06
 193   SetOutPath "$INSTDIR\bin"
 194   SetOverwrite ifnewer
 195   File "..\bin\${BUILD}\bin\pcre.dll"
 196   SetOutPath "$INSTDIR\modules"
 197   File "c:\temp\m_filter_pcre.so"
 198 SectionEnd
 199
 200 Section -AdditionalIcons
 201   SetOutPath $INSTDIR
 202   WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
 203   CreateShortCut "$SMPROGRAMS\InspIRCd\InspIRCd Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url"
 204   CreateShortCut "$SMPROGRAMS\InspIRCd\Uninstall.lnk" "$INSTDIR\uninst.exe"
 205 SectionEnd
 206
 207 Section -Post
 208   WriteUninstaller "$INSTDIR\uninst.exe"
 209   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\bin\inspircd.exe"
 210   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
 211   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
 212   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bin\inspircd.exe"
 213   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
 214   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
 215   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
 216   MessageBox MB_ICONINFORMATION|MB_OK "InspIRCd was successfully installed. Remember to edit your configuration file in $INSTDIR\conf!"
 217 SectionEnd
 218
 219 ; Section descriptions
 220 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 221   !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} "Actual executable"
 222   !insertmacro MUI_DESCRIPTION_TEXT ${SEC03} "Command modules"
 223   !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} "Default configuration files"
 224   !insertmacro MUI_DESCRIPTION_TEXT ${SEC04} "Optional non-SSL modules"
 225   !insertmacro MUI_DESCRIPTION_TEXT ${SEC05} "SSL modules and GnuTLS DLL libraries"
 226   !insertmacro MUI_DESCRIPTION_TEXT ${SEC06} "Regular expression module and PCRE DLL library"
 227 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 228
 229
 230 Function un.onUninstSuccess
 231   HideWindow
 232   MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer."
 233 FunctionEnd
 234
 235 Function .onInit
 236   SectionSetFlags ${SEC01} 17
 237   SectionSetFlags ${SEC03} 17
 238   StrCpy $INSTDIR "$PROGRAMFILES\InspIRCd"
 239 FunctionEnd
 240
 241 Function un.onInit
 242   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" IDYES +2
 243   Abort
 244 FunctionEnd
 245
 246 Section Uninstall
 247   Delete "$INSTDIR\${PRODUCT_NAME}.url"
 248   Delete "$INSTDIR\uninst.exe"
 249   Delete "$INSTDIR\modules\m_*.so"
 250   Delete "$INSTDIR\lib\cmd_*.so"
 251   Delete "$INSTDIR\conf\inspircd.quotes.example"
 252   Delete "$INSTDIR\conf\inspircd.rules.example"
 253   Delete "$INSTDIR\conf\inspircd.censor.example"
 254   Delete "$INSTDIR\conf\inspircd.conf.example"
 255   Delete "$INSTDIR\conf\inspircd.filter.example"
 256   Delete "$INSTDIR\conf\inspircd.helpop.example"
 257   Delete "$INSTDIR\conf\inspircd.helpop-full.example"
 258   Delete "$INSTDIR\conf\inspircd.motd.example"
 259   Delete "$INSTDIR\bin\inspircd.exe"
 260   Delete "$INSTDIR\bin\*.dll"
 261   Delete "$INSTDIR\InspGUI.exe"
 262   Delete "$SMPROGRAMS\InspIRCd\Uninstall.lnk"
 263   Delete "$SMPROGRAMS\InspIRCd\InspIRCd Website.lnk"
 264   Delete "$SMPROGRAMS\InspIRCd\InspIRCd.lnk"
 265
 266   RMDir "$SMPROGRAMS\InspIRCd"
 267   RMDir "$INSTDIR\modules"
 268   RMDir "$INSTDIR\lib"
 269   RMDir "$INSTDIR\conf"
 270   RMDir "$INSTDIR\bin"
 271   RMDir "$INSTDIR"
 272
 273   DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
 274   DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
 275   SetAutoClose true
 276 SectionEnd