configure

   1 #!/usr/bin/env perl
   2 #
   3 # InspIRCd -- Internet Relay Chat Daemon
   4 #
   5 #   Copyright (C) 2020 Nicole Kleinhoff <ilbelkyr@shalture.org>
   6 #   Copyright (C) 2020 Daniel Vassdal <shutter@canternet.org>
   7 #   Copyright (C) 2019 Matt Schatz <genius3000@g3k.solutions>
   8 #   Copyright (C) 2013-2021 Sadie Powell <sadie@witchery.services>
   9 #   Copyright (C) 2012, 2019 Robby <robby@chatbelgie.be>
  10 #   Copyright (C) 2012 ChrisTX <xpipe@hotmail.de>
  11 #   Copyright (C) 2010 Daniel De Graaf <danieldg@inspircd.org>
  12 #   Copyright (C) 2008 Thomas Stagner <aquanight@inspircd.org>
  13 #   Copyright (C) 2008 Robin Burchell <robin+git@viroteck.net>
  14 #   Copyright (C) 2007 Dennis Friis <peavey@inspircd.org>
  15 #   Copyright (C) 2006-2008 Craig Edwards <brain@inspircd.org>
  16 #
  17 # This file is part of InspIRCd.  InspIRCd is free software: you can
  18 # redistribute it and/or modify it under the terms of the GNU General Public
  19 # License as published by the Free Software Foundation, version 2.
  20 #
  21 # This program is distributed in the hope that it will be useful, but WITHOUT
  22 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  23 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  24 # details.
  25 #
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  28 #
  29
  30
  31 use v5.10.0;
  32 use strict;
  33 use warnings FATAL => qw(all);
  34
  35 use Cwd                   qw(getcwd);
  36 use File::Basename        qw(basename);
  37 use File::Copy            ();
  38 use File::Spec::Functions qw(abs2rel catfile catdir rel2abs);
  39 use FindBin               qw($RealDir);
  40 use Getopt::Long          qw(GetOptions);
  41 use POSIX                 qw(getgid getuid);
  42
  43 use lib $RealDir;
  44 use make::common;
  45 use make::configure;
  46 use make::console;
  47 use make::directive;
  48
  49 my ($opt_binary_dir,
  50     $opt_config_dir,
  51     $opt_data_dir,
  52     $opt_development,
  53     $opt_disable_auto_extras,
  54     $opt_disable_interactive,
  55     $opt_disable_ownership,
  56     $opt_distribution_label,
  57     $opt_example_dir,
  58     $opt_gid,
  59     $opt_log_dir,
  60     $opt_manual_dir,
  61     $opt_module_dir,
  62     $opt_portable,
  63     $opt_prefix,
  64     $opt_runtime_dir,
  65     $opt_script_dir,
  66     $opt_socketengine,
  67     $opt_system,
  68     $opt_uid);
  69
  70 sub list_extras ();
  71
  72 sub enable_extras (@);
  73
  74 sub disable_extras (@);
  75
  76 my @opt_enableextras;
  77 my @opt_disableextras;
  78
  79 exit 1 unless GetOptions(
  80         'clean'  => \&cmd_clean,
  81         'help'   => \&cmd_help,
  82         'update' => \&cmd_update,
  83
  84         'binary-dir=s'         => \$opt_binary_dir,
  85         'config-dir=s'         => \$opt_config_dir,
  86         'data-dir=s'           => \$opt_data_dir,
  87         'development'          => \$opt_development,
  88         'disable-auto-extras'  => \$opt_disable_auto_extras,
  89         'disable-interactive'  => \$opt_disable_interactive,
  90         'disable-ownership'    => \$opt_disable_ownership,
  91         'distribution-label=s' => \$opt_distribution_label,
  92         'example-dir=s'        => \$opt_example_dir,
  93         'gid=s'                => \$opt_gid,
  94         'log-dir=s'            => \$opt_log_dir,
  95         'manual-dir=s'         => \$opt_manual_dir,
  96         'module-dir=s'         => \$opt_module_dir,
  97         'portable'             => \$opt_portable,
  98         'prefix=s'             => \$opt_prefix,
  99         'runtime-dir=s'        => \$opt_runtime_dir,
 100         'script-dir=s'         => \$opt_script_dir,
 101         'socketengine=s'       => \$opt_socketengine,
 102         'system'               => \$opt_system,
 103         'uid=s'                => \$opt_uid,
 104
 105         'disable-extras=s@' => \@opt_disableextras,
 106         'enable-extras=s@'  => \@opt_enableextras,
 107         'list-extras'       => sub { list_extras; exit 0; },
 108 );
 109
 110 if (scalar(@opt_enableextras) + scalar(@opt_disableextras) > 0) {
 111         @opt_enableextras = grep { /\S/ } split /[, ]+/, join(',', @opt_enableextras);
 112         @opt_disableextras = grep { /\S/ } split /[, ]+/, join(',', @opt_disableextras);
 113         enable_extras(@opt_enableextras);
 114         disable_extras(@opt_disableextras);
 115         list_extras;
 116         print "Remember: YOU are responsible for making sure any libraries needed have been installed!\n";
 117         exit 0;
 118 }
 119
 120 our $interactive = !(
 121         !-t STDIN ||
 122         !-t STDOUT ||
 123         defined $opt_binary_dir ||
 124         defined $opt_config_dir ||
 125         defined $opt_data_dir ||
 126         defined $opt_development ||
 127         defined $opt_disable_auto_extras ||
 128         defined $opt_disable_interactive ||
 129         defined $opt_disable_ownership ||
 130         defined $opt_distribution_label ||
 131         defined $opt_example_dir ||
 132         defined $opt_gid ||
 133         defined $opt_log_dir ||
 134         defined $opt_manual_dir ||
 135         defined $opt_module_dir ||
 136         defined $opt_portable ||
 137         defined $opt_prefix ||
 138         defined $opt_runtime_dir ||
 139         defined $opt_script_dir ||
 140         defined $opt_socketengine ||
 141         defined $opt_system ||
 142         defined $opt_uid
 143 );
 144
 145 my %version = get_version $opt_distribution_label;
 146 say console_format "<|BOLD Configuring InspIRCd $version{FULL} on $^O.|>";
 147
 148 my %config;
 149 if ($interactive) {
 150         %config = read_config_file(CONFIGURE_CACHE_FILE);
 151         run_test abs2rel(CONFIGURE_CACHE_FILE, $RealDir), %config;
 152         if (!defined $config{VERSION}) {
 153                 $config{VERSION} = CONFIGURE_CACHE_VERSION;
 154         } elsif ($config{VERSION} != CONFIGURE_CACHE_VERSION) {
 155                 print_warning "ignoring contents of ${\CONFIGURE_CACHE_FILE} as it was generated by an incompatible version of $0!";
 156                 %config = ('VERSION', CONFIGURE_CACHE_VERSION);
 157         }
 158 }
 159
 160 $config{CXX} = find_compiler($config{CXX} // $ENV{CXX});
 161 unless ($config{CXX}) {
 162         say 'A suitable C++ compiler could not be detected on your system!';
 163         unless ($interactive) {
 164                 say 'Set the CXX environment variable to the path to a C++ compiler binary if this is incorrect.';
 165                 exit 1;
 166         }
 167         until ($config{CXX}) {
 168                 my $compiler_path = prompt_string 1, 'Please enter the path to a C++ compiler binary:', 'c++';
 169                 $config{CXX} = find_compiler $compiler_path;
 170         }
 171 }
 172 my %compiler = get_compiler_info($config{CXX});
 173
 174 $config{HAS_ARC4RANDOM_BUF} = run_test 'arc4random_buf()', test_file($config{CXX}, 'arc4random_buf.cpp');
 175 $config{HAS_CLOCK_GETTIME} = run_test 'clock_gettime()', test_file($config{CXX}, 'clock_gettime.cpp', $^O eq 'darwin' ? undef : '-lrt');
 176 $config{HAS_EVENTFD} = run_test 'eventfd()', test_file($config{CXX}, 'eventfd.cpp');
 177
 178 my @socketengines;
 179 push @socketengines, 'epoll'  if run_test 'epoll', test_header $config{CXX}, 'sys/epoll.h';
 180 push @socketengines, 'kqueue' if run_test 'kqueue', test_file $config{CXX}, 'kqueue.cpp';
 181 push @socketengines, 'poll'   if run_test 'poll', test_header $config{CXX}, 'poll.h';
 182 push @socketengines, 'select';
 183
 184 if (defined $opt_socketengine) {
 185         unless (grep { $_ eq $opt_socketengine } @socketengines) {
 186                 my $reason = -f "src/socketengines/socketengine_$opt_socketengine.cpp" ? 'is not available on this platform' : 'does not exist';
 187                 print_error "The socket engine you requested ($opt_socketengine) $reason!",
 188                         'Available socket engines are:',
 189                         map { "  * $_" } @socketengines;
 190         }
 191 }
 192 $config{SOCKETENGINE} = $opt_socketengine // $socketengines[0];
 193
 194 if (defined $opt_portable) {
 195         print_error '--portable and --system can not be used together!' if defined $opt_system;
 196         $config{DESTDIR}     = catfile $RealDir, 'run', '';
 197         $config{BASE_DIR}    = $opt_prefix      // '';
 198         $config{BINARY_DIR}  = $opt_binary_dir  // 'bin';
 199         $config{CONFIG_DIR}  = $opt_config_dir  // 'conf';
 200         $config{DATA_DIR}    = $opt_data_dir    // 'data';
 201         $config{EXAMPLE_DIR} = $opt_example_dir // catdir $config{CONFIG_DIR}, 'examples';
 202         $config{LOG_DIR}     = $opt_log_dir     // 'logs';
 203         $config{MANUAL_DIR}  = $opt_manual_dir  // 'manuals';
 204         $config{MODULE_DIR}  = $opt_module_dir  // 'modules';
 205         $config{RUNTIME_DIR} = $opt_runtime_dir // $config{DATA_DIR};
 206         $config{SCRIPT_DIR}  = $opt_script_dir  // $config{BASE_DIR};
 207 } elsif (defined $opt_system) {
 208         $config{BASE_DIR}    = $opt_prefix      // '/';
 209         $config{BINARY_DIR}  = $opt_binary_dir  // catdir $config{BASE_DIR}, 'usr/sbin';
 210         $config{CONFIG_DIR}  = $opt_config_dir  // catdir $config{BASE_DIR}, 'etc/inspircd';
 211         $config{DATA_DIR}    = $opt_data_dir    // catdir $config{BASE_DIR}, 'var/lib/inspircd';
 212         $config{EXAMPLE_DIR} = $opt_example_dir // catdir $config{BASE_DIR}, 'usr/share/doc/inspircd';
 213         $config{LOG_DIR}     = $opt_log_dir     // catdir $config{BASE_DIR}, 'var/log/inspircd';
 214         $config{MANUAL_DIR}  = $opt_manual_dir  // catdir $config{BASE_DIR}, 'usr/share/man/man1';
 215         $config{MODULE_DIR}  = $opt_module_dir  // catdir $config{BASE_DIR}, 'usr/lib/inspircd';
 216         $config{RUNTIME_DIR} = $opt_runtime_dir // catdir $config{BASE_DIR}, $^O eq 'linux' ? '/run/inspircd' : '/var/run/inspircd';
 217         $config{SCRIPT_DIR}  = $opt_script_dir  // catdir $config{BASE_DIR}, 'usr/share/inspircd';
 218 } else {
 219         $config{BASE_DIR}    = rel2abs $opt_prefix // $config{BASE_DIR}    // catdir $RealDir,            'run';
 220         $config{BINARY_DIR}  = $opt_binary_dir     // $config{BINARY_DIR}  // catdir $config{BASE_DIR},   'bin';
 221         $config{CONFIG_DIR}  = $opt_config_dir     // $config{CONFIG_DIR}  // catdir $config{BASE_DIR},   'conf';
 222         $config{DATA_DIR}    = $opt_data_dir       // $config{DATA_DIR}    // catdir $config{BASE_DIR},   'data';
 223         $config{EXAMPLE_DIR} = $opt_example_dir    // $config{EXAMPLE_DIR} // catdir $config{CONFIG_DIR}, 'examples';
 224         $config{LOG_DIR}     = $opt_log_dir        // $config{LOG_DIR}     // catdir $config{BASE_DIR},   'logs';
 225         $config{MANUAL_DIR}  = $opt_manual_dir     // $config{MANUAL_DIR}  // catdir $config{BASE_DIR},   'manuals';
 226         $config{MODULE_DIR}  = $opt_module_dir     // $config{MODULE_DIR}  // catdir $config{BASE_DIR},   'modules';
 227         $config{RUNTIME_DIR} = $opt_runtime_dir    // $config{RUNTIME_DIR} // $config{DATA_DIR};
 228         $config{SCRIPT_DIR}  = $opt_script_dir     // $config{SCRIPT_DIR}  // $config{BASE_DIR};
 229 }
 230
 231 # Parse --gid=123 or --gid=foo and extract the group id.
 232 my @group;
 233 if (defined $opt_disable_ownership) {
 234         @group = qw(insert-group-here . -1);
 235         print_error 'you can not use --disable-ownership and --gid at the same time!' if defined $opt_gid;
 236 } elsif (defined $opt_gid) {
 237         @group = $opt_gid =~ /^\d+$/ ? getgrgid($opt_gid) : getgrnam($opt_gid);
 238         print_error "there is no '$opt_gid' group on this system!" unless @group;
 239 } else {
 240         @group = $opt_system ? getgrnam('irc') : getgrgid($config{GID} // getgid());
 241         print_error "you need to specify a group to run as using '--gid [id|name]'!" unless @group;
 242         unless ($group[2]) {
 243                 print_warning <<"EOW";
 244 You are building as the privileged $group[0] group and have not specified
 245 an unprivileged group to run InspIRCd as.
 246
 247 This is almost never what you should do. You should probably either create a new
 248 unprivileged user/group to build and run as or pass the '--gid [id|name]' flag
 249 to specify an unprivileged group to run as.
 250 EOW
 251                 if (!prompt_bool $interactive, "Are you sure you want to build as the $group[0] group?", 0) {
 252                         # PACKAGERS: You do not need to delete this check. Use `--disable-ownership` instead.
 253                         say STDERR "If you are sure you want to build as the $group[0] group pass the --gid $group[2] flag." unless $interactive;
 254                         exit 1;
 255                 }
 256         }
 257 }
 258 $config{GROUP} = $group[0];
 259 $config{GID}   = $group[2];
 260
 261 # Parse --uid=123 or --uid=foo and extract the user id.
 262 my @user;
 263 if (defined $opt_disable_ownership) {
 264         @user = qw(insert-user-here . -1);
 265         print_error 'you can not use --disable-ownership and --uid at the same time!' if defined $opt_uid;
 266 } elsif (defined $opt_uid) {
 267         @user = $opt_uid =~ /^\d+$/ ? getpwuid($opt_uid) : getpwnam($opt_uid);
 268         print_error "there is no '$opt_uid' user on this system!" unless @user;
 269 } else {
 270         @user = $opt_system ? getpwnam('irc') : getpwuid($config{UID} // getuid());
 271         print_error "you need to specify a user to run as using '--uid [id|name]'!" unless @user;
 272         unless ($user[2]) {
 273                 print_warning <<"EOW";
 274 You are building as the privileged $user[0] user and have not specified
 275 an unprivileged user to run InspIRCd as.
 276
 277 This is almost never what you should do. You should probably either create a new
 278 unprivileged user/group to build and run as or pass the '--uid [id|name]' flag
 279 to specify an unprivileged user to run as.
 280 EOW
 281                 if (!prompt_bool $interactive, "Are you sure you want to build as the $user[0] user?", 0) {
 282                         # PACKAGERS: You do not need to delete this check. Use `--disable-ownership` instead.
 283                         say STDERR "If you are sure you want to build as the $user[0] user pass the --uid $user[2] flag." unless $interactive;
 284                         exit 1;
 285                 }
 286         }
 287 }
 288 $config{USER} = $user[0];
 289 $config{UID}  = $user[2];
 290
 291 # Warn the user about clock drifting when running on OpenVZ.
 292 if (-e '/proc/user_beancounters' || -e '/proc/vz/vzaquota') {
 293         print_warning <<'EOW';
 294 You are building InspIRCd inside of an OpenVZ container. If you
 295 plan to use InspIRCd in this container then you should make sure that NTP is
 296 configured on the Hardware Node. Failure to do so may result in clock drifting!
 297 EOW
 298 }
 299
 300 # Warn the user about OpenBSD shipping incredibly broken compilers/linkers.
 301 if ($^O eq 'openbsd') {
 302         print_warning <<'EOW';
 303 You are building InspIRCd on OpenBSD. The C++ compilers and linkers
 304 that OpenBSD ship are incredibly broken. You may have strange linker errors
 305 and crashes. Please consider using a different OS like FreeBSD/NetBSD instead.
 306 EOW
 307 }
 308
 309 # Warn about Perl versions that will not be supported in the future.
 310 if ($^V lt 'v5.26.0') {
 311         print_warning <<"EOW";
 312 You are building InspIRCd with Perl $^V. This is very old and will
 313 not be supported by the next major version of InspIRCd. Please consider updating
 314 to Perl v5.26 or newer.
 315 EOW
 316 }
 317
 318 # Warn about compiler versions that will not be supported in the future.
 319 my %future_compilers = (
 320         AppleClang => version->parse('10.0'),
 321         Clang      => version->parse('5.0'),
 322         GCC        => version->parse('7.0'),
 323 );
 324 if (exists $future_compilers{$compiler{NAME}} && $compiler{VERSION} lt $future_compilers{$compiler{NAME}}) {
 325         print_warning <<"EOW";
 326 You are building InspIRCd with $compiler{NAME} v$compiler{VERSION}. This is very old and
 327 will not be supported by the next major version of InspIRCd. Please consider
 328 updating to $compiler{NAME} v$future_compilers{$compiler{NAME}} or newer.
 329 EOW
 330 }
 331
 332 # Check that the user actually wants this version.
 333 if (defined $version{REAL_LABEL}) {
 334         print_warning <<'EOW';
 335 You are building a development version. This contains code which has
 336 not been tested as heavily and may contain various faults which could seriously
 337 affect the running of your server. It is recommended that you use a stable
 338 version instead.
 339
 340 You can obtain the latest stable version from https://www.inspircd.org or by
 341 running `<|GREEN git checkout $(git describe --abbrev=0 --tags insp3)|>` if you are
 342 installing from Git.
 343 EOW
 344         if (!prompt_bool $interactive, 'I understand this warning and want to continue anyway.', $opt_development // 0) {
 345                 say STDERR 'If you understand this warning and still want to continue pass the --development flag.' unless $interactive;
 346                 exit 1;
 347         }
 348 }
 349
 350 # Configure directory settings.
 351 my $question = <<"EOQ";
 352 Currently, InspIRCd is configured with the following paths:
 353
 354 <|BOLD Binary:|> $config{BINARY_DIR}
 355 <|BOLD Config:|> $config{CONFIG_DIR}
 356 <|BOLD Data:|>   $config{DATA_DIR}
 357 <|BOLD Log:|>    $config{LOG_DIR}
 358 <|BOLD Manual:|> $config{MANUAL_DIR}
 359 <|BOLD Module:|> $config{MODULE_DIR}
 360 <|BOLD Script:|> $config{SCRIPT_DIR}
 361
 362 Do you want to change these settings?
 363 EOQ
 364 if (prompt_bool $interactive, $question, 0) {
 365         my $original_base_dir = $config{BASE_DIR};
 366         $config{BASE_DIR} = prompt_dir $interactive, 'In what directory do you wish to install the InspIRCd base?', $config{BASE_DIR};
 367         for my $key (qw(BINARY_DIR CONFIG_DIR DATA_DIR LOG_DIR MANUAL_DIR MODULE_DIR SCRIPT_DIR)) {
 368                 $config{$key} =~ s/^\Q$original_base_dir\E/$config{BASE_DIR}/;
 369         }
 370         $config{BINARY_DIR} = prompt_dir $interactive, 'In what directory should the InspIRCd binary be placed?', $config{BINARY_DIR};
 371         $config{CONFIG_DIR} = prompt_dir $interactive, 'In what directory are configuration files to be stored?', $config{CONFIG_DIR};
 372         $config{DATA_DIR}   = prompt_dir $interactive, 'In what directory are variable data files to be stored?', $config{DATA_DIR};
 373         $config{LOG_DIR}    = prompt_dir $interactive, 'In what directory are log files to be stored?',           $config{LOG_DIR};
 374         $config{MANUAL_DIR} = prompt_dir $interactive, 'In what directory are manual pages to be placed?',        $config{MANUAL_DIR};
 375         $config{MODULE_DIR} = prompt_dir $interactive, 'In what directory are modules to be placed?',             $config{MODULE_DIR};
 376         $config{SCRIPT_DIR} = prompt_dir $interactive, 'In what directory are scripts to be placed?',             $config{SCRIPT_DIR};
 377         $config{EXAMPLE_DIR} = $config{CONFIG_DIR} . '/examples';
 378         $config{RUNTIME_DIR} = $config{DATA_DIR};
 379 }
 380
 381 # Configure module settings.
 382 $question = <<'EOQ';
 383 Currently, InspIRCd is configured to automatically enable all available extra modules.
 384
 385 Would you like to enable extra modules manually?
 386 EOQ
 387 if (prompt_bool $interactive, $question, 0) {
 388         for my $extra (<$RealDir/src/modules/extra/m_*.cpp>) {
 389                 my $module_name = module_shrink $extra;
 390                 if (prompt_bool $interactive, "Would you like to enable the <|BOLD $module_name|> module?", 0) {
 391                         enable_extras $module_name;
 392                 }
 393         }
 394 } elsif (!defined $opt_disable_auto_extras) {
 395         my %modules = (
 396                 'm_argon2.cpp'          => 'pkg-config --exists libargon2',
 397                 'm_geo_maxmind.cpp'     => 'pkg-config --exists libmaxminddb',
 398                 'm_mysql.cpp'           => 'mysql_config --version',
 399                 'm_pgsql.cpp'           => 'pg_config --version',
 400                 'm_ldap.cpp'            => "echo '#include <ldap.h>' | $config{CXX} -E -",
 401                 'm_regex_pcre.cpp'      => 'pcre-config --version',
 402                 'm_regex_posix.cpp'     => undef,
 403                 'm_regex_re2.cpp'       => 'pkg-config --exists re2',
 404                 'm_regex_stdlib.cpp'    => "$config{CXX} -o /dev/null -std=c++11 $RealDir/make/test/compiler.cpp",
 405                 'm_regex_tre.cpp'       => 'pkg-config --exists tre',
 406                 'm_sqlite3.cpp'         => 'pkg-config --exists sqlite3',
 407                 'm_ssl_gnutls.cpp'      => 'pkg-config --exists gnutls',
 408                 'm_ssl_mbedtls.cpp'     => "echo '#include <mbedtls/version.h>' | $config{CXX} -E -",
 409                 'm_ssl_openssl.cpp'     => 'pkg-config --exists openssl',
 410                 'm_sslrehashsignal.cpp' => undef,
 411         );
 412         while (my ($module, $command) = each %modules) {
 413                 unless (defined $command && system "$command 1>/dev/null 2>/dev/null") {
 414                         enable_extras $module;
 415                 }
 416         }
 417 }
 418
 419 # Generate SSL certificates.
 420 $question = <<EOQ;
 421 Would you like to generate a self-signed SSL certificate now? This certificate
 422 can be used for testing but <|BOLD should not|> be used on a production network.
 423
 424 Note: you can get a <|BOLD free|> CA-signed certificate from Let's Encrypt. See
 425 https://letsencrypt.org/getting-started/ for more details.
 426 EOQ
 427
 428 if (<$RealDir/src/modules/m_ssl_*.cpp>) {
 429         if (prompt_bool $interactive, $question, $interactive) {
 430                 create_directory CONFIGURE_DIRECTORY, 0750 or print_error "unable to create ${\CONFIGURE_DIRECTORY}: $!";
 431                 system './tools/genssl', 'auto', CONFIGURE_DIRECTORY;
 432         } else {
 433                 my @pems = <${\CONFIGURE_DIRECTORY}/{cert,csr,dhparams,key}.pem>;
 434                 $question = <<EOQ;
 435 The following self-signed files were previously generated and will be installed
 436 when you run Make. Do you want to delete them?
 437
 438   * ${\join "\n  * ", @pems}
 439 EOQ
 440                 if (@pems && prompt_bool $interactive, $question, 0) {
 441                         unlink @pems;
 442                 }
 443         }
 444 } elsif (!defined $opt_disable_auto_extras) {
 445         print_warning <<"EOM";
 446 you are building without enabling any SSL modules. This is not
 447 recommended as SSL greatly enhances the security and privacy of your IRC server
 448 and in a future version will be <|BOLD required|> for linking servers.
 449
 450 Please read the following documentation pages on how to enable SSL support:
 451
 452 GnuTLS (recommended): https://docs.inspircd.org/3/modules/ssl_gnutls
 453 mbedTLS:              https://docs.inspircd.org/3/modules/ssl_mbedtls
 454 OpenSSL:              https://docs.inspircd.org/3/modules/ssl_openssl
 455 EOM
 456 }
 457
 458 # Cache the distribution label so that its not lost when --update is run.
 459 $config{DISTRIBUTION} = $opt_distribution_label if $opt_distribution_label;
 460 $config{DISABLE_OWNERSHIP} = $opt_disable_ownership // 0;
 461
 462 write_configure_cache %config;
 463 parse_templates \%config, \%compiler, \%version;
 464
 465 print console_format <<"EOM";
 466
 467 Configuration is complete! You have chosen to build with the following settings:
 468
 469 <|GREEN Compiler:|>
 470   <|GREEN Binary:|>  $config{CXX}
 471   <|GREEN Name:|>    $compiler{NAME}
 472   <|GREEN Version:|> $compiler{VERSION}
 473
 474 <|GREEN Extra Modules:|>
 475 EOM
 476
 477 for my $file (<$RealDir/src/modules/m_*>) {
 478         say "  * ${\module_shrink $file}" if -l $file;
 479 }
 480
 481 my @makeargs;
 482 push @makeargs, "-C${\abs2rel $RealDir}" unless getcwd eq $RealDir;
 483 push @makeargs, "-j${\(get_cpu_count() + 1)}";
 484
 485 print console_format <<"EOM";
 486
 487 <|GREEN Paths:|>
 488   <|GREEN Binary:|>  $config{BINARY_DIR}
 489   <|GREEN Config:|>  $config{CONFIG_DIR}
 490   <|GREEN Data:|>    $config{DATA_DIR}
 491   <|GREEN Example:|> $config{EXAMPLE_DIR}
 492   <|GREEN Log:|>     $config{LOG_DIR}
 493   <|GREEN Manual:|>  $config{MANUAL_DIR}
 494   <|GREEN Module:|>  $config{MODULE_DIR}
 495   <|GREEN Runtime:|> $config{RUNTIME_DIR}
 496   <|GREEN Script:|>  $config{SCRIPT_DIR}
 497
 498 <|GREEN Execution Group:|> $config{GROUP} ($config{GID})
 499 <|GREEN Execution User:|>  $config{USER} ($config{UID})
 500 <|GREEN Socket Engine:|>   $config{SOCKETENGINE}
 501
 502 To build with these settings run '<|GREEN make ${\join ' ', @makeargs} install|>' now.
 503
 504 EOM
 505
 506 # Routine to list out the extra/ modules that have been enabled.
 507 # Note: when getting any filenames out and comparing, it's important to lc it if the
 508 # file system is not case-sensitive (== Epoc, MacOS, OS/2 (incl DOS/DJGPP), VMS, Win32
 509 # (incl NetWare, Symbian)). Cygwin may or may not be case-sensitive, depending on
 510 # configuration, however, File::Spec does not currently tell us (it assumes Unix behavior).
 511 sub list_extras () {
 512         use File::Spec;
 513         # @_ not used
 514         my $srcdir = File::Spec->catdir("src", "modules");
 515         my $abs_srcdir = File::Spec->rel2abs($srcdir);
 516         local $_;
 517         my $dd;
 518         opendir $dd, File::Spec->catdir($abs_srcdir, "extra") or die (File::Spec->catdir($abs_srcdir, "extra") . ": $!\n");
 519         my @extras = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 520         closedir $dd;
 521         undef $dd;
 522         opendir $dd, $abs_srcdir or die "$abs_srcdir: $!\n";
 523         my @sources = map { File::Spec->case_tolerant() ? lc($_) : $_ } (readdir($dd));
 524         closedir $dd;
 525         undef $dd;
 526         my $maxlen = (sort { $b <=> $a } (map { length module_shrink $_ } (@extras)))[0];
 527         my %extras = ();
 528 EXTRA:  for my $extra (@extras) {
 529                 next if (File::Spec->curdir() eq $extra || File::Spec->updir() eq $extra);
 530                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 531                 my $abs_source = File::Spec->catfile($abs_srcdir, $extra);
 532                 next unless ($extra =~ m/\.(cpp|h)$/ || (-d $abs_extra)); # C++ Source/Header, or directory
 533                 if (-l $abs_source) {
 534                         # Symlink, is it in the right place?
 535                         my $targ = readlink($abs_source);
 536                         my $abs_targ = File::Spec->rel2abs($targ, $abs_srcdir);
 537                         if ($abs_targ eq $abs_extra) {
 538                                 $extras{$extra} = "\e[32;1menabled\e[0m";
 539                         } else {
 540                                 $extras{$extra} = sprintf("\e[31;1mwrong symlink target (%s)\e[0m", $abs_targ);
 541                         }
 542                 } elsif (-e $abs_source) {
 543                         my ($devext, $inoext) = stat($abs_extra);
 544                         my ($devsrc, $inosrc, undef, $lnksrc) = stat($abs_source);
 545                         if ($lnksrc > 1) {
 546                                 if ($devsrc == $devext && $inosrc == $inoext) {
 547                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 548                                 } else {
 549                                         $extras{$extra} = sprintf("\e[31;1mwrong hardlink target (%d:%d)\e[0m", $devsrc, $inosrc);
 550                                 }
 551                         } else {
 552                                 open my $extfd, "<", $abs_extra;
 553                                 open my $srcfd, "<", $abs_source;
 554                                 local $/ = undef;
 555                                 if (scalar(<$extfd>) eq scalar(<$srcfd>)) {
 556                                         $extras{$extra} = "\e[32;1menabled\e[0m";
 557                                 } else {
 558                                         $extras{$extra} = sprintf("\e[31;1mout of synch (re-copy)\e[0m");
 559                                 }
 560                         }
 561                 } else {
 562                         $extras{$extra} = "\e[33;1mdisabled\e[0m";
 563                 }
 564         }
 565         # Now let's add dependency info
 566         for my $extra (keys(%extras)) {
 567                 next unless $extras{$extra} =~ m/enabled/; # only process enabled extras.
 568                 my $abs_extra = File::Spec->catfile($abs_srcdir, "extra", $extra);
 569                 my @deps = split /\s+/, get_directive($abs_extra, 'ModDep', '');
 570                 for my $dep (@deps) {
 571                         if (exists($extras{$dep})) {
 572                                 my $ref = \$extras{$dep}; # Take reference.
 573                                 if ($$ref !~ m/needed by/) {
 574                                         # First dependency found.
 575                                         if ($$ref =~ m/enabled/) {
 576                                                 $$ref .= " (needed by \e[32;1m$extra\e[0m";
 577                                         } else {
 578                                                 $$ref =~ s/\e\[.*?m//g; # Strip out previous coloring. Will be set in bold+red+blink later.
 579                                                 $$ref .= " (needed by \e[0;32;1;5m$extra\e[0;31;1;5m";
 580                                         }
 581                                 } else {
 582                                         if ($$ref =~ m/enabled/) {
 583                                                 $$ref .= ", \e[32;1m$extra\e[0m";
 584                                         } else {
 585                                                 $$ref .= ", \e[0;32;1;5m$extra\e[0;31;1;5m";
 586                                         }
 587                                 }
 588                         }
 589                 }
 590         }
 591         for my $extra (sort {$a cmp $b} keys(%extras)) {
 592                 my $text = $extras{$extra};
 593                 if ($text =~ m/needed by/ && $text !~ m/enabled/) {
 594                         printf "\e[31;1;5m%-*s = %s%s\e[0m\n", $maxlen, module_shrink($extra), $text, ($text =~ m/needed by/ ? ")" : "");
 595                 } else {
 596                         printf "%-*s = %s%s\n", $maxlen, module_shrink($extra), $text, ($text =~ m/needed by/ ? "\e[0m)" : "");
 597                 }
 598         }
 599         return keys(%extras) if wantarray; # Can be used by manage_extras.
 600 }
 601
 602 sub enable_extras(@) {
 603         my $moduledir = catdir $RealDir, 'src', 'modules';
 604         my $extradir = catdir $moduledir, 'extra';
 605
 606         for my $extra (@_) {
 607                 my $shortname = module_shrink $extra;
 608                 my $extrafile = module_expand $extra;
 609
 610                 my $extrapath = catfile $extradir, $extrafile;
 611                 if (!-f $extrapath) {
 612                         print_error "<|GREEN $extra|> is not an extra module!";
 613                 }
 614
 615                 my $modulepath = catfile $moduledir, $extrafile;
 616                 if (-l $modulepath) {
 617                         if (readlink($modulepath) ne $extrapath) {
 618                                 unlink $modulepath; # Remove the dead symlink.
 619                         } else {
 620                                 next; # Module is already enabled.
 621                         }
 622                 }
 623
 624                 if (-e $modulepath) {
 625                         print_error "unable to symlink <|GREEN ${\abs2rel $modulepath}|> to <|GREEN ${\abs2rel $extrapath}|>: the target exists and is not a symlink.";
 626                 } else {
 627                         say console_format "Enabling the <|GREEN $shortname|> module ...";
 628                         symlink $extrapath, $modulepath or print_error "unable to symlink <|GREEN ${\abs2rel $modulepath}|> to <|GREEN ${\abs2rel $extrapath}|>: $!";
 629                 }
 630         }
 631 }
 632
 633 sub disable_extras(@) {
 634         my $moduledir = catdir $RealDir, 'src', 'modules';
 635         my $extradir = catdir $moduledir, 'extra';
 636
 637         for my $extra (@_) {
 638                 my $shortname = module_shrink $extra;
 639                 my $extrafile = module_expand $extra;
 640
 641                 my $modulepath = catfile $moduledir, $extrafile;
 642                 my $extrapath = catfile $extradir, $extrafile;
 643                 if (!-e $modulepath && !-e $extrapath) {
 644                         print_error "the <|GREEN $shortname|> module does not exist!";
 645                 } elsif (!-e $modulepath && -e $extrapath) {
 646                         print_error "the <|GREEN $shortname|> module is not currently enabled!";
 647                 } elsif ((-e $modulepath && !-e $extrapath) || !-l $modulepath) {
 648                         print_error "the <|GREEN $shortname|> module is not an extra module!";
 649                 } else {
 650                         say console_format "Disabling the <|GREEN $shortname|> module ...";
 651                         unlink $modulepath or print_error "unable to unlink <|GREEN $extrapath|>: $!";
 652                 }
 653         }
 654 }